简易对象垃圾回收框架 for Delphi

原创 2004年05月26日 13:08:00

1       缘起

1.1   我的一个出错程序

程序名称:呼叫处理模块的压力测试工具,分为客户端和服务端。

开发工具:Delhpi 5

相关技术:客户端通过与服务端建立Socket连接来模拟一组电话机的拨入、按键、等待、挂机等过程。服务端对Socket事件以及收到的数据包进行预处理,并转化为抽象的呼叫模型数据,然后发送给更上层的呼叫处理模块。由于呼叫处理模块是硬件无关的(与语音板卡、交换机类型均无关),因此通过此压力测试工具可以比较真实地模拟海量呼叫,以达到测试呼叫处理模块程序的逻辑正确性及其性能的目的。

由于系统设计时的某些考虑,该测试工具被分作客户端和服务端两个程序来实现,且采用socket进行通讯。现在想来,其实不如整合成一个程序实现更为简单——但也正因为采用两个程序来实现,才引发了后面的一些问题,并由此引入了简单的垃圾回收框架。

1.2   问题

在测试工具的使用过程中,我们发现当呼叫量巨大,且测试工具动作频繁的情况下,系统出现以下错误:

n         访问地址错(EAccessViolation),代码地址位于$0046FC80附近,访问地址多为$00000028

n         出现EinvalidCast错误,该错误表明对一个地址进行类类型转换时出错(采用as关键字)。

n         程序内多处断言失败,出现许多引用已销毁对象的情况。

仔细检查程序后,我仍然认为这一切简直是不可思议!而且,本来用于对别的程序进行测试的程序自身却出现这类问题,几乎让我无地自容!

为了挽回自己的声誉,我不得不成沉住气来仔细跟踪错误,排解问题!

2       解决办法

2.1   查错

其实问题的解决还比较顺利。

通过查看程序的调用栈,发现程序出错前总是停留在发送Socket数据包的过程里。接着,进一步通过单步跟踪,发现在发送数据包的过程中,Socket检测到对端连接已经断开,就会触发OnDisconnect事件。而我正是在ServerSocketOnDisconnect事件中根据传递进来的Socket句柄,找到对应的对象将之销毁的。

我在ServerSocketOnDisconnect事件中的代码如下:

procedure Txxxx.ServerClientDisconnect(Sender: TObject;

  Socket: TCustomWinSocket);

Begin

 

  FLines.DestroyLineBySocket(Socket);//正是这一句,在不合适的时机释放了对象

 

End;

问题是这么出现的。

比如,在某个过程中具有如下代码(前面为行号):

1    FLine.DoSomething

2    FLine.SendSocketData

3    FLine.DoOtherThings

其中,FLine是代表一路呼叫的对象。该对象内部引用了一个TCustomWinSocket指针。SendSocketData就是利用此Socket进行数据发送。

FlinesTLine对象的容器类的一个实例。

由此不难解读前述的各类错误:

1.  由于行2Socket连接断开导致FLine对象释放,因此行3访问DoOtherThings几乎必然造成访问地址错;

2.  由于行2的对象销毁,因此程序中类似“Object as TLine”的代码导致第二类错误;

3.  由于对象提前销毁,善后处理工作未到位导致第三类错误;

2.2   解决方案

明白其原因后,问题解决起来就容易多了。

上述问题不外乎两个方案:

一,              判断实例是否存在

DoOtherThings之后,判断FLine对象是否仍然处于Flines之中,若是则继续处理,否则结束处理;

二,              延迟销毁FLine对象

ServerSocketOnDisconnect中,将FLine对象抛入垃圾池,待时机成熟时再销毁。

考虑到方案一所要改动的代码量较大,同时,此种方案代码也不甚优美,因此决定采用方案二,即引入垃圾回收机制来解决问题。方案二的要点是选择合适的时机真正销毁对象。而对于这一点,问题倒不大,只需选择消息循环中处理消息的第一个环节进行回收即可。因为在之后的处理环节中,必然能够确保对FLine是否仍然有效的检查。

3       简易对象垃圾回收框架(untGarbagCollector

3.1   概述

简易的垃圾回收非常简单:

n         使用TThreadList支持线程并发访问,并保存待回收的对象指针;

n         提供Put方法保存待回收对象;

n         提供Recycle方法进行真正的回收(因为所有对象均自TObject派生而来)。

3.2   实现代码

unit untGarbagCollector;

 

interface

 

uses

  Classes;

 

type

 

  TGarbagCollector = Class(TObject)

  private

    FList: TThreadList;

  public

    constructor Create;

    destructor Destroy; override;

    procedure Put(const AObject: TObject);

    procedure Recycle(const MaxCount: Integer);

  end;

 

function GarbagCollector: TGarbagCollector;

 

implementation

 

var

  _GarbagCollector: TGarbagCollector;

 

function GarbagCollector: TGarbagCollector;

begin

  if not Assigned(_GarbagCollector) then

    _GarbagCollector := TGarbagCollector.Create;

  result := _GarbagCollector;

end;

 

 

{ TGarbagCollect }

 

constructor TGarbagCollector.Create;

begin

  FList := TThreadList.Create;

end;

 

destructor TGarbagCollector.Destroy;

begin

  try

    Recycle(FList.LockList.Count);

  finally

    FList.UnlockList;

  end;

  FList.Free;

end;

 

procedure TGarbagCollector.Put(const AObject: TObject);

begin

  try

    FList.LockList.Add(AObject);

  finally

    FList.UnlockList;

  end;

end;

 

procedure TGarbagCollector.Recycle(const MaxCount: Integer);

var

  I: Integer;

  AList: TList;

begin

  AList := FList.LockList;

  try

    I := 0;

    while (AList.Count > 0) and (I < MaxCount) do

    begin

      TObject(AList.Last).Free;

      AList.Delete(AList.Count - 1);

      Inc(I);

    end;

  finally

    FList.UnlockList;

  end;

end;

 

initialization

 

finalization

  if Assigned(_GarbagCollector) then

    _GarbagCollector.Free;

 

end.

3.3   使用举例

引用untGarbagCollector单元后,可以直接使用GarbagCollector进行对象的销毁和回收。

n         销毁

AObject := TObject.Create;

GarbagCollector.Put(AObject);

n         回收

可以在定时器、线程以及其他场合调用Recycle方法。

MaxCount是用于控制每次销毁个数的参数,主要是怕一次性销毁太多占用过多的cpu

(突然发现还可以扩展为限制时间进行销毁,比如每次销毁耗时不超过的n毫秒)。

3.4   使用场合

在本案例中,为了防止对象过早销毁引起访问冲突,而引入了垃圾回收技术。

在其它场合,比如为了提高某些程序的主观性能,也可以引入该技术。比如完成某些特定任务的程序,在处理过程中会产生临时的对象,而销毁这些对象又比较耗时。因此,为了尽早地结束任务,可以把这些临时对象保存至垃圾池中。待作业(任务)完成,并且等一段时间后cpu比较空闲时,再把临时对象真正销毁。此做法的真谛就是以空间换取时间——与某些系统预创建对象,并重复利用对象以提高性能的做法相同。

 

[文终]

Delphi插件管理框架的简单实现

1 前言 1.1 插件技术许多软件采用“插件”(PlugIns)来扩展其功能,比如PhotoShop所支持的各类滤镜就是插件;我们所熟知的Winamp,也有许多皮肤以及可视效果插件。...
  • xieyunc
  • xieyunc
  • 2017年03月19日 13:34
  • 1142

Delphi 画布对象及其简单应用

 TShape组件的属性,事件和方法 TImage组件的属性,事件和方法 Paintbox组件的属性,事件和方法 使用鼠标事件的绘图第 9章 图像图形应用编程 9.1 图形应用编程本章主...
  • hutao1101175783
  • hutao1101175783
  • 2014年02月09日 19:01
  • 833

delphi 对象与类类型

对象与类类型   从用户角度考虑,用户并不需要了解面向对象编程,就可编写Delphi应用程序。当用户在建立新窗体,添加新构件以及处理事件时,大部分相关代码会由Delphi自动产生。但是,知道语言...
  • hcwp2008
  • hcwp2008
  • 2014年03月23日 14:32
  • 721

一个php简单的框架实现,仅实现了简单路由层

这是一个简单的php框架的实现代码,其他框架原理大致与此相同的。
  • shi_yi_fei
  • shi_yi_fei
  • 2017年01月23日 17:19
  • 1839

Delphi 三层框架开发 服务端开发

采用Delphi7+SQL2008 首先创建数据库和表
  • gykthh
  • gykthh
  • 2014年10月24日 14:40
  • 13430

简易session购物车开发

简易session购物车开发要求:(1)保证中文的正常显示(2)表单提交以后,可以专门用一个jsp处理,然后再回退到操作界面(需要一定的时间延迟刷新,保证用户能感受到页面的变化)。(3)购物车数据通过...
  • qq_40197828
  • qq_40197828
  • 2017年11月03日 18:54
  • 311

Delphi中避免使用ClassName判断对象的类型

在公司原有系统的代码中,我看到了很多判别对象的ClassName属性进行分别处理的代码。而且似乎已经是处理类似问题的标准方法。但是其中可能会隐含一些问题。 首先,我们知道多态是面向对象的三大...
  • wozengcong
  • wozengcong
  • 2013年12月19日 01:16
  • 1326

DELPHI基于线程的定时器和一个泛型对象池

笔记 unit ThreadTimer; //次编译指令仅在测试时使用,请勿在Release版本中打开 {$DEFINE RunInMainThread} interface uses Sy...
  • huixch
  • huixch
  • 2016年05月12日 01:13
  • 327

Delphi框架、类库和实用资源集合 Awesome Delphi

http://www.open-open.com/lib/view/open1413120365093.html 阅读目录 General LibrariesMultime...
  • dacong
  • dacong
  • 2015年05月15日 22:14
  • 1860

序列化(Serialization)一个对象

1. 序列化的概念         序列化: 将数据结构或对象转换成二进制串的过程,简单理解就是将对象转换为容易传输的格式的过程。 2. 序列化的作用    序列化是为了保存内存中各种对象的状态,并且...
  • xby_869151205
  • xby_869151205
  • 2016年08月06日 17:19
  • 468
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:简易对象垃圾回收框架 for Delphi
举报原因:
原因补充:

(最多只允许输入30个字)