解读 .NET 中的重写与重载

转载 2012年03月31日 11:34:18
很多人对“重写”和“重载”这两个概念都很模糊,甚至把它们弄混淆。我们都知道,面向对象语言的四大特征是:抽象、封装、继承和多态。而重写和重载是多态的两种表现形式。多态,顾名思义,就是指多种形态。而重写和重载正好体现了这一点。现在我们以 VB.NET 语言来说明两者的区别。


        重写是发生在父类与子类之间的关系。具体来讲就是子类可以重写父类的现有的方法。它要求子类的方法名称及参数必须与父类完全一致。比如吃饭,父亲可以吃两碗面,孩子同样也是吃面,却只能吃一碗。

        重载则主要是发生在同一个类当中的,它通过多个名称相同的方法,但方法参数不相同,或者方法返回类型不相同来加以区别。其中,方法参数不相同包括以下几种情况:参数的个数不相同,参数的类型不相同,参数的对应位置不相同。需要说明的是,重载同样可以应用到父类与子类当中。即子类重载了父类的方法。

重写:

        在 VB.NET 中,重写汲及到的关键字有:
                OverRidable: 在父类中声明的可以在子类中重写的方法。
                OverRides: 在子类中声明的要重写父亲中可重写的方法。
                MustOverRide: 在父类中,表示这个方法必须在子类中重写。此时,该类必须声明为抽象类。
                NotOverridable: 如果当前类还有子类,那么,在其子类中,该方法不允许被重写。

        下面通过一个例子来认识它们的作用。


'本例中我们声明了三个类,分别代表三种对象:人,父亲,儿子。儿子继承自父亲,父亲又继承自人。

'声明一个抽像类
Public MustInherit Class People
    '它包括一个抽象方法,这个方法必须要在其子类中被实现(重写)
    Public MustOverride Sub Eat(ByVal FoodName As String, ByVal num As Integer)
End Class

'声明父亲类,继承自 Person 类
Public Class Father : Inherits People
   '重写 Person 的抽象方法,这是必须的。
    Public Overrides Sub Eat(ByVal FoodName As String, ByVal num As Integer)
        Console.WriteLine("父亲吃{0},他可以吃{1}碗!", FoodName, num)
    End Sub

    '声明一个可被重写的函数,用 OverRidable 关键字
    Public Overridable Function GetMyName() As String
        Return "父亲"
    End Function

    '声明另外一个方法,用来说明子类中使用 NotOverRidable
    Public Overridable Sub ShowMyFatherClass()
        Console.WriteLine("我的父类是 People")
    End Sub
End Class

'声明儿子类,继承自 Father
Public Class Son : Inherits Father

    '子类重写 Father 类的 Eat 方法,这里有两点要说明:
    '1. Son 类作为 People 子类(Father)的子类,它不必一定要重写抽象方法。
    '     换句话说,抽象类的抽象方法,只需要在其直接子类中强制实现,而不用
    '     在它的除直接子类之外的其它子类(可看作是“孙类”)中实现。

    '2. 在 Father 类中的 Eat 方法标记为 OverRides,它包括了两层含义:(1).它重写
    '     了抽象父类中的抽象方法; (2). 这个方法可以在其子类中被隐式重写。因此,
    '      它不包括 OverRidable 这个关键字,而其子类 Son 就可以对这个方法重写

    Public Overrides Sub Eat(ByVal FoodName As String, ByVal num As Integer)
        Console.WriteLine("孩子吃{0},他能吃{1}碗!", FoodName, num)
    End Sub

    '重写父类中被声明为 OverRidable 的方法,重写时用关键字 OverRides
    Public Overrides Function GetMyName() As String
        '如果要使用父类的实现过程,则使用 MyBase 关键字
        'Return MyBase.GetMyName()

        Return "孩子"
    End Function

    '如果 Son 类还有子类,那么下面这个方法不可以在其子类中被重写,因为它被声明
    '为 NotOverridable。这里有一点要注意:
    '如果一个方法被声明为 NotOverRidable,那么它也同时必须被声明为 OverRides

    Public NotOverridable Overrides Sub ShowMyFatherClass()
        Console.WriteLine("我的父类是 Father")
    End Sub
End Class

重载:


        在 VB.NET 中,重载用到的关键是 OverLoads。请看如下代码:

    Public Sub ShowMySelf(ByVal Name As String)

    Public Sub ShowMySelf(ByVal Name As String, ByVal Age As Integer)

    Public Sub ShowMySelf(ByVal Name As String, ByVal Age As Integer, ByVal Sex As String)


    Public Overloads Function GetMyInfo() As String

    Public Overloads Function GetMyInfo(ByVal MyID As Integer) As String

        这里需要说明几点:

        1. 对于在同一类当中,一组名称相同的方法或函数重载时,可以加关键字 OverLoads 或者不加。但如果其中有一个方法加上,那同组其它方法也必须加该关键字。

        2. 如果该方法是重载父类中的方法。那么必须加 OverLoads 关键字。

        3. 如果两个同名函数仅返回类型不相同,则它们不能重载,即必须在参数上有所不同。


相关文章推荐

ASP.NET方法如何重载

决定方法是否构成重载有以下几个条件:   ◆ 在同一个类中; ◆ 方法名相同; ◆ 参数列表不同。     在设计重载方法的时候应该注意一下事项   1  避免随意更改重载中的参数名称。如果某个重载的...

重载asp.net的dropdownlist控件,使其支持样式和空格的一点改进

参考:http://kb.cnblogs.com/a/391555/这个代码很好用,让呆板的DropDownList可以添加漂亮的样式,并且支持空格.也很有代表性,可以让大家举一反三,灵活使用其他as...

VB.net学习笔记(八)重载与共享

gg

.NET内存中动态构造类并重载某函数

开发中,经常需要用到很多容器功能,而容器级别的功能大都是Reflection(类反射)所提供的,本文就是借这个名来看看如何在.NET 内存中动态构造类并重载某函数,具体的例子代码如下:原类:TestC...

VB.NET之旅(六)—重载与隐藏

大李坐在转椅上左右晃动着,手中的一个硬币在他指间灵巧地翻滚着。“hi, Henry。你对重写与重载的意思理解是怎么样的呢?”   我正盯着他手中的硬币发愣呢,“哦,重写,就是您刚才举的示例中,在派生...

.NET-Dictionary索引重载 赋值时允许Key不存在

看到同事的一段代码,我认为其写法不安全,Key赋值前没有判断Key是否存在,但而我同事坚持认为这没问题。为方便说明我将代码简化成如下static void Main(string[] args) { ...

vb.net方法重载

自己理解的方法重载就是,同一个类中多次声明相同名字的方法,每次声明时都是不同的参数列表。方法重载主要是为了实现同一个功能,而使用统一的方法处理不同的数据类型。它是多样性在同一类中的一种表现。而且方法重...

黑马程序员--.NET笔记--枚举、数组、排序、方法、变量的作用域、重载

---------------------- ASP.Net+Android+IO开发S、.Net培训、期待与您交流! ----------------------   常量: 语法:const...
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:深度学习:神经网络中的前向传播和反向传播算法推导
举报原因:
原因补充:

(最多只允许输入30个字)