flex_如何创建自定义事件示例;

原创 2012年03月22日 16:43:32

功能:从xml文件中加载数据,然后在list组件上显示出数据来。

=>userContent.xml文件

<?xml version="1.0" encoding="UTF-8"?>
<users>
    <user name="唐龙" site="http://www.tanglong.com"/>
    <user name="楚源" site="http://www.chuyuan.com"/>
    <user name="徐泽" site="http://www.xuze.com"/>
    <user name="罗锋" site="http://www.luofeng.com"/>
    <user name="韩立" site="http://www.hanli.com"/>
</users>


=>ContentEvent.as自定义事件文件

// 自定义事件以便用于数据传输等等;
package net.events
{
    import flash.events.Event;
    
    import mx.collections.ArrayCollection;
    
    public class ContentEvent extends Event
    {
        // 声明事件类型_事件引用中使用的事件常量。
        public static const DATA_BACK:String = "dataBack";
        public static const DATA_ERROR:String = "dataError";
        
        // 自定义事件数据属性。
        public var users:ArrayCollection;
        public var errors:String;
        
        public function ContentEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false)
        {
            super(type, bubbles, cancelable);
        }
        
        /*
        *覆盖此clone()函数说明:由于这个类只是一个基本框架,而所有自定义事件都应该重写Event.clone()方法。
        *如果没有重写该方法,但是事件被克隆,那么自定义数据就无法包含到克隆的事件中,这就意味着克隆的副本
        *与原始事件不一致。该方法只是创建事件的一个新实例,并按照当前属性设置新实例的属性,实际上就是事件
        *的一个完整克隆。
        */
        override public function clone():Event{
            var event:ContentEvent = new ContentEvent(type, bubbles, cancelable);
            event.users = users;
            event.errors = errors;
            return event;
        }
    }
}


=>DataLoader.as加载数据类

package net
{
    import flash.events.ErrorEvent;
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.IEventDispatcher;
    import flash.events.IOErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    
    import mx.collections.ArrayCollection;
    
    import net.events.ContentEvent;    // 自定义事件;
    
    
    /* 添加事件元数据,以便在MXML应用程序中可以这样使用:
     * <fx:Declarations>
     *         <net:DataLoader id="dataLoader" dataBack="onData(event)" dataError="onError(event)"/>
     * </fx:Declarations>
     */
    [Event(name="dataBack", type="net.events.ContentEvent")]
    [Event(name="dataError", type="net.events.ContentEvent")]
    /**
     * 类功能:加载数据、分派完成和错误事件;
     */
    public class DataLoader extends EventDispatcher
    {
        protected var _loader:URLLoader;
        
        public function DataLoader(target:IEventDispatcher=null)
        {
            super(target);
            
            _loader = new URLLoader();
            _loader.addEventListener(Event.COMPLETE, onComplete);    // 数据加载完成后调用。
            _loader.addEventListener(IOErrorEvent.IO_ERROR, onError);    // 不能加载数据时调用;
            _loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onError);
        }
        
        public function load(url:String):void{
            _loader.load(new URLRequest(url));
        }
        
        protected function onComplete(event:Event):void{
            var users:ArrayCollection = new ArrayCollection();
            for each(var user:XML in XML(_loader.data).user) {
                users.addItem(user.@name + "_" + user.@site);
            }
            
            
            // 创建并分派自定义完成事件。
            var customEv:ContentEvent = new ContentEvent(ContentEvent.DATA_BACK);
            customEv.users = users;
            dispatchEvent(customEv);
        }
        
        protected function onError(event:ErrorEvent):void{
            // 创建并分派自定义错误事件。
            var customEv:ContentEvent = new ContentEvent(ContentEvent.DATA_ERROR);
            customEv.errors = event.text;
            dispatchEvent(customEv);
        }
        
    }
}


=>UsersView.mxml应用程序

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark"
               xmlns:mx="library://ns.adobe.com/flex/mx"
               minWidth="1024" minHeight="768" pageTitle="用户信息列表"
               applicationComplete="initFn()" xmlns:net="net.*">
    
    <fx:Script>
        <![CDATA[
            import net.DataLoader;
            import net.events.ContentEvent;
            
            protected function initFn():void{
                var dataLoader:DataLoader = new DataLoader();
                dataLoader.addEventListener(ContentEvent.DATA_BACK, onData);
                dataLoader.addEventListener(ContentEvent.DATA_ERROR, onError);
                dataLoader.load("net/data/userContent.xml");
            }
            
            protected function onData(event:ContentEvent):void{
                userlist.dataProvider = event.users;
            }
            
            protected function onError(event:ContentEvent):void{
                trace("=>Error: " + event.errors);
            }
        ]]>
    </fx:Script>
    
    <fx:Declarations>
        <!-- 非可视元素 -->
    </fx:Declarations>
    
    <!--view-->
    <s:VGroup verticalCenter="0" horizontalCenter="0">
        <s:List id="userlist" width="250" height="120"/>
    </s:VGroup>
    
</s:Application>

提醒:只要复制粘贴就可以运行,唯一要注意的就是文件结构:


按照上边文件结构组织文件或者自己修改相关文件目录就ok。


相关文章推荐

Flex4自定义事件

1、自定义事件 2、自定义带参数的事件         刚到公司上班没多久,事情不是太多。打酱油的成分占据大多时间。闲着没事学习下Flex。在这之前没有接触过Flex。在理解上面多有拙劣之处。重在...

Flex组件组件添加自定义事件

自定义组件如下:com.cp2

Flex组件组件添加自定义事件

自定义组件如下:com.cp2

【以前的日志】Flex 组件控件加载顺序心得

http://hi.baidu.com/flexvsjava/blog/item/1b400a259152be09918f9d87.html 学过面向对象编程的人,对FLEX都会,有一些很熟悉的感触...

Flex/AS3/flash player支持屏蔽右键菜单,自定义菜单,并设置相应的菜单事件(示例,图解)

该文同步至http://www.waylau.com/217/     播放器 版本 11.2以后支持右键菜单屏蔽及自定义菜单 1.更新播放器 ,11.2 以上版本 http...

flex自定义组件事件DEMO

  • 2014年11月18日 21:49
  • 2.41MB
  • 下载

flex 事件与自定义事件

  • 2010年07月26日 09:59
  • 751KB
  • 下载

flex自定义事件(包括DispatchEvent与addEventListener)传参

在网上查了一会,用常用的自定义事件的方式,有时候进行传参、监听和发送貌似不成功。所自己找了一些资料,自己写了一个自定义 的事件,直接使用自身的DispatchEvent和监听addeventliste...
  • ttbat
  • ttbat
  • 2013年07月31日 11:23
  • 1394

Flex中自定义事件

      xmlns:s="library://ns.adobe.com/flex/spark"       xmlns:mx="library://ns.adobe.com/flex/mx" mi...
  • xyylchq
  • xyylchq
  • 2011年03月24日 15:58
  • 608

Flex4中的自定义事件(转)

1.方式一:通过继承Event类编写Flex4的自定义事件 下面我们来做一个例子,实现这样的功能:监控TextInput的输入,通过监控输入的内容,触发不同的自定义事件。 我们先来写这个自定义事件...
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:flex_如何创建自定义事件示例;
举报原因:
原因补充:

(最多只允许输入30个字)