01分数规划_01分数规划的应用之一—最优比率生成树。洛谷-CSDN博客

[关键字]

0/1分数规划

最优比率生成树

最优比率环

[定义]

01分数规划问题：所谓的01分数规划问题就是指这样的一类问题，给定两个数组，a[i]表示选取i的收益，b[i]表示选取i的代价。如果选取i，定义x[i]=1否则x[i]=0。每一个物品只有选或者不选两种方案，求一个选择方案使得R=sigma(a[i]*x[i])/sigma(b[i]*x[i])取得最值，即所有选择物品的总收益/总代价的值最大或是最小。

01分数规划问题主要包含一般的01分数规划、最优比率生成树问题、最优比率环问题等。我们将会对这三个问题进行讨论。

永远要记得，我们的目标是使R取到最值，本文主要讨论取到最大值的情况。这句话我会在文中反复的强调。

[一些分析]

数学分析中一个很重要的方法就是分析目标式，这样我们来看目标式。

R=sigma(a[i]*x[i])/sigma(b[i]*x[i])

我们来分析一下他有什么性质可以给我们使用。

我们先定义一个函数F(L):=sigma(a[i]*x[i])-L*sigma(b[i]*x[i])，显然这只是对目标式的一个简单的变形。分离参数，得到F(L):=sigma((a[i]-L*b[i])*x[i])。这时我们就会发现，如果L已知的话，a[i]-L*b[i]就是已知的，当然x[i]是未知的。记d[i]=a[i]-L*b[i]，那么F(L):=sigma(d[i]*x[i])，多么简洁的式子。我们就对这些东西下手了。

再次提醒一下，我们的目标是使R取到最大值。

我们来分析一下这个函数，它与目标式的关系非常的密切，L就是目标式中的R，最大化R也就是最大化L。

F的值是由两个变量共同决定的，即方案X和参数L。对于一个确定的参数L来说，方案的不同会导致对应的F值的不同，那么这些东西对我们有什么用呢?

假设我们已知在存在一个方案X使得F(L)>0，这能够证明什么?

F(L)=sigma(a[i]*x[i])-L*sigma(b[i]*x[i])>0即sigma(a[i]*x[i])/sigma(b[i]*x[i])>L也就是说，如果一个方案使得F(L)>0说明了这组方案可以得到一个比现在的L更优的一个L，既然有一个更优的解，那么为什么不用呢？

显然，d数组是随着L的增大而单调减的。也就是说，存在一个临界的L使得不存在一种方案，能够使F(L)>0. 我们猜想，这个时候的L就是我们要求的最优解。之后更大的L值则会造成无论任何一种方案，都会使F(L)<0.类似于上面的那个变形，我们知道，F(L)<0是没有意义的，因为这时候的L是不能够被取得的。当F(L)=0使，对应方案的R值恰好等于此时的L值。

综上，函数F(L)有这样的一个性质：在前一段L中可以找到一组对应的X使得F(L)>0，这就提供了一种证据，即有一个比现在的L更优的解，而在某个L值使，存在一组解使得F(L)=0,且其他的F(L)<0，这时的L无法继续增大，即这个L就是我们期望的最优解，之后的L会使得无论哪种方案都会造成F(L)<0.而我们已经知道，F(L)<0是没有任何意义的，因为此时的L值根本取不到。

最后一次提醒，我们的目标是R！！！

如果现在你觉得有些晕的话，那么我要提醒你的就是，千万不要把F值同R值混淆。F值是根据我们的变形式求的D数组来计算的，而R值则是我们所需要的真实值，他的计算是有目标式决定的。F值只是提供了一个证据，告诉我们真正最优的R值在哪里，他与R值本身并没有什么必然的联系。

根据这样的一段性质，很自然的就可以想到二分L值，然后验证是否存在一组解使得F(L)>0，有就移动下界，没有就移动上界。

所有的01分数规划都可以这么做，唯一的区别就在于求解时的不同--因为每一道题的限制条件不同，并不是每一个解都是可行解的。比如在普通的数组中，你可以选取1、2、3号元素，但在生成树问题中，假设1、2、3号元素恰好构成了一个环，那就不能够同时选择了，这就是需要具体问题，具体分析的部分。

二分是一个非常通用的办法，但是我们来考虑这样的一个问题，二分的时候我们只是用到了F(L)>0这个条件，而对于使得F(L)>0的这组解所求到的R值没有使用。因为F(L)>0,我们已经知道了R是一个更优的解，与其漫无目的的二分，为什么不将解移动到R上去呢？求01分数规划的另一个方法就是

，他就是基于这样的一个思想，他并不会去二分答案，而是先随便给定一个答案，然后根据更优的解不断移动答案，逼近最优解。由于他对每次判定使用的更加充分，所以它比二分会快上很多。但是，他的弊端就是需要保存这个解，而我们知道，有时候验证一个解和求得一个解的复杂度是不同的。二分和Dinkelbach算法写法都非常简单，各有长处，大家要根据题目谨慎使用。

[实践]

上面啰嗦了这么多，现在给出程序的框架。

二分法

L:=...;R:=...;

Repeat

  Mid:=(L+R)/2;

  For I=1..X do D[i]:=A[i]-Mid*B[i];//根据Mid计算D数组

Dinkelbach算法-

L:=随便什么东西;
Repeat
  Ans:=L;
  For I=1..X do D[i]:=A[i]-L*B[i];//根据L计算D数组
  检查解并记录;
  p:=0;q:=0;
  for I=每一个元素 do 
     如果元素I在解中
        begin
          p:=p+A[i];q:=q+B[i];
        end;
  L:=p/q;//更新解
Until abs(Ans-L)<Eps;

其中检查解的部分是要看具体情况的。

[例题1Poj2976Dropping tests--普通的01分数规划]

大意：给定A数组B数组，从中选择N-K个使得R最大，输出Round(100*R);

分析：限制很简单，只是数目上有所限制，处理方法也很简单，求出D数组后从大到小排列，从先前向后取N-K个即可，这时的D一定是最大的。

代码：

二分代码 110MS 1 //10147353      perseawe        2976    Accepted        896K    110MS   Pascal  1517B   2012-05-03 10:09:47

Const
  Eps=1e-6;

Var
  n,k:Longint;
  Ans:Double;
  a,b,c:Array [0..1000+100] of Longint;
  d:Array [0..1000+100] of Double;

Procedure Init;
  var
    i:longint;
  begin
    readln(n,k);
    if (n=0)and(k=0) then Halt;
    for i:=1 to n do read(a[i]);readln;
    for i:=1 to n do read(b[i]);readln;
  end;

procedure swap(var a,b:Longint);var t:Longint;begin t:=a;a:=b;b:=t;end;
procedure swap(var a,b:double);var t:Double;begin t:=a;a:=b;b:=t;end;

Procedure Qsort(l,r:Longint);
  var
    a,b:Longint;
    mid:Double;
  begin
    a:=l;b:=r;mid:=d[(l+r) shr 1];
    repeat
      while d[a]>mid do inc(a);
      while d[b]<mid do dec(b);
      if a<=b then
        begin
          swap(d[a],d[b]);
          swap(c[a],c[b]);
          inc(a);dec(b);
        end;
    until a>=b;
    if a<r then qsort(a,r);
    if l<b then qsort(l,b);
  end;

Procedure Main;
  var
    m,i:Longint;
    L,R,Mid,tmp:Double;
  begin
    //2'
    m:=n-k;

    Mid:=0;
    for i:=1 to n do if a[i]/b[i]>Mid then Mid:=a[i]/b[i];
    L:=0;R:=Mid;

    Repeat
      Mid:=(L+R)/2;
      for i:=1 to n do begin d[i]:=a[i]-Mid*b[i];c[i]:=i;end;
      Qsort(1,n);
      tmp:=0;
      for i:=1 to m do tmp:=tmp+d[i];
      if tmp>0 then L:=Mid else R:=Mid;
    Until abs(L-R)<Eps;
    Ans:=L;
  end;

Procedure Print;
  begin
    writeln(Round(Ans*100));
  end;

Begin
  While True Do
    begin
      Init;
      Main;
      Print;
    end;
End.

Dinkelbach代码 32MS 1 //10147329      perseawe        2976    Accepted        896K    32MS    Pascal  1455B   2012-05-03 10:02:32

Const
  Eps=1e-6;

Var
  n,k:Longint;
  Ans:Double;
  a,b,c:Array [0..1000+100] of Longint;
  d:Array [0..1000+100] of Double;

Procedure Init;
  var
    i:longint;
  begin
    readln(n,k);
    if (n=0)and(k=0) then Halt;
    for i:=1 to n do read(a[i]);readln;
    for i:=1 to n do read(b[i]);readln;
  end;

procedure swap(var a,b:Longint);var t:Longint;begin t:=a;a:=b;b:=t;end;
procedure swap(var a,b:double);var t:Double;begin t:=a;a:=b;b:=t;end;

Procedure Qsort(l,r:Longint);
  var
    a,b:Longint;
    mid:Double;
  begin
    a:=l;b:=r;mid:=d[(l+r) shr 1];
    repeat
      while d[a]>mid do inc(a);
      while d[b]<mid do dec(b);
      if a<=b then
        begin
          swap(d[a],d[b]);
          swap(c[a],c[b]);
          inc(a);dec(b);
        end;
    until a>=b;
    if a<r then qsort(a,r);
    if l<b then qsort(l,b);
  end;

Procedure Main;
  var
    p,q:Int64;
    m,i:Longint;
    L:Double;
  begin
    //Dinkelbach
    m:=n-k;
    l:=1;
    Repeat
      Ans:=L;
      for i:=1 to n do begin d[i]:=a[i]-L*b[i];c[i]:=i;end;
      Qsort(1,n);
      p:=0;q:=0;
      for i:=1 to m do
        begin
          inc(p,a[c[i]]);
          inc(q,b[c[i]]);
        end;
      L:=p/q;
    Until abs(L-Ans)<Eps;
  end;

Procedure Print;
  begin
    writeln(Round(Ans*100));
  end;

Begin
  While True Do
    begin
      Init;
      Main;
      Print;
    end;
End.

另外：如果是最小选择N-K个怎么办？办法是一样的，从大到小排列序，傻子才多选，能少裑就少选。反正F值具体的大小没什么关系，我们只要知道他与0的关系即可。

[例题2Poj2728Desert King--最优比率生成树]

大意：给定一张图，每条边有一个收益值和一个花费值，求一个生成树，要求花费/收益最小，输出这个值

分析：现在的限制就有点复杂了，要求解必须是一棵生成树。而且这道题目要求的花费/收益最小，当然你求收益/花费最大然后反过来也是可以的，注意处理花费为0的情况。如果求最小的，处理方法是也类似的，先求个D，然后做一次最小生成树，显然得到的就是函数值。不过这道题用Dinkelbach比二分好的多。

Dinkelbach代码  1 //10148420      perseawe        2728    Accepted        916K    407MS   Pascal  1560B   2012-05-03 16:03:10

Const
  Eps=1e-6;
  MaxN=1000+100;

Var
  n:Longint;
  ans:Double;
  x,y,h:Array [0..MaxN] of Longint;
  Use:Array [0..MaxN] of Boolean;
  a,b,d:Array [0..MaxN] of Double;

Procedure Init;
  var
    i:Longint;
  begin
    readln(n);
    if n=0 then Halt;
    for i:=1 to n do readln(x[i],y[i],h[i]);
  end;

Procedure Main;
  var
    i,m,pos:Longint;
    L,tmp,ta,tb,p,q:Double;
  begin
    L:=0;
    Repeat
      Ans:=L;
      //Prim
      Fillchar(Use,sizeof(Use),False);Use[1]:=True;
      For i:=2 to n do
        begin
          a[i]:=abs(h[i]-h[1]);
          b[i]:=sqrt(sqr(x[i]-x[1])+sqr(y[i]-y[1]));
          d[i]:=a[i]-L*b[i];
        end;
      m:=1;p:=0;q:=0;
      While m<n do
        begin
          tmp:=1000000000;
          for i:=2 to n do
            if not(Use[i])and(d[i]<tmp) then
              begin
                tmp:=d[i];pos:=i;
              end;
          Use[pos]:=true;p:=p+a[pos];q:=q+b[pos];
          for i:=2 to n do
            if not(Use[i]) then
              begin
                ta:=abs(h[i]-h[pos]);tb:=sqrt(sqr(x[i]-x[pos])+sqr(y[i]-y[pos]));
                if ta-L*tb<d[i] then
                  begin
                    d[i]:=ta-L*tb;
                    a[i]:=ta;b[i]:=tb;
                  end;
              end;
          Inc(m);
        end;
      L:=p/q;
    Until abs(L-Ans)<Eps;
  end;

Procedure Print;
  begin
    writeln(ans:0:3);
  end;

Begin
  while True Do
    begin
      Init;
      Main;
      Print;
    end;
End.

最小生成树用了Prim，只要不是实在没办法，还是不要在稠密图特别是完全图上用Kruskal吧。

[例题3Poj3621Sightseeing Cows--最优比率环]

大意：给定一张图，边上有花费，点上有收益，点可以多次经过，但是收益不叠加，边也可以多次经过，但是费用叠加。求一个环使得收益和/花费和最大，输出这个比值。

分析：比上面更加的恶心了。先不说环的问题，就是花费和收益不在一处也令人蛋疼。这时候需要用到几个转化和结论。

首先的一个结论就是，不会存在环套环的问题，即最优的方案一定是一个单独的环，而不是大环套着小环的形式。这个的证明其实非常的简单，大家可以自己想一下（提示，将大环上的收益和记为x1,花费为y1，小环上的为x2,y2。重叠部分的花费为S。表示出来分类讨论即可）。有了这个结论，我们就可以将花费和收益都转移到边上来了，因为答案最终一定是一个环，所以我们将每一条边的收益规定为其终点的收益，这样一个环上所有的花费和收益都能够被正确的统计。

解决了蛋疼的问题之后，就是01分数规划的部分了，我们只需要计算出D数组后找找有没有正权环即可，不过这样不太好，不是我们熟悉的问题，将D数组全部取反之后，问题转换为查找有没有负权环，用spfa或是bellman_ford都可以。这道题目就是典型的不适合用Dinkelbach，记录一个负权环还是比较麻烦的，所以二分搞定。

二分代码 1 //10148804      perseawe        3621    Accepted        1000K   422MS   Pascal  1239B   2012-05-03 17:17:40

Const
  Eps=1e-6;
  MaxNode=1000+100;
  MaxEdge=5000+500;

Var
  Ans:Double;
  n,m:Longint;
  a:Array [0..MaxNode] of Longint;
  dis:array [0..MaxNode] of Double;
  b,u,v:Array [0..MaxEdge] of Longint;
  d:Array [0..MaxEdge] of Double;

Procedure Init;
  var
    i:Longint;
  begin
    readln(n,m);
    for i:=1 to n do readln(a[i]);
    for i:=1 to m do readln(u[i],v[i],b[i]);
  end;

Function Bellman_Ford(L:Double):Boolean;
  var
    i,j:Longint;
    Flag:Boolean;
  begin
    for i:=1 to m do d[i]:=-(a[v[i]]-L*b[i]);
    for i:=1 to n do dis[i]:=0;
    for i:=1 to n do
      begin
        Flag:=False;
        for j:=1 to m do
          if Dis[u[j]]+d[j]<Dis[v[j]] then
            begin
              Dis[v[j]]:=Dis[u[j]]+d[j];
              Flag:=True;
            end;
        If not(Flag) then Exit(False);
      end;
    Exit(True);
  end;

Procedure Main;
  var
    L,R,Mid:Double;
  begin
    L:=0;R:=20000;
    Repeat
      Mid:=(L+R)/2;
      if Bellman_Ford(Mid) then L:=Mid else R:=Mid;
    Until abs(L-R)<Eps;
    Ans:=L;
  end;

Procedure Print;
  begin
    if Ans>Eps then writeln(Ans:0:2) else writeln(0);
  end;

Begin
  Init;
  Main;
  Print;
End.

因为图省事，所以用了Bellman_Ford。还有就是注意无解的判断，无解时检查会一直不成功的，你懂的。

[后记]

本来Zoj上还有一道题的，时间不够了就先放过去吧，但是常见的三种01规划我都已经列举到了并给出了常见的处理手段。

算法运用之妙,存乎一心也。数学是最神奇的。强烈建议大家学好数学！

本来还有一个例题0和一个非常巧妙的数学证明的，但是发觉没有什么太大的意义，就省略掉了。大意就是给定A数组和B数组（A、B的元素值都大于0），最小取一个，求最大的R值。显然直接计算所有的A[i]/B[i]取最大值就可以，因为两个分数分子分母对应相加得到的结果一定是小于较大的那个。具体的证明很简单，分类讨论即可。

另一个被我省略的部分就是对Dinkelbach算法的分析，这需要更强的数学分析才行，因为这并不是重点，所以我将其省略掉了。如果有兴趣的同学可以找一下一篇叫做《对于0-1分数规划的Dinkelbach算法的分析》，由武钢三中吴豪[译]的一篇文章看一下。

最后感谢网上很多大牛的题解和心得，特别是This_poet的题解，第一二题中参考了她的代码，几乎已经是Copy了，见谅。>_<

欢迎大家拍砖讨论，具体看背景。http://www.haogongju.NET/art/1426981

----------------Update：2012年5月10日--------------

[例题4Poj3155--Hard Life最大密度子图]

大意：给定G=(V,E)求其中的一个子图使得边数/点数最大

分析：详见《最小割模型在信息学竞赛中的应用》作者胡伯涛。

----------------Update：2012年6月19日--------------

[例题5Zoj2676--Network Wars]

大意：给定一张图，规定一个割的平均值是边权和/边数.求平均值最小的割.

分析：非常显然，因为是求最小，所以只要对于某个L值，解空间中最小的一组解满足g(x)=0即可。于是，二分L后改变权值求解最小割。但是会出现负权的情况，这里需要特殊处理。负权是一定会出现在解中的，遇到负权直接加上即可。如果最小割<0则L增大,反之减少.还有就是注意精度的问题，小心处理。

[例题6游戏--最大密度子图变种]

大意：给定N个人，可以选择任意多个人，记为K。单个人是没有战斗力的，必须要合体才有战斗力（大雾），给定所有的Aij表示当选择方案同时出现i和j两个人时的战斗力加成。特殊的Aii=0。但是选择人不是没有代价的，代价是k*(200-k).定义这个方案的评分=sigma(A[i,j]|if i,j both selected)/(k*(200-k))。要求最大化评分。

N<=50...也就是满足选择的人越多代价越多.

分析：显然是一个最大密度子图的模型。但是与一般的模型中，表达式中的分母不仅仅含有点数，更含有一个点数的平方。这是令人非常难受的。问题的核心就在于如何将这个平方蕴含到图里面去。观察到这个图非常的特殊，当选择一些点时，这些点构成的子图是一个完全图，即边数是K*(K-1)/2.哈哈，这里也有一个K的平方，于是问题得以解决了。二分L后整理表达式，将分母上的K的平方蕴含到边权上去。这样就可以转化为一般的最大密度子图。

[一些理解]

从这篇文章写出来到现在也已经很长时间了，对01分数规划问题也有了很多新的看法。

以下是一些个人的理解，很有可能存在错误。大家帮忙看看有没有问题。

01分数规划问题求最值，但是最值有两种，一种是最大值，一种是最小值。

在我看来，对于每一个L。我们先假定L是确定了的，这时问题还会有很多的方案，每一个方案有其评估值。我们求最小值时是找这样的一个L:所有的合法方案中，只有唯一的一个方案评估值为0，其他的方案评估值都>0.而最大值恰好相反，即也是只有唯一的一个方案评估值为0，但是其他的方案评估值都<0.

在上面的推导中，我已经说过了，当存在评估值>0的方案时，说明L是可以增大的。因为计算方案对应的原始表达式值计算出的L'一定是大于L的，同理，而评估值<0的方案则是不优的。

虽然题目要求的东西会不同，生成树呀，割呀，子图之类的呀。但是我觉得上面的这个东西是一个通用的玩意，是01分数规划本身决定的，而不是题目决定的。我现在还是有一个概念不是特别明白。先写到这里，欢迎讨论。

----------------Update：2012年7月27日----------------------------

[例题7Poj3266--CowSchool0/1分数规划+数据结构]

大意:(From applepi)

Bessie考了N科（N≤50000），每科的得分为Ti，满分为Pi（样例似乎是五科红灯……）。现在Bessie的老师要给她们统计最终得分，方法是先算出每一科得分的百分比，去除D个百分比最低的科目，然后剩下科目的∑T / ∑P就是最终得分的百分比。很幸运，没有人有两科的得分比一样。Bessie的数学很牛X，她马上就发现她的老师在坑爹，因为有时候可以通过去除不同的科目来获得更高的分数。现在Bessie想知道，对于哪些D值，她可以通过去除与老师不同的D科，从而获得更高的分数呢？

题解：显然,Bessie的老师没有看过这篇文章(>_<)。要不他（她）就不会犯这么意识流的问题了。现在题目要求我们给出一个"证据"来证明那些D老师的做法并不是最优的.由上面的一些结论，我们可以知道，只要我们能够找到在老师给定的百分比下的一组解，其值>0即可,这就证明了存在一个百分比要优于老师的解.这时我们可以用一个巧妙的转化,显然,老师选定的解在加权之后的和一定是0.那么,一个简单的构造方法是找出老师选定中的最小加权值以及没选定的中最大的加权值,如果后者大于前者,那么显然将前者更换为后者得到的解值>0，说明存在更优的解。然后这样的一个问题可以把每一个分数看做平面上的一个点，用平衡树维护凸壳或是充分挖掘单调性后使用栈和队列来维护都是可以快速的完成查找操作的。具体见applepi的题解就好。

这道题就把01分数规划作为一个工具，要求挖掘更加符合这个题目的特性，还是很难的。说实话，这道题是Poj上Usaco题目中最难的一道题目了。