【原创】在MASM32中使用自己的STUB

原创 2004年12月29日 09:58:00
这是我测试PE格式的STUB的源代码,可显示当前所用操作操作系统版本。

dos下的stub部分源代码---调用DOS中断服务程序

 @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
; FileName: os_type.asm
; function: Reports current operation system type
; Author : Purple Endurer
; Version : 0.1
;
; OS Name Offset of INT 08h Offset of INT 43h
; -------------------------------------------------------
; MS DOS 7.00 001Fh 5710h
; MS DOS 7.10 18DEh 6EE5h
; UCDOS 1AF3h
; UCDOS98 1AEBh 6E20h
; MSDOS mode 0000h
; PDOS95 0A50h 6E20h
;
; Date Summary
; -------------------------------------------------------
; 2002.04.07 Created from software paper 95P125
; 2002.06.11 Show version if os is MS-DOS
; 2002.08.07 Convert it to DOS EXE format to be stub
; program in PE format execute file
; 2004.02.09 Added the condition asm var 'UseStack'
; Question:
; Why can this program run normally with stack segment,
; though there is push and pop instruction in bin2dec proc?
 
UseStack equ 0
data segment
strMSDOS db "MS DOS "
cMajorVer db ' '
db '.'
cMinorVer db " $"
 
strUCDOS db "UCDOS"
cUCDOSVer db " 98特别版$"
 
strPDOS95 db "Windows95中文DOS方式PDOS95$"
data ends
 
if UseStack
sseg segment stack
db 10 dup(?)
sseg ends
endif
code segment
;--------------------------------------
if UseStack
assume cs: code, ds: data, ss: sseg
else
assume cs: code, ds: data
endif
 
main proc
start:
mov ax, data
mov ds, ax
 
if UseStack
mov ax, sseg
mov ss, ax
endif
 
mov ah, 30h ; Get Version
int 21h
add al, '0'
mov cMajorVer, al
mov bx, offset cMinorVer
call bin2dec
 
mov ax, 3508h
int 21h
 
mov dx, offset strMSDOS
mov ah, 09h
int 21h
 
cmp bx, 1fh
je @end ;Here is DOS 7.00 only
cmp bx, 18deh
je @End ;Here is DOS 7.10 only
 
mov dx, offset strUCDOS
cmp bx, 1aebh
je @Report
 
cmp bx, 1af3h
jne @next2
mov cUCDOSVer, '$'
jmp @report
 
@next2:
 
mov dx, offset strPDOS95
cmp bx, 0a50h
jne @End
@Report:
;mov ah, 09h
int 21h
@End:
mov ax, 4c00h
int 21h
main endp
 
; ========================================================
; Input : AH = the Binary will be translated)
; BX = First offset of memory us to store the result
; Output: BX = First offset of memory stored the result
; --------------------------------------------------------
bin2dec proc
push dx
mov dl, 10
@LoopDiv:
mov al, ah
xor ah, ah
div dl ; (AL) <- (AX) / (DL) (AH) <- (AX) % (DL)
add al, '0'
mov [bx], al
inc bx
cmp ah, 10
jg @LoopDiv
 
add ah, '0'
mov [bx], ah
pop dx
ret
bin2dec endp
;=========================================
code ends
end main

WINDOWS下的源代码--调用 API 函数GetVersionEx()

;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
;FileName: StubDemo.asm
; Fuction: Demo how to use the custome stub of PE exe files.
; Author: Purple Endurer
 
; Date Summary
; -------------------------------------------------------
; 2002.04.07 Created!
;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
 
.386
.model flat, stdcall
option casemap:none
include /masm32/include/windows.inc
include /masm32/include/kernel32.inc
include /masm32/include/user32.inc
includelib /masm32/lib/user32.lib
includelib /masm32/lib/kernel32.lib
 
bDetailInfo equ 0
 
.data
szMsgBoxTitle db "当前操作系统",0
 
if bDetailInfo ;?????? bDetailInfo
szWin31 db "Win32s on Windows 3.1 ", 0
szWin9x db "Win32 on Windows 95 ", 0
else
szWin31 db "Windows 3.1 ", 0
szWin9x db "Windows 95 ", 0
endif ;?????? bDetailInfo
 
szWinNT db "Windows NT ", 0
 
szFormat4OsVer db "%lu.%lu.%lu", 0
szGetOsInfoFail db "取操作系统信息失败!", 0
 
.data?
OsVer OSVERSIONINFO <>
szOsVerInfo db 255 dup (?)
szOsVerInfoTmp db 255 dup (?)
 
.code
start:
mov OsVer.dwOSVersionInfoSize, SIZEOF OSVERSIONINFO
invoke GetVersionEx, ADDR OsVer
 
.if eax
mov eax, OsVer.dwPlatformId
 
;Identifies the build number of the operating
;system in the low-order word For Win9X
 
.if eax == VER_PLATFORM_WIN32s
mov esi, OFFSET szWin31
and OsVer.dwBuildNumber, 0FFFFh
 
.elseif eax == VER_PLATFORM_WIN32_WINDOWS
mov esi, OFFSET szWin9x
and OsVer.dwBuildNumber, 0FFFFh
 
.else ; eax ==VER_PLATFORM_WIN32_NT
mov esi, OFFSET szWinNT
.endif
 
invoke lstrcpy, ADDR szOsVerInfo, esi
 
invoke wsprintf, ADDR szOsVerInfoTmp,/
ADDR szFormat4OsVer, OsVer.dwMajorVersion,/
OsVer.dwMinorVersion, OsVer.dwBuildNumber
 
invoke lstrcat, ADDR szOsVerInfo, ADDR szOsVerInfoTmp
invoke lstrcat, ADDR szOsVerInfo, ADDR OsVer.szCSDVersion
mov edi, OFFSET szOsVerInfo
mov esi, MB_OK OR MB_ICONINFORMATION
.else
mov edi, OFFSET szGetOsInfoFail
mov esi, MB_OK OR MB_ICONWARNING
.endif
 
invoke MessageBox, NULL, edi, addr szMsgBoxTitle, esi
 
invoke ExitProcess,NULL
 
end start

到命令行,把我们自己定义的stub连接进来

命令是:

/masm32/bin/link /stub:<filename.exe> /subsystem:windows <objectname.obj>

本例中使用的命令是:

/masm32v6/WORKS/my_stub>/masm32/bin/link /stub:stub.exe /subsystem:windows stubdemo.obj

尽管会看到下面的警告信息,但程序仍然是可以正常运行的。

Microsoft (R) Incremental Linker Version 5.12.8078
Copyright (C) Microsoft Corp 1992-1998. All rights reserved.
 
stub.exe : warning LNK4060: stub file missing full MS-DOS header; rebuild stub with /KNOWEAS 16-bit LINK option
 

MASM32的使用

最近在学习SEH的东西,所以需要用到汇编,我下载了masm32. 解压后是个安装文件,直接安装即可,安装成功后运行qeditor,进入MASM的集成开发环境。 1.创建新文件:File->Ne...
  • dxddxd1987
  • dxddxd1987
  • 2011年08月18日 11:07
  • 3562

MASM32环境设置

我用的不是MASM32 V8.2而是MASM32 V7.0,但我从网站www.masm32.com上下载并安装了MASM32 V8.2后发现里面的编译器和MASM32 V7.0的编译器版本号一样都是6...
  • yunhaiC
  • yunhaiC
  • 2007年05月24日 18:14
  • 2213

安装及设置MASM32 SDK

win10 企业版64位 首先,从官网(http://www.masm32.com/)下载最新的安装包,之后,以管理员身份运行安装。 之后,安装程序会在指定磁盘创建masm32文件夹,并在...
  • friendbkf
  • friendbkf
  • 2015年09月08日 19:53
  • 4740

MASM32 v11 汇编、连接及运行程序的方法

MASM32自带一个Quick Editor的编辑器,位于masm32目录下,名为qeditor.exe。 作为一个IDE,Quick Editor让我们很方便地在其中进行编辑源码,连接并运行程序。...
  • a949308398
  • a949308398
  • 2014年10月05日 20:57
  • 3574

[原创]MASM32新手指南

如果你在用汇编语言来开发windows下的程序的话,MASM32是很好的选择。(Masm32下载地址请用google搜索罢。)工欲善其事,必先利其器。本文主要针对masm32 v8来说明三点:1、基本...
  • Purpleendurer
  • Purpleendurer
  • 2005年03月24日 16:50
  • 8947

常用的masm32宏 等等

common.inc ;-------------------------------------------------------------------- ; common.inc ;...
  • jcw2012
  • jcw2012
  • 2012年01月03日 22:47
  • 453

声明:关于原创与转载的标注

声明:本blog多采用word发布blog,对转载文章因office未提供此选项,常自动发布为原创,尽管本人已经在文章醒目位置(头部或者尾部)标注转载位置,但仍不可避免对原创作者造成精神损失。本人会尽...
  • jo_say
  • jo_say
  • 2011年05月23日 13:44
  • 627

入门masm32编写简单汇编程序并做具体分析

用masm32编写一个很简单的汇编程序来入门一下masm32,打算使用斐波拉切数列这个简单的小程序来作为例子讲述。...
  • codes_first
  • codes_first
  • 2017年10月19日 00:56
  • 496

关于在java1.8环境下成功用rmic命令生成_stub.class文件的方法

关于在java1.8环境下成功用rmic命令生成_stub.class文件的方法 正确安装java之后目录文件夹应该如下: 整理系统Path变量中无效的项目,并且添加jdk和jre两个项目 ...
  • Charchunchiu
  • Charchunchiu
  • 2016年12月08日 17:33
  • 1137

从csdn的原创文章被扒说起

我居然都6年---不在csdn发文了.. 只是,我已经没有太多兴趣使用阿里,如果不是被阿里收购的万网有我几个域名,我会永远afk阿里。更别谈什么打败阿里。...
  • loadfuture
  • loadfuture
  • 2017年03月07日 17:33
  • 225
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:【原创】在MASM32中使用自己的STUB
举报原因:
原因补充:

(最多只允许输入30个字)