bzoj 1191 [HNOI]超级英雄Hero 二分图最大匹配（匈牙利算法）

1191: [HNOI2006]超级英雄Hero

Time Limit: 10 Sec   Memory Limit: 162 MB
Submit: 3911   Solved: 1801
[ Submit][ Status][ Discuss]

Description

现在电视台有一种节目叫做超级英雄,大概的流程就是每位选手到台上回答主持人的几个问题,然后根据回答问题的多少获得不同数目的奖品或奖金。主持人问题准备了若干道题目，只有当选手正确回答一道题后，才能进入下一题，否则就被淘汰。为了增加节目的趣味性并适当降低难度，主持人总提供给选手几个“锦囊妙计”，比如求助现场观众，或者去掉若干个错误答案（选择题）等等。 这里，我们把规则稍微改变一下。假设主持人总共有m道题，选手有n种不同的“锦囊妙计”。主持人规定，每道题都可以从两种“锦囊妙计”中选择一种，而每种“锦囊妙计”只能用一次。我们又假设一道题使用了它允许的锦囊妙计后，就一定能正确回答，顺利进入下一题。现在我来到了节目现场，可是我实在是太笨了，以至于一道题也不会做，每道题只好借助使用“锦囊妙计”来通过。如果我事先就知道了每道题能够使用哪两种“锦囊妙计”，那么你能告诉我怎样选择才能通过最多的题数吗？

Input

输入文件的一行是两个正整数n和m(0 < n <1001,0 < m < 1001)表示总共有n中“锦囊妙计”，编号为0~n-1，总共有m个问题。
以下的m行，每行两个数，分别表示第m个问题可以使用的“锦囊妙计”的编号。
注意，每种编号的“锦囊妙计”只能使用一次，同一个问题的两个“锦囊妙计”可能一样。

Output

第一行为最多能通过的题数p

Sample Input

5 6
3 2
2 0
0 3
0 4
3 2
3 2

Sample Output

4

HINT

Source

比较显然的二分图，

把每个问题和它可以选择的两个锦囊连边，

然后按照问题的顺序，去判断是否从第一个问题到该问题是否都可以得到匹配，

求出最大的匹配数，

即找到第一个不能匹配的问题，然后该问题序号-1即是最多能连续回答的问题数

注意：因为要找到第一个不能匹配的问题，所以循环到m+1，

不然的话如果m个问题都能回答我们的输出将是（m-1）

AC代码：

var
    l,n,m,ans,a,b       :longint;
    i                   :longint;
    pre,other           :array[0..2010] of longint;
    last,link           :array[0..1010] of longint;
    flag                :array[0..1010] of boolean;
procedure connect(x,y:longint);
begin
   inc(l);
   pre[l]:=last[x];
   last[x]:=l;
   other[l]:=y;
end;

function find(x:longint):boolean;
var
    p,q:longint;
begin
   q:=last[x];
   while (q<>0) do
   begin
      p:=other[q];
      if not flag[p] then
      begin
         flag[p]:=true;
         if (link[p]=0) or find(link[p]) then
         begin
            link[p]:=x;
            exit(true);
         end;
      end;
      q:=pre[q];
   end;
   exit(false);
end;


begin
   read(n,m);
   for i:=1 to m do
   begin
      read(a,b);
      connect(i,a);
      connect(i,b);
   end;
   //
   for i:=1 to m do
   begin
      fillchar(flag,sizeof(flag),false);
      if find(i) then inc(ans) else break;
   end;
   //
   writeln(ans);
end.

——by Eirlys