用Socket做简单聊天程序(VB.net)

原创 2006年05月18日 15:35:00

有位网友发贴问我一个聊天的问题,不好拒绝;也看到最近VB.net版问这个的人很多,就写了一个放在这里。

本例只适合初学用Socket编程的人,因而力求简单,让老鸟见笑了J

另本示例用的是vs2005

1、服务端

Imports System.Net

Imports System.Net.Sockets

Imports System.Threading

Imports System.Text

Imports System.Diagnostics

 

Public Class frmServer

 

    '服务端的Socket

    Dim listener As Socket

    '与客户端会话的Socket

    Dim mySocket As Socket

    '服务端的运行状态

    Dim IsRun As Boolean = False

    '监听接收数据线程

    Dim myThread As Thread

 

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        myThread = New Thread(AddressOf Listen)

        myThread.Start()

    End Sub

 

    Public Sub Listen()

        Dim bytes() As Byte = New [Byte](1024) {}

        Dim data As String = String.Empty

        Dim tokens() As String

 

        Dim localEndPoint As New IPEndPoint(Net.IPAddress.Parse("127.0.0.1"), 11000)

        '初始化socket

        listener = New Socket(AddressFamily.InterNetwork, SocketType.Stream, ProtocolType.Tcp)

        '绑定端口

        listener.Bind(localEndPoint)

        '开始监听

        listener.Listen(10)

 

        BeginInvoke(New EventHandler(AddressOf AddInfo), "服务端已启动,正在等待连接......")

 

        mySocket = listener.Accept()

        IsRun = True

 

        While True

            Dim bytesRec As Integer = mySocket.Receive(bytes)

            data = Encoding.UTF8.GetString(bytes, 0, bytesRec)

 

            tokens = data.Trim.Split("|")

            Select Case tokens(0) '分析接收到的数据,可自己定义更多一些

                Case "Chat"

                    BeginInvoke(New EventHandler(AddressOf AddInfo), tokens(1))  'Invoke保证线程安全

                Case "Exit"

                    IsRun = False

                    BeginInvoke(New EventHandler(AddressOf AddInfo), tokens(1))  'Invoke保证线程安全

                    mySocket.Shutdown(SocketShutdown.Both)

                    mySocket.Close()

                    Exit Sub

            End Select

        End While

 

    End Sub

 

    '发送信息

    Private Sub btnSend_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnSend.Click

        Dim msg As Byte() = Encoding.UTF8.GetBytes("Chat|" + TextBox1.Text)

        mySocket.Send(msg)

        ListBox1.Items.Add("本地信息: " + TextBox1.Text)

 

        TextBox1.Text = ""

    End Sub

 

    '非UI线程调用窗体控件,保证线程安全。与聊天实现无关。

    Sub AddInfo(ByVal sender As System.Object, ByVal e As System.EventArgs)

        ListBox1.Items.Add("远程信息: " + sender.ToString)

    End Sub

 

    '关闭窗口时发关退出信息并清理资源

    Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing

        If IsRun Then

            Dim msg As Byte() = Encoding.UTF8.GetBytes("Exit|服务端退出: " + Me.Handle.ToString)

            Dim bytesSent As Integer = mySocket.Send(msg)

        End If

        listener.Close()

        mySocket = Nothing

        myThread.Abort()

    End Sub

 

End Class

 

2、客户端

Imports System.Net

Imports System.Net.Sockets

Imports System.Text

Imports System.Threading

 

Public Class frmClient

    '客户端Socket

    Dim cliSocket As Socket

    '连接状态

    Dim IsConnected As Boolean = False

    '接收信息线程

    Dim myThread As Thread

 

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        Dim remoteEP As New IPEndPoint(Net.IPAddress.Parse("127.0.0.1"), 11000)

        cliSocket = New Socket(AddressFamily.InterNetwork, SocketType.Stream, ProtocolType.Tcp)

        Try

            cliSocket.Connect(remoteEP)

            ListBox1.Items.Add("连接服务端成功!")

            IsConnected = True

 

            myThread = New Thread(AddressOf ReciveMsg)

            myThread.Start()

        Catch ex As Exception

            ListBox1.Items.Add(ex.Message)

        End Try

    End Sub

 

    Sub ReciveMsg()

        Dim bytes() As Byte = New Byte(1024) {}

        Dim data As String = String.Empty

        Dim tokens() As String

 

        While True

            Dim bytesRec As Integer = cliSocket.Receive(bytes)

            data = Encoding.UTF8.GetString(bytes, 0, bytesRec)

 

            tokens = data.Trim.Split("|")

            Select Case tokens(0) '分析接收到的数据,可自己定义更多一些

                Case "Exit"

                    IsConnected = False

                    BeginInvoke(New EventHandler(AddressOf AddInfo), tokens(1))   'Invoke保证线程安全

                    cliSocket.Shutdown(SocketShutdown.Both)

                    cliSocket.Close()

                    Exit Sub

                Case "Chat"

                    BeginInvoke(New EventHandler(AddressOf AddInfo), tokens(1))   'Invoke保证线程安全

            End Select

 

        End While

 

    End Sub

 

    '发送信息

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

        Dim msg As Byte() = Encoding.UTF8.GetBytes("Chat|" + TextBox1.Text)

        Dim bytesSent As Integer = cliSocket.Send(msg)

 

        ListBox1.Items.Add("本地信息: " + TextBox1.Text)

        TextBox1.Text = ""

    End Sub

 

    '非UI线程调用窗体控件,保证线程安全。与聊天实现无关。

    Sub AddInfo(ByVal sender As System.Object, ByVal e As System.EventArgs)

        ListBox1.Items.Add("远程信息: " + sender.ToString)

    End Sub

 

    '关闭窗口时发关退出信息并清理资源

    Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing

        If IsConnected Then

            Dim msg As Byte() = Encoding.UTF8.GetBytes("Exit|客户端退出: " + Me.Handle.ToString)

            Dim bytesSent As Integer = cliSocket.Send(msg)

            myThread.Abort()

        End If

 

    End Sub

End Class

 

源程序下载:

VB聊天程序.rar

版权声明:本文为博主原创文章,未经博主允许不得转载。

相关文章推荐

Android客户端与PC服务器通过socket进行交互实例

一直以来对Android socket通信都很模糊,今天终于研究了一个网上的例子,自己又修改了下,算是对Android socket通信有点了解了。 下面是具体的代码,说明都在注释中了。需要注意的是,...

(三)处理基本数据类型

1、混合类型表达式转换:总原则:不失真        因此,一般都是由窄类型向宽类型转换。 2、随机数:  产生0到10:  a=rand() % 11          ...

用Socket做简单聊天程序(VB.net)

原文地址:http://blog.csdn.net/chendazhi/archive/2006/05/18/744130.aspx 有位网友发贴问我一个聊天的问题,不好拒绝;也看到最近VB.net版...

VB.NET关于Socket分包发送的原理分析

关于Socket编程,我之前一直处于小数据传输的阶段,就像什么多人聊天之类的,这几天项目碰到了要做在线更新,就想着肯定要静静的写一个非文字信息传输的Socket程序   难点在于: 1、Socket编...

VB.NET环境下的Socket编程举例

原文地址:http://track.cnblogs.com/archive/2005/09/26/244673.aspx        一直以来很想学习Socket编程方面的应用,比如怎样通过Sock...

VB.NET Socket 入门(尚未整理完...)

服务端:Imports System.Collections.Generic Imports System.ComponentModel Imports System.Data Imports ...

一个基于VB.net的异步Socket网络TCP通信可防止任意一端意外终止TCP连接的类,。

之前,因为要做一个TCP通信的项目,有研究一下Socket类,但是为了快速完成任务,还是在网上找了一些源码来调试测试,发现很多源码都无法触发TCP连接的任意一端 的突然意外中断连接的事件,于是本...
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:深度学习:神经网络中的前向传播和反向传播算法推导
举报原因:
原因补充:

(最多只允许输入30个字)