NP的重启代码(记录备份)！_np启动命令-CSDN博客

NP的重启代码(记录备份)！

2009-05-14 16:20

貌似很多游戏保护系统都是这么重启的
mov dx, 64h
mov al, feh
out dx, al

HS的重启

cli
push 000000FE
push 00000064
Call WRITE_PORT_UCHAR
hlt

异曲同工之处！

BIOS知识点滴Follow Bini系列之---系统重启

复制内容到剪贴板
代码:
;----------------------------------------------
; 文件名：KBCReset.asm
;----------------------------------------------
;    2007-12-11    bini.Yi/易祝兵    For teaching
;----------------------------------------------
    .386
    .model tiny
    .code
    org     100h

;; 如下代码参照《PC技术内幕》第8章键盘系统

START:
    mov     bl, 0FEh                ; KBC Reset命令
    call    keyboard_cmd            ; 不应该有返回
    hlt

IODELAY MACRO
out 0EDh, al
ENDM

;----------------------------------------------
; keyboard_cmd()
;----------------------------------------------
; 如果由于缓冲区满超时，则 ah 返回非零

;    调用    bl = 命令字节
;            ds = cs
;
;    返回    如果 ah =0，则成功
;            如果 ah =1，则失败
;----------------------------------------------

keyboard_cmd PROC NEAR
xor cx, cx ; 超时计数器(64K)

cmd_wait:
    in      al, 64h                 ; 获取控制器状态
    IODELAY
    test    al, 2                   ; bit1,输入缓冲区满？（控制器是否有数据没处理完）
    jz      cmd_send                ; 缓冲区空，准备接收命令.
    loop    cmd_wait                ; 缓冲区满，重试

    jmp     cmd_error               ; 超时，失败

cmd_send:
    mov     al, bl                  ; 取 bl 中的命令字节
    out     64h, al                 ; 发送命令字节
    IODELAY

    xor     cx, cx                  ; 超时计数器(64K)
cmd_accept:
    in      al, 64h                 ; 获取控制器状态
    IODELAY
    test    al, 2                   ; bit1,输入缓冲区满？（控制器是否有数据没处理完）
    jz      cmd_ok                  ; 缓冲区空，处理完
    loop    cmd_accept              ; 缓冲区满，重试

cmd_error:                          ; 超时失败
    mov     ah, 1                   ; 失败返回状态非零
    jmp     cmd_exit

cmd_ok:
    xor     ah, ah                  ; 成功返回零

cmd_exit:
    ret
keyboard_cmd    ENDP

END START
2、PORT 92h

从EISA系统之后，系统控制端口定义了一位用来快速重启的寄存器，就是在PORT 92h的Bit0，这种方式最终结果是和KBC一样的，HOST会拉CPU的INIT#以让系统重启。但这种方式不通过KBC，所以速度更快一点，代码如下：

复制内容到剪贴板
代码:
in al, 92h
IODELAY
or al, 1
out 92h, al
hlt

3、Reset Control Register(Port CF9h)

用此方法控制Reset，各Chip极有可能各芯片产商的做法会不同。

计算机研发论坛,BIOS技术网站,BIOS技术论坛,BIOS SPEC,BIOS手册,BIOS入门,ACPI,SMBIOS,BIOS技术,EC资料,EC开发,PS/2,KBC) f$ w9 t7 X) l) h6 U

这里大家可以认识几种Reset的名词： Platform Reset, PCI Reset, System Reset, Reset CPU.我们来看Intel的文档，如下图：

1.GIF (21.4 KB)

大家注意看，如果System Reset bit位为1，那么如果Reset CPU bit从0变为1时，系统就会产生Platform Reset（包括产生PCI、FWH、SIO、LPC、MCH Reset），即称为Hard Reset；如System Reset bit位为0,那么系统就会产生Soft Reset，即：和KBC/PORT 92h Bit0一样，下拉CPU INIT# 16个PCI Clock。

因此你可以用下如代码Hard Reset：

复制内容到剪贴板
代码:
mov al, 6
mov dx, 0CF9h
out dx, al
jmp $

也可以用如下代码“关机”（看你的机器的做法，也就是对SLP_S3#,SLP_S4#,SLP_S5#的处理）：

复制内容到剪贴板
代码:
mov al, 0Eh
mov dx, 0CF9h
out dx, al
jmp $

4、Ctrl+Alt+Del

这种方法“基本”是在“DOS”下有效，教课书上常称为"热启"。键盘中断会hook住你的按键，Hook就是BIOS的INT 09h软中断，当你按下这三个键时，就相当于Far jmp到 F000:FFF0处。用如下代码在DOS可实现热启动。

复制内容到剪贴板
代码:
jmp F000:FFF0

OK,你对系统重启是否又清楚了一些呢?