TOMCAT 之 startup.bat文件分析

@echo off
rem Licensed to the Apache Software Foundation (ASF) under one or more
rem contributor license agreements.  See the NOTICE file distributed with
rem this work for additional information regarding copyright ownership.
rem The ASF licenses this file to You under the Apache License, Version 2.0
rem (the "License"); you may not use this file except in compliance with
rem the License.  You may obtain a copy of the License at
rem
rem     http://www.apache.org/licenses/LICENSE-2.0
rem
rem Unless required by applicable law or agreed to in writing, software
rem distributed under the License is distributed on an "AS IS" BASIS,
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
rem See the License for the specific language governing permissions and
rem limitations under the License.

rem ---------------------------------------------------------------------------
rem Start script for the CATALINA Server
rem ---------------------------------------------------------------------------

setlocal

rem Guess CATALINA_HOME if not defined
set "CURRENT_DIR=%cd%"
if not "%CATALINA_HOME%" == "" goto gotHome
set "CATALINA_HOME=%CURRENT_DIR%"
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
cd ..
set "CATALINA_HOME=%cd%"
cd "%CURRENT_DIR%"
:gotHome
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
echo The CATALINA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
goto end
:okHome

set "EXECUTABLE=%CATALINA_HOME%\bin\catalina.bat"

rem Check that target executable exists
if exist "%EXECUTABLE%" goto okExec
echo Cannot find "%EXECUTABLE%"
echo This file is needed to run this program
goto end
:okExec

rem Get remaining unshifted command line arguments and save them in the
set CMD_LINE_ARGS=
:setArgs
if ""%1""=="""" goto doneSetArgs
set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
shift
goto setArgs
:doneSetArgs

call "%EXECUTABLE%" Start %CMD_LINE_ARGS%

:end

 

1.@echo off表示执行了这条命令关闭所有命令（包括本身这条命令）的回显，而echo off命令则表示关闭其他所有命令（不包括本身这条命令）的回显。

2.ms-dos命令：rem [comment]，可以在批处理文件或配置文件中加入注释。dos命令大全

3.ms-dos命令：setlocal，开始批处理文件中环境变量的本地化，本地化持续到出现匹配endlocal命令或者到达批处理文件结尾为止。

4.ms-dos命令：set，显示、设置或删除环境变量，如果没有任何参数，set命令将显示当前环境设置。

5.%cd%：current directory。

6.ms-dos：shift，更改批处理文件中批处理参数的位置。shift命令通过将每个参数复制到前一个参数中，更改批处理参数%0到%9的值。也就是将%1的值 复制到%0。

7.ms-dos：call ，从一个批处理程序调用另一个批处理程序，并且不终止父批处理程序。

8.ms-dos：start，启动单独的“命令提示符”窗口来运行指定程序或命令。

 

最后欢迎大家访问我的个人网站：1024s