Delphi编辑框自动提示完成功能

最新推荐文章于 2021-12-12 19:03:56 发布

无幻

最新推荐文章于 2021-12-12 19:03:56 发布

阅读量7.9k

点赞数 1

分类专栏： 5.2 Delphi编程文章标签： delphi autocomplete shell search class 联想

本文链接：https://blog.csdn.net/akof1314/article/details/6295415

版权

5.2 Delphi编程专栏收录该内容

41 篇文章 0 订阅

订阅专栏

最近在想要使用当鼠标进入编辑框，或者在编辑框输入某个字符就会在编辑框上面或者下面弹出可参考输入内容，就像谷歌搜索框一样，如下图所示：

要想完成这个功能，就必须得需要shell32.dll的支持，涉及到Shell外壳编程，在参考《Delphi深度探索》一书中的《实现AutoComplete》，原文讲述的十分清楚，可以在http://www.biye5u.com/article/prog/dephi/2011/3679.html看到此篇文章。现我把只需要用到的功能整理封装成一个类，如下：

{*******************************************************}  
 {                                                       }  
 {       系统名称 编辑框自动提示完成                     }  
 {       作者网址 http://blog.csdn.net/akof1314          }  
 {       单元名称 UnitAutoComplete.pas                   }  
 {       单元功能 绑定编辑框，使之关联字符串，可联想提示 }  
 {                                                       }  
 {*******************************************************}  
 unit UnitAutoComplete;  
   
 interface  
 uses  
     Windows, Classes, StdCtrls, ActiveX, ShlObj, ComObj;  
 const  
   { IAutoComplete2 options }  
   ACO_NONE = 0;               //无自动完成功能  
   ACO_AUTOSUGGEST = $1;       //自动显示下拉列表  
   ACO_AUTOAPPEND = $2;        //自动添加完成项  
   ACO_SEARCH = $4;            //在下拉列表多一个搜索项  
   ACO_FILTERPREFIXES = $8;    //防止自动完成匹配常用前缀比如"www.", "http://"等  
   ACO_USETAB = $10;           //用TAB键在下拉列表中选择  
   ACO_UPDOWNKEYDROPSLIST = $20; //上下按键可以用来调出下拉列表框  
   ACO_RTLREADING = $40;       //按由右到左的顺序读  
 type  
     TEnumString = class(TInterfacedObject, IEnumString)  
   private  
     FStrings: TStrings;  
     FIndex: Integer;  
   protected  
     { IEnumString }  
     function Next(celt: Longint; out elt; pceltFetched: PLongint): HResult; stdcall;  
     function Skip(celt: Longint): HResult; stdcall;  
     function Reset: HResult; stdcall;  
     function Clone(out enm: IEnumString): HResult; stdcall;  
   public  
     constructor Create(Strings: TStrings);  
   end;  
   
     TAutoComplete = class  
     private  
       //  
     protected  
       //  
     public  
       class procedure EnableAutoComplete(edt: TCustomEdit;sl: TStrings;dwFlag: DWORD);  
   end;  
 implementation  
   
 constructor TEnumString.Create(Strings: TStrings);  
 begin  
   inherited Create;  
   FStrings := Strings;  
 end;  
   
 { TEnumString.IEnumString }  
   
 function TEnumString.Next(celt: Longint;  
   out elt; pceltFetched: PLongint): HResult;  
 var  
   I: Integer;  
 begin  
   I := 0;  
   while (I < celt) and (FIndex < FStrings.Count) do  
   begin  
     TPointerList(elt)[I] := PWideChar(WideString(FStrings[FIndex]));  
     Inc(I);  
     Inc(FIndex);  
   end;  
   if pceltFetched <> nil then pceltFetched^ := I;  
   if I = celt then Result := S_OK else Result := S_FALSE;  
 end;  
   
   
 function TEnumString.Skip(celt: Longint): HResult;  
 begin  
   if (FIndex + celt) <= FStrings.Count then  
   begin  
     Inc(FIndex, celt);  
     Result := S_OK;  
   end  
   else  
   begin  
     FIndex := FStrings.Count;  
     Result := S_FALSE;  
   end;  
 end;  
   
 function TEnumString.Reset: HResult;  
 begin  
   FIndex := 0;  
   Result := S_OK;  
 end;  
   
 function TEnumString.Clone(out enm: IEnumString): HResult;  
 begin  
   try  
     enm := TEnumString.Create(FStrings);  
     Result := S_OK;  
   except  
     Result := E_UNEXPECTED;  
   end;  
 end;  
   
 {-------------------------------------------------------------------------------  
   过程名:    TAutoComplete.EnableAutoComplete  
   功能:      自动完成          
   参数:      edt: TCustomEdit;sl: TStrings;dwFlag: DWORD  
   返回值:    无  
 -------------------------------------------------------------------------------}  
 class procedure TAutoComplete.EnableAutoComplete(edt: TCustomEdit;sl: TStrings;dwFlag: DWORD);  
 var  
   FAutoComplete: IAutoComplete2;  
   FStrings: IUnknown;  
 begin  
   FAutoComplete := CreateComObject(CLSID_AutoComplete) as IAutoComplete2;  
   FStrings := TEnumString.Create(sl) as IUnknown;  
   OleCheck(FAutoComplete.SetOptions(dwFlag));  
   OleCheck(FAutoComplete.Init(edt.Handle, FStrings, nil, nil));  
 end;  
 end.  

要使用的话，只需要调用TAutoComplete.EnableAutoComplete过程就可以了，如下测试：

uses UnitAutoComplete;  
   
 {$R *.dfm}  
   
 procedure TForm1.FormCreate(Sender: TObject);  
 var  
   FStrings: TStrings;  
 begin  
   FStrings := TStringList.Create;  
   FStrings.Add('无幻');  
   FStrings.Add('无幻博客');  
   FStrings.Add('无幻欢迎你');  
   FStrings.Add('CSDN社区');  
   TAutoComplete.EnableAutoComplete(edt1, FStrings, ACO_AUTOSUGGEST + ACO_UPDOWNKEYDROPSLIST);  
 end;  

运行结果如下图所示：

附资料：http://topic.csdn.net/u/20100809/21/8297d1f5-c409-40b1-af07-c0bab9943b1e.html 第17楼C++ Builder实现方式

无幻

关注

1
点赞
踩
6

收藏

觉得还不错? 一键收藏
3
评论
Delphi编辑框自动提示完成功能

最近在想要使用当鼠标进入编辑框，或者在编辑框输入某个字符就会在编辑框上面或者下面弹出可参考输入内容，就像谷歌搜索框一样，如下图所示：要想完成这个功能，就必须得需要shell32.dll的支持，涉及到Shell外壳编程，在参考《Delphi深度探索》一书中的《实现AutoC
复制链接

扫一扫