显示 cpu 使用率

看到 yrt888 提出的问题，抽空研究了一下，发现其实并不像网上那些示例写的，计算其实很简单，只要使用 SystemProcessorPerformanceInformation 参数反复调用 NtQuerySystemInformation，然后根据返回的 IdleTime, KernelTime, UserTime 值，分别用后一次调用取得的值减去前一次调用取得的值，得到各增量值，之后一个除法就得到使用率了。这里唯一要注意的就是 KernelTime 成员的值包含了 IdleTime 和核心调用使用时间。另外发现当使用 SystemBasicInformation 调用 NtQuerySystemInformation 来试图获取 cpu 个数时会失败，返回 0xC0000004 错误码，好在还有 GetSystemInfo 这个 api 可以用来查出 cpu 的个数。所以下面的示例中核心的部分只有一个方法，就是 getCpuTimeInfo，其它只是用来显示使用率的 GUI 界面设计。这个示例对系统安装的每个 cpu 分别使用一个自定义容器来显示使用率图像/数据，不过我们通常只有一个 cpu，而且即使有双核，一般的软件也只能使用到其中的一个，不过印象中有些影片编辑软件可以使用多处理器，例如像“小日本”。

示例代码只在 Windows2003+vfp9 上测试，其他环境未测试。

2. public oForm
4. oForm = newobject("myform")
5. oForm.show
7. define class myform as form
8.   top = 0
9.   left = 0
10.   height = 200
11.   width = 100
12.   showwindow = 2
13.   showintaskbar = .f.
14.   caption = "CPU Usage"
15.   alwaysontop = .t.
16.   allowoutput = .f.
17.   maxbutton = .f.
18.   minbutton = .f.
19.   name = "form1"
21.   cpu_nums = 0              && 系统拥有的 cpu 个数
22.   dimension aCpuInfo[1,4]       && 1/2/3/4 - t_idle / t_kernel / t_user / usage
24.   procedure updateUsage         && 获取最新的 cpu 使用率信息
25.     local array laTemp[1]
26.     local liIdleTime, liKernelTime, liUserTime, lnUsage, loUsage
28.     acopy( this.aCpuInfo, m.laTemp )
29.     this.getCpuTimeInfo()
31.     for m.ii = 1 to this.cpu_nums
32.       m.liIdleTime  = m.laTemp[m.ii,1]
33.       m.liKernelTime    = m.laTemp[m.ii,2]
34.       m.liUserTime  = m.laTemp[m.ii,3]
35.       m.lnUsage = ;
36.         ( this.aCpuInfo[m.ii,1] - m.liIdletime ) / ;
37.         ( this.aCpuInfo[m.ii,2] + this.aCpuInfo[m.ii,3] ;
38.         - m.liKernelTime - m.liUserTime )
39.       this.aCpuInfo[m.ii,4] = ( 1.00 - m.lnUsage )          && * 100
40.       m.loUsage = evaluate( 'this.cntUsage' +  transform(m.ii))
41.       m.loUsage.value = this.aCpuInfo[m.ii,4]
42.     endfor
43.   endproc
45.   procedure getCpuTimeInfo      && 获取最新的 cpu 空闲/核心/用户用时信息
46.     #define SystemProcessorPerformanceInformation   8
48.     local liSize, lcBuff, liBase, ii
50.     m.liSize = 48 * this.cpu_nums
51.     m.lcBuff = replicate( chr(0), m.liSize )
52.     if ( 0 != NtQuerySystemInformation( ;
53.         SystemProcessorPerformanceInformation, @ m.lcBuff, m.liSize, 0 ))
54.       wait window nowait '获取 cpu 信息失败: ' + transform( m.iresult, '@0' )
55.       return
56.     endif
58.     for m.ii = 1 to this.cpu_nums
59.       m.liBase = 1 + ( m.ii - 1 ) * 48
60.       this.aCpuInfo[ m.ii, 1 ] = ;
61.         this.ctobin_big( substr( m.lcBuff, m.liBase +  0, 8 ))
62.       this.aCpuInfo[ m.ii, 2 ] = ;
63.         this.ctobin_big( substr( m.lcBuff, m.liBase +  8, 8 ))
64.       this.aCpuInfo[ m.ii, 3 ] = ;
65.         this.ctobin_big( substr( m.lcBuff, m.liBase + 16, 8 ))
66.     endfor
67.   endproc
69.   function ctobin_big( tcstring as string )
70.     return ;
71.         ctobin( substr( m.tcstring, 1, 2 ) + 0h0000, 'rs' ) ;
72.       + ctobin( substr( m.tcstring, 3, 2 ) + 0h0000, 'rs' ) * 0x10000 ;
73.       + ctobin( substr( m.tcstring, 5, 2 ) + 0h0000, 'rs' ) * 0x100000000 ;
74.       + ctobin( substr( m.tcstring, 7, 2 ) + 0h0000, 'rs' ) * 0x1000000000000
75.   endfunc
77.   procedure init
78.     declare long GetSystemInfo in win32api ;
79.       string @ lpsysteminfo
80.     declare long NtQuerySystemInformation in ntdll ;
81.       long systeminformationclass, ;
82.       string @ systeminformation, ;
83.       long systeminformationlength, ;
84.       long @ returnlength
86.     local lcBuff, lcName, loUsage, ii
88. *!* 获取本机已安装的 cpu 数量
89.     m.lcBuff = replicate( chr(0), 0x40 )
90.     GetSystemInfo( @ m.lcBuff )
91.     this.cpu_nums = ctobin( substr( m.lcBuff, 21, 4 ), 'rs' )
92.     dimension this.aCpuInfo[this.cpu_nums, 4]
94. *!* 创建更新计时器
95.     this.newobject( 'tmrUpdate', 'myTimer' )
96. *!* cpu 使用率显示对象, 每个 cpu 一个
97.     for m.ii = 1 to this.cpu_nums
98.       m.lcName = 'cntUsage' + transform(m.ii)
99.       this.newobject( m.lcName,  'myUsage' )
100.       m.loUsage = evaluate( 'this.' + m.lcName )
101.       with m.loUsage
102.         .move( 10+(m.ii-1)*(10+.width), 10, .width, this.height-20 )
103.         .anchor = 5
104.         .visible = .t.
105.       endwith
106.     endfor
107. *!* 调整表单宽度以显示所有使用率对象
108.     this.width = 10 + ( 10 + this.cntUsage1.width ) * this.cpu_nums
110.     this.getCpuTimeInfo()
111.   endproc
112. enddefine
114. define class myTimer as timer
115.   interval = 500            && 使用率更新间隔( ms )
116.   name = "timer1"
117.   procedure timer
118.     thisform.updateUsage()
119.   endproc
120. enddefine
122. define class myUsage as container
123.   borderwidth = 0
124.   backstyle = 0
125.   width = 50
126.   height = 100
127.   value = 0
129.   function value_assign( tnNewVal )     && 更新显示值
130.     this.lblUsage.caption = transform(round(m.tnNewVal*100,0)) + '%'
131.     with this
132.       .cntBar.height = ( .cntFull.height - 2 ) * m.tnNewVal
133.       .cntBar.top = .cntFull.height + .cntFull.top - .cntBar.height - 1
134.       .cntBar.backcolor = icase( ;
135.         m.tnNewVal <= 0.50, rgb(0,255,0), ;
136.         m.tnNewVal <= 0.75, rgb(255,255,0), rgb(255,0,0))
137.     endwith
138.   endfunc
140.   procedure init
141.     this.newobject( 'lblUsage', 'label' )
142.     with this.lblUsage
143.       .move( 0, 2, this.width, 16 )
144.       .alignment = 2
145.       .backstyle = 0
146.       .anchor = 11
147.       .visible = .t.
148.     endwith
149.     this.newobject( 'cntFull', 'container' )
150.     with this.cntFull
151.       .backcolor = rgb(255,255,255)
152.       .move( 0, 20, this.width, this.height - 20 )
153.       .anchor = 15
154.       .visible = .t.
155.     endwith
156.     this.newobject( 'cntBar', 'container' )
157.     with this.cntBar
158.       .backcolor = rgb(0,255,0)
159.       .borderwidth = 0
160.       .move( 1, 0, this.width-2, 0 )
161.       .visible = .t.
162.     endwith
164.     this.value = 0
165.   endproc
166. enddefine

单独做成一个类来使用的示例：
由于示例中要使用 inkey 函数来延时，所以类库中不能在使用 vfp 自己的计时器来定义更新 cpu 使用率数据，否则 inkey 函数将导致 vfp 的计时器暂停运行，所以这里用 api 函数 SetTimer 来生成一个外部的计时器，并将类库的 updateUsage 方法绑定到这个计时器上。但这也会带了一些问题，因为 inkey 函数肯定也会使用 SetTimer 来创建计时器，这样就可能发生冲突，由于只是想示例 NtQuerySystemInformation 函数的用法，所以类库中也没有仔细处理这些问题，如果你要用它且遇到了问题，可能要从下面几个方面来着手解决：
1. 绑定到 _vfp.hwnd 的 WM_TIMER 事件之前，先用 GetWindowLong 获取并保存好 vfp 原来的缺省窗口处理过程。
2. 被绑定的 updateUsage 处理过程中，应该先判断 p3 是否就是我们定义的 TIMER_ID 值，如果是才执行其中的更新代码，否则调用第一步中保存的 _vfp 缺省处理过程。
3. 定义不同的 TIMER_ID 试试，例如: 0x12345
4. 如果你的程序中使用这个类库的代码段内没有使用 inkey 函数，就恢复使用 vfp 的计时器事件来调用 updateUsage 方法。

2. clear
3. oo = newobject( 'cpuUsage' )
4. for m.ii = 1 to 50
5.   inkey(0.5)      && 这时候你应该干点别的什么，免得 cpu 一只闲着而总是显示 0
6.   ? oo.GetUsage(1)
7. endfor
8. oo = null
10. * ----------------------------------------------------
11. #define WM_TIMER        0x0113
12. #define TIMER_ID        200
14. define class cpuUsage as session
15.   cpu_nums = 0                  && 系统拥有的 cpu 个数
16.   dimension aCpuInfo[1,4]       && 1/2/3/4 - t_idle / t_kernel / t_user / usage
17.   
18.   procedure getUsage
19.     lparameters tiCpuNo         && 要获取使用率的 cpu 编号
20.     
21.     if ( pcount() < 1 ) or ( 'N' != vartype( m.tiCpuNo ))
22.       m.tiCpuNo = 1
23.     endif
24.     m.tiCpuNo = max( 1, min( this.cpu_nums, m.tiCpuNo ))
25.     return this.aCpuInfo[ m.tiCpuNo, 4 ]
26.   endproc
27.   
28.   procedure updateUsage          && 获取最新的 cpu 使用率信息
29.     lparameters p1, p2, p3, p4
30.     
31.     local array laTemp[1]
32.     local liIdleTime, liKernelTime, liUserTime, lnUsage, loUsage, ii
34.     acopy( this.aCpuInfo, m.laTemp )
35.     this.getCpuTimeInfo()
37.     for m.ii = 1 to this.cpu_nums
38.       m.liIdleTime  = m.laTemp[m.ii,1]
39.       m.liKernelTime    = m.laTemp[m.ii,2]
40.       m.liUserTime  = m.laTemp[m.ii,3]
41.       m.lnUsage = ;
42.         ( this.aCpuInfo[m.ii,1] - m.liIdletime ) / ;
43.         ( this.aCpuInfo[m.ii,2] + this.aCpuInfo[m.ii,3] ;
44.         - m.liKernelTime - m.liUserTime )
45.       this.aCpuInfo[m.ii,4] = round(( 1.00 - m.lnUsage ) * 100, 0 )
46.     endfor
47.   endproc
49.   procedure getCpuTimeInfo      && 获取最新的 cpu 空闲/核心/用户用时信息
50.     #define SystemProcessorPerformanceInformation   8
52.     local liSize, lcBuff, liBase, ii
54.     m.liSize = 48 * this.cpu_nums
55.     m.lcBuff = replicate( chr(0), m.liSize )
56.     if ( 0 != NtQuerySystemInformation( ;
57.         SystemProcessorPerformanceInformation, @ m.lcBuff, m.liSize, 0 ))
58.       wait window nowait '获取 cpu 信息失败: ' + transform( m.iresult, '@0' )
59.       return
60.     endif
62.     for m.ii = 1 to this.cpu_nums
63.       m.liBase = 1 + ( m.ii - 1 ) * 48
64.       this.aCpuInfo[ m.ii, 1 ] = ;
65.         this.ctobin_big( substr( m.lcBuff, m.liBase +  0, 8 ))
66.       this.aCpuInfo[ m.ii, 2 ] = ;
67.         this.ctobin_big( substr( m.lcBuff, m.liBase +  8, 8 ))
68.       this.aCpuInfo[ m.ii, 3 ] = ;
69.         this.ctobin_big( substr( m.lcBuff, m.liBase + 16, 8 ))
70.     endfor
71.   endproc
73.   function ctobin_big( tcstring as string )
74.     return ;
75.         ctobin( substr( m.tcstring, 1, 2 ) + 0h0000, 'rs' ) ;
76.       + ctobin( substr( m.tcstring, 3, 2 ) + 0h0000, 'rs' ) * 0x10000 ;
77.       + ctobin( substr( m.tcstring, 5, 2 ) + 0h0000, 'rs' ) * 0x100000000 ;
78.       + ctobin( substr( m.tcstring, 7, 2 ) + 0h0000, 'rs' ) * 0x1000000000000
79.   endfunc
81.   procedure init
82.     declare long GetSystemInfo in win32api ;
83.       string @ lpSystemInfo
84.     declare long NtQuerySystemInformation in ntdll ;
85.       long SystemInformationClass, ;
86.       string @ SystemInformation, ;
87.       long SystemInformationLength, ;
88.       long @ ReturnLength
89.     declare long SetTimer in win32api ;
90.       long hWnd, long nIDEvent, long uElapse, long lpTimerFunc
91.     declare long KillTimer in win32api ;
92.       long hWnd, long uIDEvent
94.     local lcBuff
96.     *!* 获取本机已安装的 cpu 数量
97.     m.lcBuff = replicate( chr(0), 0x40 )
98.     GetSystemInfo( @ m.lcBuff )
99.     this.cpu_nums = ctobin( substr( m.lcBuff, 21, 4 ), 'rs' )
100.     dimension this.aCpuInfo[this.cpu_nums, 4]
101.     this.aCpuInfo = 0
103.     SetTimer( _vfp.hwnd, TIMER_ID, 200, 0 )
104.     bindevent( _vfp.hwnd, WM_TIMER, this, 'updateUsage' )
105.     this.getCpuTimeInfo()
106.   endproc
107.   
108.   procedure destroy
109.     unbindevent( _vfp.hwnd, WM_TIMER )
110.     KillTimer( _vfp.hwnd, TIMER_ID )
111.   endproc
112. enddefine