升级Windows10![收不到Win10升级预订通知的解决办法]

原创 2015年07月31日 16:20:45

Windows10发布了,你更新了吗? 大多数用户电脑状态栏已经显示Win10升级预定通知,但是仍然有一大部分用户不显示。

收不到Win10升级预订通知的解决办法

不出现升级提示的不要着急,可将如下代码复制到文本文件内,并改扩展名为.bat:
(或在这里下载:收不到Win10升级预定解决办法

@echo off
title Windows 10 Missing Icon Fixes
goto foreward
:foreward
color 0b
cls
echo The methods inside this batch modify files and registry settings.
echo While they are tested and tend to work, I take no responsibility for the use of this file.
echo This batch is provided without warranty. Any damage caused is your own responsibility.
echo.
echo As well, batch files are almost always flagged by anti-virus, feel free to review the code if you're unsure.
echo.
echo If you understand the above, and accept - press any key to continue...
pause > NUL
goto elevatecheck
:elevatecheck
color 0c
cls
echo Checking for Administrator elevation...
echo.
echo.
openfiles > NUL 2>&1
if %errorlevel%==0 (
    echo Elevation found! Proceeding...
    goto vercheck
) else (
    echo You are not running as Administrator...
    echo This batch cannot do it's job without elevation!
    echo.
    echo Right-click and select ^'Run as Administrator^' and try again...
    echo.
    echo Press any key to exit...
    pause > NUL
    exit
)
:vercheck
color 0c
cls
echo Performing Pre-Checks...
for /f "tokens=4-5 delims=. " %%i in ('ver') do set version=%%i.%%j
if "%version%"=="6.3" set allow=1
if "%version%"=="6.1" set allow=1
if %allow%==1 goto warning
set allow=0
echo.
echo You did not pass the pre-requisites.
echo If you're running Windows 8, go install Windows 8.1 from the Store.
echo.
echo Press any key to exit.
pause > NUL
exit
:warning
color 0b
cls
echo Warning about qualifications...
echo.
echo.
echo Just because your version checks out, doesn't mean you're eligible for the free upgrade!
echo Notably, the following are not elibile for Windows 10 via Windows Update...
echo.
echo Windows 7 RTM
echo Windows 8
echo Windows 8.1 RTM
echo Windows RT
echo Windows Phone 8.0
echo.
echo Press any key to continue...
pause > NUL
goto menu
:menu
color 0b
cls
echo Main Menu
echo.
echo.
echo 1^) Check Update Status
echo 2^) Quick-Method #1 ^[JC from answers.microsoft.com^]
echo 3^) Quick-Method #2 ^[KevinStevens_845 from answers.microsoft.com^]
echo 4^) Long-Method #1 ^[Yaqub K from answers.microsoft.com^]
echo 5^) EXIT
echo.
set /p mmchoice=Selection: 
if %mmchoice%==1 goto upstatus
if %mmchoice%==2 goto qm1
if %mmchoice%==3 goto qm2
if %mmchoice%==4 goto lm1
if %mmchoice%==5 exit
goto error
:error
color 0C
cls
echo Main Menu - Error!
echo.
echo.
echo You did not enter a valid entry.
echo.
echo Press any key to return to the main menu and try again.
pause > NUL
goto menu
:upstatus
cls
echo Checking for appropriate update installation status...
echo.
echo.
if "%version%"=="6.3" goto upstatus8
if "%version%"=="6.1" goto upstatus7
goto menu
:upstatus8
echo Windows 8^+ detected...
echo.
set upcheck=3035583
echo Checking for update KB%upcheck%...
dism /online /get-packages | findstr %upcheck% > NUL
if %errorlevel%==0 (
    echo Update KB%upcheck% is installed!
    set missupdate=0
) else (
    echo Update KB%upcheck% is missing!
    set missupdate=1
)
echo.
set upcheck=3035583
echo Checking for update KB%upcheck%...
dism /online /get-packages | findstr %upcheck% > NUL
if %errorlevel%==0 (
    echo Update KB%upcheck% is installed!
) else (
    echo Update KB%upcheck% is missing!
    set /a missupdate=%missupdate%+1>NUL
)
echo.
echo.
if %missupdate%==0 (
    echo You are not missing any updates, congratulations!
) else (
    echo You are missing %missupdate% update^(s^).
)
echo Press any key to return to the main menu...
pause > NUL
goto menu
:upstatus7
echo Windows 7 detected...
echo.
set upcheck=3035583
echo Checking for update KB%upcheck%...
dism /online /get-packages | findstr %upcheck% > NUL
if %errorlevel%==0 (
    echo Update KB%upcheck% is installed!
    set missupdate=0
) else (
    echo Update KB%upcheck% is missing!
    set missupdate=1
)
echo.
set upcheck=2952664
echo Checking for update KB%upcheck%...
dism /online /get-packages | findstr %upcheck% > NUL
if %errorlevel%==0 (
    echo Update KB%upcheck% is installed!
) else (
    echo Update KB%upcheck% is missing!
    set /a missupdate=%missupdate%+1>NUL
)
echo.
echo.
if %missupdate%==0 (
    echo You are not missing any updates, congratulations!
) else (
    echo You are missing %missupdate% update^(s^).
)
echo Press any key to return to the main menu...
pause > NUL
goto menu
:qm1
cls
echo Quick-Method #1 ^[JC from answers.microsoft.com^]
echo.
echo.
echo Updating registry...
reg add "HKLM\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\UpgradeExperienceIndicators" /v UpgEx /t REG_SZ /d Green /f
echo Trying to launch notification tray application...
%SystemRoot%\System32\GWX\GWX.exe /taskLaunch
echo.
echo This method is now complete - and is also instant!
echo You should see the Windows 10 icon in your notification tray.
echo If you do not, return to the menu and try another method.
echo.
echo Press any key to return to the main menu...
pause > NUL
goto menu
:qm2
echo Quick-Method #2 ^[KevinStevens_845 from answers.microsoft.com^]
echo.
echo.
echo Trying to launch GWX task...
%SystemRoot%\System32\GWX\GWX.exe /taskLaunch
echo Trying to refresh GWX config...
%SystemRoot%\System32\GWX\GWXConfigManager.exe /RefreshConfig
echo.
echo This method is now complete - but it could take a few minutes.
echo In approximately 10 minutes you should see the Windows 10 icon in your notification tray.
echo If you do not, return to the menu and try another method.
echo.
echo Press any key to return to the main menu...
pause > NUL
goto menu
:lm1
cls
echo Long-Method #1 ^[Yaqub K from answers.microsoft.com^]
echo.
echo.
echo This method can take anywhere from 10 minutes on. 
echo I've had this run up to 40 minutes during my tests...
echo.
echo This will loop for a while but please note...
echo If you see the ^"STATUS^" as anything but ^"RUNNING^", there is something wrong.
echo If that happens, close the batch file and start over. It may take a few times.
echo.
echo Further, due to the way this script was originally written, you may have to re-launch this batch to continue.
echo.
echo If you understand the above, press any key to continue.
pause > NUL
color 0c
cls
echo Work has begun...
REG QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\UpgradeExperienceIndicators" /v UpgEx | findstr UpgEx
if "%errorlevel%"=="0" goto RunGWX
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Appraiser" /v UtcOnetimeSend /t REG_DWORD /d 1 /f
schtasks /run /TN "\Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser"
echo THIS MAY CAUSE A LOOP - CHECK FOR RUNNING STATUS!!! &echo THIS MAY CAUSE A LOOP - CHECK FOR RUNNING STATUS!!! &echo THIS MAY CAUSE A LOOP - CHECK FOR RUNNING STATUS!!!
:CompatCheckRunning
schtasks /query /TN "\Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser"
schtasks /query /TN "\Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser" | findstr Ready
if not "%errorlevel%"=="0" ping localhost > NUL &goto :CompatCheckRunning
:RunGWX
schtasks /run /TN "\Microsoft\Windows\Setup\gwx\refreshgwxconfig"
color 0b
cls
echo.
echo This method is now complete.
echo Reports show that this could take up to an hour to show the icon.
echo It is also recommended that you reboot your PC if it has not shown up after that hour wait.
echo.
echo If you do not see the notification tray icon, try another method.
echo If you are using this method last, please wait in the Microsoft Answers forums for a new answer.
echo.
echo Press any key to return to the main menu...
pause > NUL
goto menu

以管理员身份运行,按任意键继续,直到出现如下显示:
Windows10.CLeopard
输入1,回车后,程序自动检测并更新补丁,如图:
Windows10.CLeopard
如果没有缺少必需更新,系统仍无法收到升级提醒,按任意键返回到主菜单。这里提供了三种修复方法:两种快速(Quick)修复方法和一个比较慢(Long)的修复方法,可以依次尝试一下。这些修复方法都来自于微软的问答社区,这里是将其汇总起来做成了批处理。

官方Windows10升级助手

也可尝试微软官方升级助手:官方Windows10升级助手 http://download.csdn.net/detail/cleopard/8949097
包括32位和64位。

Windows10激活

……………………
自己激活吧。。
CLeopard
2015/07/31 14:27

版权声明:本文为博主原创文章,未经博主允许不得转载。

如何升级nodejs

Node.js的更新之快,最新稳定版本也频繁变化,经常会发现,某个模块不能在你当前的Node版本上使用了,此时你需要升级Node。而管理Node版本,则有一个模块叫做Node Binary的管理模块...
  • michael_ouyang
  • michael_ouyang
  • 2017年05月26日 12:47
  • 1335

微软仍计划在2017年发布两次Windows 10系统升级

微软本月重申,今年将发布两次Windows 10系统升级,这相当于2016年的两倍。但他们对公司的原定目标仍有顾虑。 在11天前澳大利亚举行的微软技术会议上项目管理主管比尔·卡拉古尼斯指出,后续...
  • Harriet666
  • Harriet666
  • 2017年02月24日 15:00
  • 1799

升级安装Windows10后如何删除Windows.old文件

升级安装Windows10后,会在盘下边产生一个叫做“Windows.old”的大文件,足足15G有余,咱们怎么能够删除呢,今天就给大家讲讲如何正确删除(尽量不要用强力删除软件)...
  • fmc201314
  • fmc201314
  • 2017年01月20日 19:40
  • 381

解决windows10无法更新问题

手头有一个MacBook,但是实在用不惯MacOS,于是下载了Boot Camp,分了区,从网上随便down了一个Win10,如何激活?嗯,大家都懂的。☺ 装完之后,winver显示的版本号是143...
  • sharpbladepan
  • sharpbladepan
  • 2016年12月11日 20:31
  • 2290

升级win10,提示(RAM)内存不足2G的解决办法,亲测可行

前两天升级win10,检测时提示内存不足2G,这让我8G的内存郁闷不已        百度,google了很多方法,有些是两根内存,去掉一个就好了,可是我的就一根8G的,其他就没什么好的方法了,改...
  • bixingtao
  • bixingtao
  • 2015年08月03日 23:51
  • 14695

最近win10无数人更新失败,这里是解决方案

先说问题和现象,下文说解决方案 近来,媒体频频报道微软的累积更新“Windows 10 Version 1607 累积更新 (KB3194496)”出现无法安装的问题。 笔者收到更新推送后...
  • qq_36290329
  • qq_36290329
  • 2016年10月04日 15:30
  • 88262

关于windows10升级

本人今天心血来潮,去点了下升级,原来是win8.1,想升级到win10,结果升级完成后发现不是旗舰版的,而是家庭版的。所以就想升级到专业版。我的步骤如下,可能大家各有差异 1.在网上找到升级密钥,注...
  • luzle
  • luzle
  • 2015年08月01日 09:33
  • 359

Windows 10四大版本官方对比:国人肯定专业版

每一代Windows系统都会针对不同市场、根据功能特性不同划分出多个版本,但是每一代又有不同的划分方式。Windows 10果然又变了,不过微软今天很贴心地放出了一份对比表格,详细列举了四大版本的异同...
  • Real_Myth
  • Real_Myth
  • 2016年04月18日 10:13
  • 591

win10 10240专业版升级15063微软官方最新版

自己做的装机U盘,用的是电脑店。后期在淘宝上购买了激活码,完成win10专业版的激活,正常使用一年半左右的时间。最近因为写代码要安装IDE,发现从官网下载的压缩包解压之后所有的批处理文件全部丢失,部分...
  • qq_34209528
  • qq_34209528
  • 2017年04月26日 21:32
  • 2915

windows10升级后删除Windows.old安装包

一、Windows.old文件 “Windows.old”文件夹包含升级win10前系统的“Windows”、“Program Files”、“Users”这三个目录中的文件,将之前的系统文件和安装...
  • caizhaoyang589
  • caizhaoyang589
  • 2018年01月15日 11:13
  • 13
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:升级Windows10![收不到Win10升级预订通知的解决办法]
举报原因:
原因补充:

(最多只允许输入30个字)