详解VB中系统热键使用

原创 2011年08月22日 14:44:55

最近弄这个很头疼了,没多少基础,不好理解,现在弄清楚了,这里总结一下.

先说要用到的API

SetWindowLong
GetWindowLong  '用来获取/设置窗口的消息处理函数地址,为什么后面会说到

上面两个函数都要用到GWL_WNDPROC = (-4)这个常数

CallWindowProc

RegisterHotKey
UnregisterHotKey '用来注册,释放快捷键(因为就算程序关了,系统自己不会释放程序注册了的快捷键,会造成其他程序注册相同快捷键的时候失败)


因为VB本身不处理热键消息,有关此消息请参考MSDN上WM_HotKey的说明

所以,我们要自己写消息处理函数来处理热键消息,

窗体的消息处理函数,是一个名叫WindowProc的回调函数,每个窗口都有一个这样的函数用来处理各种消息,

因为它要处理各种不同种类的消息进行不同的判断,所以一般是一个相当大的函数,不过我们不需要重写它,毕竟这是很耗时间的事情,

我们只需要增加一点点专门处理热键消息的过程就可以了,把其他的消息交给原来窗口的WindowProc,这样就可以省很多事.

但是,VB本身对于WindowProc是在编译的时候添加进去的,没有给我们留下编辑的余地,所以,得用其他变通的方法解决.

这里的思路是:先让自己写的过程收到消息判断是否是热键消息,然后再进行进一步判断和需要的过程调用,如果不是热键消息,就把消息归还给原来的窗口.

下来说具体的实现例子

以添加一个Alt+N的热键用来隐藏/显示窗口为例(就是通常说的老板键)

关于虚拟键码请参考

http://blog.csdn.net/franticblack/article/details/6699697或MSDN

关于WM_HotKey热键消息的结构请参考

http://msdn.microsoft.com/en-us/library/ms646279(VS.85).aspx

'*********************
'以下代码需要
'一个窗体,名为frm_Main
'一个标准模块
'*********************

'--------------------------------------------
'frm_Main的代码
Option Explicit
Private Sub Form_Load()
    preWinProc = GetWindowLong(Me.hWnd, GWL_WNDPROC)'得到原窗口过程地址,保存在变量preWinProc
    SetWindowLong Me.hWnd, GWL_WNDPROC, AddressOf WndProc''将窗口地址设置成我们写的消息处理函数的地址,AddressOf用来返回一个过程的地址,这样系统发送的消息就会先进入我们定义的WndProc供我们处理
    RegisterHotKey Me.hWnd, 1, MOD_ALT, vbKeyN '装载时注册热键
End Sub

Private Sub Form_Unload(Cancel As Integer)
    SetWindowLong Me.hWnd, GWL_WNDPROC, preWinProc'将窗口过程地址还原
    UnregisterHotKey Me.hWnd, 1 '释放热键供其它应用程序使用
    End
End Sub



'--------------------------------------------
'module1的代码
Option Explicit

'变量
Public preWinProc As Long '存储原本的窗口过程的地址

'常量
Public Const GWL_WNDPROC = (-4) '这个常数供GetWindowLong和SetWindowLong使用以得到和设置窗口过程地址
Public Const WM_HOTKEY = &H312 '热键消息常数,用来判断消息是否为热键消息的常数
Public Const MOD_ALT = &H1 'RegisterHotKey和UnregisterHotKey用到的表示按下Alt键的常数


'API声明
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal _
                        hWnd As Long, ByVal _
                        nIndex As Long, ByVal _
                        dwNewLong As Long) As Long 

Public Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal _
                        hWnd As Long, ByVal _
                        nIndex As Long) As Long

Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal _
                        lpPrevWndFunc As Long, ByVal _
                        hWnd As Long, ByVal _
                        Msg As Long, ByVal _
                        wParam As Long, ByVal _
                        lParam As Long) As Long 

Public Declare Function RegisterHotKey Lib "user32" (ByVal _
                        hWnd As Long, ByVal _
                        ID As Long, ByVal _
                        fsModifiers As Long, ByVal _
                        vk As Long) As Long '向系统注册热键

Public Declare Function UnregisterHotKey Lib "user32" (ByVal _
                        hWnd As Long, ByVal _
                        ID As Long) As Long

'过程
Sub Main()
    If App.PrevInstance = True Then    '如果如果已经运行就自己退出
        MsgBox "程序已经运行!", vbOKOnly, "提示"
        End
    End If
    frm_Main.Show
End Sub


Public Function WndProc(ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    If Msg = WM_HOTKEY Then '如果是热键消息
        If wParam = 1 Then '如果是本程序定义的(系统消息中的wParam参数在热键消息中代表热键标示符,是在RegisterHotKey注册热键的时候定义的一个整数,如果热键是系统定义的,则标示符取值为-1或-2,详见开头
                Call WindowShowHide ' 热键对应上了之后就调用指定的过程
                Exit Function '消息已处理,不需要发回窗口
        End If
    End If
    WndProc = CallWindowProc(preWinProc, hWnd, Msg, wParam, lParam)'不是热键消息,就把消息发给原来窗口过程交给它处理
End Function


Public Sub WindowShowHide() ' 用于隐藏显示窗口
	Select Case frm_Main.Visible
		Case True
			frm_Main.Hide
		Case False
			frm_Main.Show
	End Select
End Sub

这样,运行之后,反复按Alt + N 就可以实现窗口的隐藏与显示





                

VB6的快捷键

VB6的快捷键 组合按键 窗体设计 代码设计 运行中断时 F1 帮助 F2 对象浏览器 ...
  • u013166875
  • u013166875
  • 2013年12月16日 21:30
  • 822

用VB如何编写无窗口系统热键程序

用VB如何编写系统热键程序,网上有很多现成代码,但大都使用了窗口,即使这个窗口根本没有用。其实,如果只是要在某个热键中处理某件事件,根本不需要创建窗口,也无需借助窗口子类化。本文以获得当前IE页面中B...
  • lyserver
  • lyserver
  • 2009年07月11日 23:02
  • 3473

Vb热键Hotkey源代码典型示例

  • 2013年07月14日 18:35
  • 3KB
  • 下载

详解VB中系统热键使用

最近弄这个很头疼了,没多少基础,不好理解,现在弄清楚了,这里总结一下. 先说要用到的API SetWindowLong GetWindowLong  '用来获取/设置窗口的消息处理函数地址,为什...
  • FranticBlack
  • FranticBlack
  • 2011年08月22日 14:44
  • 2819

VB 全局热键

今天在研究我的新系统的时候坐在我旁边的磊磊说...想要一个热键功能~习惯了使用热键...我想想也是...于是就上网找了找VB全局热键的写法...一看才知道NND全局热键都很占资源大都用DO~LOOP来...
  • ZOU_SEAFARER
  • ZOU_SEAFARER
  • 2007年03月16日 23:08
  • 1988

在PB中实现系统热键功能

本方法可以实现在任何时候,即无论你的窗口是不是当前获得焦点的窗口,还是处于系统图标区,只要用户按下热键,都将触发窗口中的事件,在本例中实现窗口的状态切换。  1、首先我们必须声明Windows API...
  • Luckeryin
  • Luckeryin
  • 2008年11月28日 21:25
  • 1343

HotKey函数的应用(VB实现热键)

  • 2010年06月04日 19:50
  • 162B
  • 下载

VB启动热键设置源代码

  • 2014年02月26日 19:39
  • 4KB
  • 下载

Delphi RegisterHotKey 设置系统热键

首先先贴一张热键表 Symbolic constant name Value (hexadecimal) Keyboard (or mouse) equivalent ...
  • yanjiaye520
  • yanjiaye520
  • 2012年08月22日 15:33
  • 4310

vb 监听回车键

在文本框的keypress事件里写代码。 private sub text1_keypress(KeyAscii As Integer) if keyascii = vblf the...
  • esonbest1234
  • esonbest1234
  • 2016年02月24日 11:13
  • 305
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:详解VB中系统热键使用
举报原因:
原因补充:

(最多只允许输入30个字)