解释一个ld.script文件

最新推荐文章于 2024-04-24 16:14:41 发布
最新推荐文章于 2024-04-24 16:14:41 发布
阅读量1k 收藏
点赞数
分类专栏： 技术人生 文章标签： list output 脚本 access 平台 c

本文详细解释一个 ld.script 文件

OUTPUT_FORMAT("elf32-tradlittlemips")
OUTPUT_ARCH(mips)
ENTRY(_start)
SECTIONS
{
  /* Read-only sections, merged into text segment: */
  . = 0x80100000;
  .text      : 
  {
    _ftext = . ;
    *(.text)
    *(.rodata)
    *(.rodata1)
    *(.reginfo)
    *(.init)
    *(.stub)
    /* .gnu.warning sections are handled specially by elf32.em.  */
    *(.gnu.warning)
  } =0
  _etext = .;
  PROVIDE (etext = .);
  .fini      : { *(.fini)    } =0
  .data    :
  {
    _fdata = . ;
    *(.data)
    CONSTRUCTORS
  }
  .data1   : { *(.data1) }
  .ctors         :
  {
                __CTOR_LIST__ = .;
                LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
               *(.ctors)
                LONG(0)
                __CTOR_END__ = .;
  }
  .dtors         :
  {
                __DTOR_LIST__ = .;
                LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
               *(.dtors)
                LONG(0)
                __DTOR_END__ = .;
  }
  _gp = ALIGN(16) + 0x7ff0;
  .got           :
  {
    *(.got.plt) *(.got)
   }
  /* We want the small data sections together, so single-instruction offsets
     can access them all, and initialized data all before uninitialized, so
     we can shorten the on-disk segment size.  */
  .sdata     : { *(.sdata) }
  .lit8 : { *(.lit8) }
  .lit4 : { *(.lit4) }
  _edata  =  .;
  PROVIDE (edata = .);
  __bss_start = .;
  _fbss = .;
  .sbss      : { *(.sbss) *(.scommon) }
  .bss       :
  {
   *(.dynbss)
   *(.bss)
   *(COMMON)
  }
  . = ALIGN(16);
  __bss_end = .;
  _end = .;__end = .; end = .; 
  PROVIDE (end = .);
  /* These are needed for ELF backends which have not yet been
     converted to the new style linker.  */
  .stab 0 : { *(.stab) }
  .stabstr 0 : { *(.stabstr) }
  /* DWARF debug sections.
     Symbols in the .debug DWARF section are relative to the beginning of the
     section so we begin .debug at 0.  It's not clear yet what needs to happen
     for the others.   */
  .debug          0 : { *(.debug) }
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }
  .debug_sfnames  0 : { *(.debug_sfnames) }
  .line           0 : { *(.line) }
  /* These must appear regardless of  .  */
  .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
  .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
}

下面逐句解释。

OUTPUT_FORMAT("elf32-tradlittlemips")
OUTPUT_ARCH(mips)

OUTPUT_FORMAT 和 OUTPUT_ARCH 都是 ld 脚本的保留字命令。OUTPUT_FORMAT 说明输出二进制文件的格式。OUTPUT_ARCH 说明输出文件在平台。 
ENTRY(_start)

ENTRY 命令的作用是，将后面括号中的符号值设置成入口地址。入口地址（entry point）的定义是这样的──进程执行的第一条用户空间的指令在进程地址空间中的地址。

ld 有多种方法设置进程入口地址，通常它按以下顺序：（编号越前, 优先级越高）
1, ld 命令行的-e选项
2, 连接脚本的 ENTRY(SYMBOL) 命令
3, 如果定义了 start 符号, 使用 start 符号值
4, 如果存在 .text section, 使用 .text section 的第一字节的位置值
5, 使用值 0

SECTIONS
{

然后，接下来是一大段的 SECTIONS，对应的右大括号直到脚本的末尾。
SECTIONS 命令告诉 ld 如何把输入文件的 sections 映射到输出文件的各个 section：即是如何将输入 section 合为输出 section；如何把输出 section 放入程序地址空间 (VMA) 和进程地址空间 (LMA) 。该命令格式如下：
SECTIONS
{
….
} 
/* Read-only sections, merged into text segment: */
  . = 0x80100000;

这句把定位器符号置为 0x80100000 （若不指定，则该符号的初始值为 0）。
. 是一个特殊的符号，它是定位器，一个位置指针，指向程序地址空间内的某位置（或某section内的偏移，如果它在SECTIONS命令内的某section描述内），该符号只能在SECTIONS命令内使用。 
.text      : 
  {
    _ftext = . ;
    *(.text)
    *(.rodata)
    *(.rodata1)
    *(.reginfo)
    *(.init)
    *(.stub)
    /* .gnu.warning sections are handled specially by elf32.em.  */
    *(.gnu.warning)
  } =0

.text : 表示text段开始。
_ftext
*(.text) 将所有(*符号代表任意输入文件)输入文件的.text section合并成一个.text section, 该section的地址由定位器符号的值指定, 即0x80100000.
*(.rodata)
*(.rodata1)
*(.reginfo)
*(.init)
*(.stub)
*(.gnu.warning)
} =0 表示合并时留下的空隙用 0 填充； 
_etext = .;
  PROVIDE (etext = .);

_etext = .; 我们看到，很多变量都定义成等于这个 . 符，实际上这个符号所代表的值是在变化的，随着越往后走，值越增加，根据前面填充的多少自动往后加。
PROVIDE关键字用于定义这类符号：在目标文件内被引用，但没有在任何目标文件内被定义的符号。
这里就定义了一个 etext 符号，当目标文件内引用了 etext 符号，却没有定义它时，etext 符号对应的地址被定义为 .text section 之后的第一个字节的地址。 
.fini      : { *(.fini)    } =0

意思与前面一样，但 fini 这名字是哪个段，我还搞不太清楚（？？？）。 
.data    :
  {
    _fdata = . ;
    *(.data)
    CONSTRUCTORS
  }
  .data1   : { *(.data1) }

数据段终于来到了，意思很容易理解的了。
CONSTRUCTORS 是一个保留字命令。与 c++ 内的（全局对象的）构造函数和（全局对像的）析构函数相关。 
.ctors         :
  {
                __CTOR_LIST__ = .;
                LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
               *(.ctors)
                LONG(0)
                __CTOR_END__ = .;
  }
  .dtors         :
  {
                __DTOR_LIST__ = .;
                LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
               *(.dtors)
                LONG(0)
                __DTOR_END__ = .;
  }

对于支持任意section名的目标文件格式，比如COFF、ELF格式，GNU C++将全局构造和全局析构信息分别放入 .ctors section 和 .dtors section 内
当连接器生成的目标文件格式不支持任意section名字时，比如说ECOFF、XCOFF格式，连接器将通过名字来识别全局构造和全局析构，对于这些文件格式，连接器把与全局构造和全局析构的相关信息放入出现 CONSTRUCTORS 关键字的输出section内。

符号__CTORS_LIST__表示全局构造信息的的开始处，__CTORS_END__表示全局构造信息的结束处。
符号__DTORS_LIST__表示全局构造信息的的开始处，__DTORS_END__表示全局构造信息的结束处。
这两块信息的开始处是一字长的信息，表示该块信息有多少项数据，然后以值为零的一字长数据结束。
一般来说，GNU C++在函数__main内安排全局构造代码的运行，而__main函数被初始化代码（在main函数调用之前执行）调用。

_gp = ALIGN(16) + 0x7ff0;

_gp是一个重要的全局变量，好像是用作全局引用的一个指针。 
.got           :
  {
    *(.got.plt) *(.got)
   }
  /* We want the small data sections together, so single-instruction offsets
     can access them all, and initialized data all before uninitialized, so
     we can shorten the on-disk segment size.  */
  .sdata     : { *(.sdata) }
  .lit8 : { *(.lit8) }
  .lit4 : { *(.lit4) }

意义类似。 
_edata  =  .;
  PROVIDE (edata = .);

意义与前面的 etext 类似。edata 符号也较为重要。 
__bss_start = .;
  _fbss = .;
  .sbss      : { *(.sbss) *(.scommon) }
  .bss       :
  {
   *(.dynbss)
   *(.bss)
   *(COMMON)
  }
  . = ALIGN(16);
  __bss_end = .;
  _end = .;__end = .; end = .; 
  PROVIDE (end = .);

BSS段开始了。
COMMON 这个保留字的意义：
通用符号(common symbol)的输入section：
在许多目标文件格式中，通用符号并没有占用一个section。连接器认为：输入文件的所有通用符号在名为COMMON的section内。
上例中将所有输入文件的所有通用符号放入输出.bss section内。

这里，定义了几个重要的符号
__bss_start = .;
__bss_end = .;
_end = .;
__end = .;
end = .;
在代码中可能会用到的。

/* These are needed for ELF backends which have not yet been
     converted to the new style linker.  */
  .stab 0 : { *(.stab) }
  .stabstr 0 : { *(.stabstr) }
  /* DWARF debug sections.
     Symbols in the .debug DWARF section are relative to the beginning of the
     section so we begin .debug at 0.  It's not clear yet what needs to happen
     for the others.   */
  .debug          0 : { *(.debug) }
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }
  .debug_sfnames  0 : { *(.debug_sfnames) }
  .line           0 : { *(.line) }
  /* These must appear regardless of  .  */
  .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
  .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
}

余下的这几个意义也类似，看英文注释应该能明白。

对初步编译出来的一个二进制文件进行 nm 解析，得到如下内容

80100200 D __CTOR_END__
801001f8 D __CTOR_LIST__
80100208 D __DTOR_END__
80100200 D __DTOR_LIST__
80100220 A __bss_end
80100208 A __bss_start
80100220 A __end
80100208 A _edata
80100220 A _end
801001f8 A _etext
80100208 A _fbss
80100200 A _fdata
80100000 T _ftext
80108200 A _gp
80100000 T _start
80100038 t cleanpipe
80100220 A end
80100210 b flag_initialized.1263
80100158 T inbFrCom
801000b4 T initBss
80100060 T initConstructor
80100100 T initMips
801001a4 T outbToCom
80100140 T readComReg
801000f8 T showVersion
800fc000 T stack
80100000 T start
80100120 T writeComReg

可以看到，所有的地址全是从 0x80100000 开始的。

三个起始符号（T表示在text段中）
80100000 T _start
80100000 T start
80100000 T _ftext

几个函数都在代码段内
80100038 t cleanpipe
80100060 T initConstructor
801000b4 T initBss
801000f8 T showVersion
80100100 T initMips
80100120 T writeComReg
80100140 T readComReg
80100158 T inbFrCom
801001a4 T outbToCom

栈底地址果然是在 start 下方 0x4000 处
800fc000 T stack

（A 表示绝对不变）
801001f8 A _etext
80100200 A _fdata
80100208 A _edata
80100208 A _fbss
80100208 A __bss_start
80100220 A __bss_end
80100220 A __end
80100220 A _end
80100220 A end

全局构造和析构变量段（D表示在已初始化过的数据段中）
801001f8 D __CTOR_LIST__
80100200 D __CTOR_END__
80100200 D __DTOR_LIST__
80100208 D __DTOR_END__

还有一个是用 B 标记的，表示在未初始化的数据段中
80100210 b flag_initialized.1263
对应的代码是
static int flag_initialized = 0;
可以看出，这是个局部静态变量。

令其按地址排序

nm -n bamboo

800fc000 T stack
80100000 T _ftext
80100000 T _start
80100000 T start
80100038 t cleanpipe
80100060 T initConstructor
801000b4 T initBss
801000f8 T showVersion
80100100 T initMips
80100120 T writeComReg
80100140 T readComReg
80100158 T inbFrCom
801001a4 T outbToCom
801001f8 D __CTOR_LIST__
801001f8 A _etext
80100200 D __CTOR_END__
80100200 D __DTOR_LIST__
80100200 A _fdata
80100208 D __DTOR_END__
80100208 A __bss_start
80100208 A _edata
80100208 A _fbss
80100210 b flag_initialized.1263
80100220 A __bss_end
80100220 A __end
80100220 A _end
80100220 A end
80108200 A _gp

结合这些数据，去理解前面的 ld.script 的讲解，会有一个清晰的印象。


da895
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
LD script pdf
09-22
The script of the LD in Linux/Unix world
openredir:通过 LD_PRELOAD 重定向文件打开操作
05-31
打开目录 通过 LD_PRELOAD 重定向文件打开操作
关于GNU ld和ld脚本 转
hnhbdss的专栏
10-10 1318
-------------------------------------------------------------------------------- ld,即GNU的连接工具，用于将各目标文件合并在一起，并重新安排他们的数据以及符号的引用，常常是程序编译的最后一步。ld scripts 即ld脚本。ld 脚本的主要目的是要描述怎样将输入文件的各段印象到输出文件中去。它控制输出文
GCC的连接脚本--LD 学习笔记
申小白
03-29 2555
GCC的连接脚本学习笔记 连接脚本将我整整蒙了1天零一个上午，做了很多实验，看了人家不少例子代码 勉强能驾驭了，让linker按照我想要的来处理，做个笔记。 1，什么叫输入段，什么叫输出段 不知道怎么回事，我对GCC系列的输入和输出两个单词总是进入思维死角，很简单 就是 input section 和 output section，这里不是说翻译的问题，我觉得是一种 思考的方式的问题。 我的问题就...
GNU ld 脚本浅析 z
11-18 664
本文乃转载, 我在其基础上做了少量修改. 原作者的E-mail是[email protected]. 完成于2005.11.5-2005.11.80. Contents1. 概论2. 基本概念3. 脚本格式4. 简单例子5. 简单脚本命令6. 对符号的赋值7. SECTIONS命令8. MEMORY命令9. PHDRS命令10. VERSION命令11. 脚本内的表达式12. 暗含的连接脚
ld script 学习笔记
qq_38350702的博客
11-01 747
———————————————— 版权声明：本文为CSDN博主「ioscoder」的原创文章，遵循CC 4.0 BY-SA版权协议，转载请附上原文出处链接及本声明。 原文链接：https://blog.csdn.net/embinux/article/details/78357215 ld script 学习笔记 Linker Script linker script 是用来控制链接过程的，它的主要目的有两个： 描述如何将输入文件的section映射到输出文件 控制输出文件的内存布局 链接器总是使用
Xilinx SDK中指定变量的物理位置
nickchao的IT生涯
08-28 2745
问题点：使用Xilinx SDK开发 zynq，如果不注意修改堆栈大小，运行会直接卡死崩掉。因为SDK开发属于裸机程序开发了，内存需要自己管理，而带系统的由系统管理。 首先在声明变量的时候在后面增加attribute int matrix[16][16384] __attribute__((section(".matrix"))); 然后在Linker Script里面做如下修改：
SoC 第三讲 AMP架构双核应用程序开发和软中断处理（一）——双核应用程序
用心记录每天的学习，提升自己，虽然有的很基础但真的很重要！
08-21 3066
SoC 第三讲 AMP架构双核应用程序开发和软中断处理（一） 本节主要涉及到 裸机 使用两个ARM CPU 处理器（AMP架构） 来跑不同的应用程序，即使用共享内存时进行交互，并将其写进SD卡。并且介绍中断的定义，关于中断的例程可以参考下一讲。 一、AMP 非对称处理器架构 二、搭建 BD 工程（Vivado） 二、搭建C语言环境（SDK） 1. 创建CPU0、CPU1上应用空程序amp_cpu0、amp_cpu1。 2. DDR的空间分配 3. 对DDR地址空间进行配置
【调试记录】vitis下的Microblaze
相博镪的博客
01-04 2393
问题和解决方案 问题描述：使用Vitis IDE时，创建自带freeRTOS模板例程失败 详细描述：在block design中创建了microblaze、mig、timer、uart、ledgpio，使用中断。在vitis中尝试standalone的helloworld和memorytest模板成功。创建freeRTOS的helloworld模板例程后，build工程失败。 开发环境：vivado2020.2 报错内容: Description Resource Path Location Type ‘
Link-Script语法/ HighTec用户手册/ 链接脚本
08-17
The Linker Script File .ld 文件 ,链接脚本说明，第十九章介绍所有的ld脚本相关说明，对于链接脚本解析与阅读有很好的参考作用。 例如： CORE_ID、FLAGS、KEEP、REGION_MAP、AT等指令详细说明及案例。
json-ld:用于RDF.rb的Ruby JSON-LD读写器
05-12
JSON-LD读取器/写入器 用于和完全处理器的读取器/写入器。 此外，此gem实现了 。...这个gem实现了一个优化的流阅读器，该阅读器用于从格式为JSON-LD的大型数据集转储中生成RDF。 此类文档必须与JSON-LD流配置文件相对应
Using ld The GNU linker version 2
07-27
GNU ld是链接器，ld实际并...所有的链接过程都是由LD脚本控制的，写这个脚本的语言称为 linker command language，LD脚本的最主要的功能是描述如何将输入文件映射到输出文件以及输出文件的存储布局（memory layout）。
Linker Script
05-21
链接脚本使用文档Linker script,详细说明链接文件使用方法
STL-List
欢迎来到jiantaoyab博客
04-19 1062
我们将进入到C++STL 的学习。STL在各各C++的头文件中，以源代码的形式出现，不仅要会用，还要了解底层的实现。
【第六章】集合类：List、Iterator迭代器
小火龙的博客
04-22 695
集合类就像一个容器，相当于一个动态数组。为了在程序中可以保存数目不确定的对象，Java提供了一系列特殊的类，这些类可以存储任意类型的对象，并且长度可变，这些类被统称为集合。集合类都位于java.util包中，使用时必须导包。
C++学习第九天（list及其模拟实现）
最新发布
zjx_web_c的博客
04-24 338
概念：迭代器失效即迭代器所指向的节点无效，即该节点被删除了，因为list的底层结构是带头节点的双向循环链表，因此在list中进行插入时是不会导致list的迭代器失效的，只有在删除的时候才会失效，而且失效的只是指向被删除节点的迭代器，其他迭代器不会受到影响。list中的接口比较多，一下是常见的重要接口。
day18 java ​​​​​​​集合Collection的List和Set
oldzhongyi的博客
04-23 1144
Collection分成List和Set|-------List : 存储的元素是有序的并且可以重复|-------Set : 存储的元素是无序的并且不可以重复。
link_script.ldscript
07-27
`link_script.ldscript` 是一个链接器脚本文件，用于定义链接器在将目标文件链接成可执行文件时的行为和布局。该文件通常使用后缀名 `.ld` 或 `.lds`。 链接器脚本文件包含了一系列指令和命令，用于描述如何组织和...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值