将多个文件写到一个文件(并合文件)，也可从该并合文件中获得其中某个文件的流（具体不多写了，压缩功能未加进，有兴趣留言）

1. Imports System.IO
2. Imports System.Runtime.InteropServices
3. Imports System.ComponentModel
5. Public Class Form1
6.     Dim cfm As New CoalescentFileManager
7.     Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
8.         For Each x In My.Computer.FileSystem.GetFiles(My.Computer.FileSystem.SpecialDirectories.MyPictures, FileIO.SearchOption.SearchTopLevelOnly, ("*.jpg"))
9.             cfm.AddSourceFile(x)
10.             Console.WriteLine(x)
12.         Next
14.         '
16.         cfm.WriteCoalescentFile(Environment.GetFolderPath(Environment.SpecialFolder.Desktop) & "/" & "xx.dat")
18.         cfm.LoadCoalescentFile(Environment.GetFolderPath(Environment.SpecialFolder.Desktop) & "/" & "xx.dat")
19.         ListBox1.Items.AddRange(cfm.CurrentCoalescentFile.NameList)
20.         'cfm.CurrentCoalescentFile.RevertCoalescentFileToDirectory(Environment.GetFolderPath(Environment.SpecialFolder.Desktop) & "/xx/")
22.     End Sub
27.     Private Sub ListBox1_SelectedIndexChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles ListBox1.SelectedIndexChanged
29.         Me.BackgroundImage = Image.FromStream(cfm.CurrentCoalescentFile.GetStream(ListBox1.SelectedIndex))
30.     End Sub
31. End Class
35. Public Class CoalescentFileManager
39.     Dim _fullFilenameList As New List(Of String)
41.     Dim _coaFileLoaded As Boolean
43.     Dim _cf As CoalescentFile
45.     Sub New()
46.     End Sub
49.     Sub AddSourceFile(ByVal source As String)
50.         If Not File.Exists(source) Then Return
52.         _fullFilenameList.Add(source)
53.     End Sub
56.     Public Sub WriteCoalescentFile(ByVal filename As String)
58.         WriteCoalescentFile(filename, False)
59.     End Sub
63.     Public Sub WriteCoalescentFile(ByVal filename As String, ByVal useDeflate As Boolean)
65.         Using fs As New FileStream(filename, FileMode.Create, FileAccess.ReadWrite)
66.             Dim bw As New BinaryWriter(fs)
67.             '
68.             bw.Write("CoalescentFile")
69.             '
70.             bw.Write(useDeflate)
71.             '占用了4字节
72.             bw.Write(_fullFilenameList.Count)
74.             For Each f In _fullFilenameList
75.                 Dim fi As New FileInfo(f)
76.                 '每个占用8字节
77.                 bw.Write(fi.Length)
78.                 fi = Nothing
79.             Next
81.             For Each f In _fullFilenameList
82.                 bw.Write(Path.GetFileName(f))
83.             Next
86.             For Each f In _fullFilenameList
87.                 bw.Write(File.ReadAllBytes(f))
88.                 bw.Flush()
89.             Next
92.             bw.Close()
94.         End Using
95.     End Sub
100.     Public Sub LoadCoalescentFile(ByVal coalescentFile As String)
101.         If Not File.Exists(coalescentFile) Then
102.             Throw New InvalidCoalescentFileException("所指示文件不存在。")
103.         End If
106.         Using fs As New FileStream(coalescentFile, FileMode.Open, FileAccess.Read)
107.             Dim br As New BinaryReader(fs)
108.             Dim headStr As String = br.ReadString
110.             If headStr <> "CoalescentFile" Then
111.                 Throw New InvalidCoalescentFileException("该文件不是有效的合并文件。")
112.             End If
113.         End Using
116.         _cf = New CoalescentFile(coalescentFile)
117.         _coaFileLoaded = True
118.     End Sub
122.     Public ReadOnly Property CurrentCoalescentFile() As CoalescentFile
123.         Get
124.             Return _cf
125.         End Get
126.     End Property
131.     Public Class CoalescentFile
132.         Dim _shortNameList As List(Of String)
133.         Dim _fileLengthList As List(Of Long)
134.         Dim _fileCount As Integer
136.         Dim _isZip As Boolean
137.         Dim _cf As String
138.         Dim _contentStartPos As Long
140.         Sub New(ByVal cf As String)
141.             _shortNameList = New List(Of String)
142.             _fileLengthList = New List(Of Long)
144.             _cf = cf
146.             Using fs As New FileStream(_cf, FileMode.Open, FileAccess.Read)
147.                 Dim br As New BinaryReader(fs)
149.                 br.ReadString()
150.                 _isZip = br.ReadBoolean
151.                 _fileCount = br.ReadInt32
153.                 For i = 1 To _fileCount
154.                     _fileLengthList.Add(br.ReadInt64())
155.                 Next
157.                 For i = 1 To _fileCount
158.                     _shortNameList.Add(br.ReadString)
159.                 Next
161.                 _contentStartPos = fs.Position
162.                 br.Close()
164.             End Using
165.         End Sub
168.         Public Sub RevertCoalescentFileToDirectory(ByVal dir As String)
169.             If Not Directory.Exists(dir) Then Directory.CreateDirectory(dir)
171.             Using fs As New FileStream(_cf, FileMode.Open, FileAccess.Read)
172.                 Dim br As New BinaryReader(fs)
174.                 fs.Position = _contentStartPos
176.                 For i = 0 To _fileCount - 1
177.                     Dim buffer = br.ReadBytes(_fileLengthList(i))
178.                     File.WriteAllBytes(dir & _shortNameList(i), buffer)
179.                 Next
181.                 br.Close()
183.             End Using
184.         End Sub
186.         Public Sub WriteOneToFile(ByVal index As Integer, ByVal file As String)
187.             Using fs As New FileStream(file, FileMode.Create, FileAccess.Write)
188.                 Using mems As MemoryStream = GetStream(index)
189.                     Dim bw As New BinaryWriter(fs)
190.                     '若用 memoryStream.GetBuffer 方法则会在末尾多出一些  空符(字符码为零)
191.                     bw.Write(mems.ToArray)
192.                     bw.Close()
193.                 End Using
194.             End Using
195.         End Sub
197.         Public Function GetStream(ByVal index As Integer) As MemoryStream
198.             Dim startPos As Long = _contentStartPos
199.             For i = 0 To index - 1
200.                 startPos += _fileLengthList(i)
201.             Next
202.             Dim buffer As Byte()
204.             Using fs As New FileStream(_cf, FileMode.Open, FileAccess.Read)
205.                 Dim br As New BinaryReader(fs)
206.                 fs.Position = startPos
207.                 buffer = br.ReadBytes(_fileLengthList(index))
208.                 br.Close()
209.             End Using
211.             Dim mems As MemoryStream
213.             mems = New MemoryStream(buffer)
216.             Erase buffer
217.             GC.Collect()
218.             Return mems
220.         End Function
223.         Public ReadOnly Property NameList() As String()
224.             Get
225.                 Return _shortNameList.ToArray
226.             End Get
227.         End Property
230.         Public ReadOnly Property FileCount() As Integer
231.             Get
232.                 Return _fileCount
233.             End Get
234.         End Property
237.         Public ReadOnly Property CurrentFile() As String
238.             Get
239.                 Return _cf
240.             End Get
241.         End Property
243.         Public ReadOnly Property IsDeflate() As Boolean
244.             Get
245.                 Return _isZip
246.             End Get
247.         End Property
249.     End Class
253. End Class
256. Public Class InvalidCoalescentFileException
257.     Inherits Exception
259.     Sub New(ByVal text As String)
260.         MyBase.New(text)
261.     End Sub
262. End Class