关于头文件 2410Init.s的详细注释分析

工程里面的头文件 2410Init.s包括了板子上电后的初始话，具体有几个步骤：

讲述S3C2410启动程序设计

1.       屏蔽所有中断，关看门狗。

2.       根据工作频率设置PLL寄存器

3.       初始化存储控制相关寄存器

4.       初始化各模式下的栈指针

5.       设置缺省中断处理函数

6.       将数据段拷贝到RAM中，将零初始化数据段清零

7.       跳转到C语言Main入口函数中

 

要看懂这个头文件是比较难的，我跟DVD视频的教程看了两遍，弄懂了一些，视频上讲的是 ARM7 S3C44B0的 Init.s 但我觉得和2410的差不多。我将这个程序注释了一下。可能有些地方不是很正确，只提供参考。

;=========================================

; NAME: 2410INIT.S

; DESC: C start up codes

;       Configure memory, ISR ,stacks

;   Initialize C-variables

; HISTORY:

; 2002.02.25:kwtark: ver 0.0

; 2002.03.20:purnnamu: Add some functions for testing STOP,POWER_OFF mode

; 2002.04.10:SJS:sub interrupt disable 0x3ff -> 0x7ff

; 2002.11.29:Kong:DCD BANKSIZE Resiger 0x32 -> 0xb2 (ARM core burst enable)

;=========================================

    INCLUDE option.inc

    INCLUDE memcfg.inc

    INCLUDE 2410addr.inc

BIT_SELFREFRESH EQU (1<<22)

;下面是对arm处理器模式寄存器对应值的常数定义，arm处理器中有一个CPSR程序状态寄存器 它的后五位决定目前的处理器模式

;Pre-defined constants

USERMODE    EQU     0x10

FIQMODE     EQU     0x11

IRQMODE     EQU     0x12

SVCMODE     EQU     0x13

ABORTMODE   EQU     0x17

UNDEFMODE   EQU     0x1b

MODEMASK    EQU     0x1f

NOINT       EQU     0xc0

;The location of stacks

UserStack   EQU (_STACK_BASEADDRESS-0x3800)     ;0x33ff4800 ~

SVCStack    EQU (_STACK_BASEADDRESS-0x2800)     ;0x33ff5800 ~

UndefStack  EQU (_STACK_BASEADDRESS-0x2400)     ;0x33ff5c00 ~

AbortStack  EQU (_STACK_BASEADDRESS-0x2000)     ;0x33ff6000 ~

IRQStack    EQU (_STACK_BASEADDRESS-0x1000)     ;0x33ff7000 ~

FIQStack    EQU (_STACK_BASEADDRESS-0x0)        ;0x33ff8000 ~

;check if tasm.exe is used.

;arm处理器有两种工作状态 1.arm:32位 这种工作状态下执行字对准的arm指令 2.Thumb:16位 这种工作状;态执行半字对准的Thumb指令

;因为处理器分为16位 32位两种工作状态 程序的编译器也是分16位和32两种编译方式 所以下面的程序用;于根据处理器工作状态确定编译器编译方式

;code16伪指令指示汇编编译器后面的指令为16位的thumb指令

;code32伪指令指示汇编编译器后面的指令为32位的arm指令

;这段是为了统一目前的处理器工作状态和软件编译方式（16位编译环境使用tasm.exe编译

;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.

    GBLL    THUMBCODE

    [ {CONFIG} = 16 ;if config==16 这里表示你的目前处于领先地16位编译方式

THUMBCODE SETL  {TRUE};设置THUMBCODE 为 true

        CODE32;转入32位编译模式

        |  ;else

THUMBCODE SETL  {FALSE};设置THUMBCODE 为 false

        ]

        MACRO

    MOV_PC_LR

        [ THUMBCODE

            bx lr

        |

            mov pc,lr

        ]

    MEND

        MACRO

    MOVEQ_PC_LR

        [ THUMBCODE

            bxeq lr

        |

            moveq pc,lr

        ]

    MEND

;注意下面这段程序是个宏定义 很多人对这段程序不理解 我再次强调这是一个宏定义 所以大家要注意了

;下面包含的HandlerXXX HANDLER HandleXXX将都被下面这段程序展开

;这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。

;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字

;空间都有一个标号，以Handle***命名。

;在向量中断模式下使用“加载程序”来执行中断服务程序。

;这里就必须讲一下向量中断模式和非向量中断模式的概念

;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的;

;指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址

;函数中 节省了中断处理时间提高了中断处理速度标 例如 ADC中断的向量地址为0xC0,则在0xC0处放如下

;代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会

;自动跳转到HandlerADC函数中

;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt

;pending寄存器中对应标志位置位 然后跳转到位于0x18处的统一中断

;函数中 该函数通过读取interrupt pending寄存器中对应标志位 来判断中断源 并根据优先级关系再跳到

;对应中断源的处理代码中

        MACRO

$HandlerLabel HANDLER $HandleLabel

;HandlerLabel为中断服务入口地址

$HandlerLabel

    sub     sp,sp,#4        ;decrement sp(to store jump address)

    ;将要使用的r0寄存器入栈

    stmfd   sp!,{r0}        ;PUSH the work register to stack(lr does't push because it return to original address)

    ldr     r0,=$HandleLabel;load the address of HandleXXX to r0

    ldr     r0,[r0]         ;load the contents(service routine start address) of HandleXXX

    ;将对应的中断函数首地址入栈

    str     r0,[sp,#4]      ;store the contents(ISR) of HandleXXX to stack

    ;将中断函数首地址出栈 放入程序指针中 系统将跳转到对应中断处理函数

    ldmfd   sp!,{r0,pc}     ;POP the work register and pc(jump to ISR)

    MEND

   

;一个arm由RO,RW,ZI三个断组成 其中RO为代码段，RW是已经初始化的全局变量，ZI是未初始化的全局变量

;（对于GNU工具 对应的概念是TEXT ,DATA,BSS）bootloader

;bootloader要将RW段复制到ram中并将ZI段清零 编译器使用下列段来记录各段的起始和结束地址

; |Image$$RO$$Base| ; RO段起始地址

; |Image$$RO$$Limit| ; RO段结束地址加1

; |Image$$RW$$Base| ; RW段起始地址

; |Image$$RW$$Limit| ; RW段结束地址加1

; |Image$$ZI$$Base| ; ZI段起始地址

; |Image$$ZI$$Limit| ; ZI段结束地址加1

;这些标号的值是通过编译器的设定来确定的 如编译软件中对ro-base和rw-base的设定，例如 ro-;base=0xc000000 rw-base=0xc5f0000

    IMPORT  |Image$$RO$$Limit|  ; End of ROM code (=start of ROM data)

    IMPORT  |Image$$RW$$Base|   ; Base of RAM to initialise

    IMPORT  |Image$$ZI$$Base|   ; Base and limit of area

    IMPORT  |Image$$ZI$$Limit|  ; to zero initialise

   

   

    IMPORT  Main    ; The main entry of mon program

   

    AREA    Init,CODE,READONLY

;异常中断矢量表（每个表项占4个字节） 下面是中断向量表 一旦系统运行时有中断发生 即使移植了操作;系统 如linux 处理器已经把控制权交给了操作系统 一旦发生中断 处理器还是会跳转到从0x0开始

;中断向量表中某个中断表项（依据中断类型）开始执行

;具体中断向量布局请参考s3c44b0 spec 例如 adc中断向量为 0x000000c0下面对应表中第49项位置 向量地址0x0+4*(49-1)=0x000000c0

    ENTRY

;板子上电和复位后 程序开始从位于0x0处开始执行硬件刚刚上电复位后 程序从这里开始执行跳转到标?

;为ResetHandler处执行

    ;1)The code, which converts to Big-endian, should be in little endian code.

    ;2)The following little endian code will be compiled in Big-Endian mode.

    ;  The code byte order should be changed as the memory bus width.

    ;3)The pseudo instruction,DCD can't be used here because the linker generates error.

    ;总线宽度判?

    ;DCD用于分配一段字内存单片，并用后面的伪指令初始化

    ;分配字节由expr 个数决定

    ASSERT  :DEF:ENDIAN_CHANGE

    [ ENDIAN_CHANGE

        ASSERT  :DEF:ENTRY_BUS_WIDTH

        [ ENTRY_BUS_WIDTH=32

        b   ChangeBigEndian     ;DCD 0xea000007

        ]

       

        [ ENTRY_BUS_WIDTH=16

        andeq   r14,r7,r0,lsl #20   ;DCD 0x0007ea00

        ]

       

        [ ENTRY_BUS_WIDTH=8

        streq   r0,[r0,-r10,ror #1] ;DCD 0x070000ea

            ]

    |

        b   ResetHandler 

        ]

    b   HandlerUndef    ;handler for Undefined mode

    b   HandlerSWI      ;handler for SWI interrupt

    b   HandlerPabort   ;handler for PAbort

    b   HandlerDabort   ;handler for DAbort

    b   .               ;reserved 0x14

    b   HandlerIRQ      ;handler for IRQ interrupt

    b   HandlerFIQ      ;handler for FIQ interrupt

;@0x20

    b   EnterPWDN

 ;大小端判断

ChangeBigEndian

;@0x24

    [ ENTRY_BUS_WIDTH=32

        DCD 0xee110f10  ;0xee110f10 => mrc p15,0,r0,c1,c0,0

        DCD 0xe3800080  ;0xe3800080 => orr r0,r0,#0x80;  //Big-endian

        DCD 0xee010f10  ;0xee010f10 => mcr p15,0,r0,c1,c0,0

    ]

    [ ENTRY_BUS_WIDTH=16

        DCD 0x0f10ee11

        DCD 0x0080e380 

        DCD 0x0f10ee01 

    ]

    [ ENTRY_BUS_WIDTH=8

        DCD 0x100f11ee 

        DCD 0x800080e3 

        DCD 0x100f01ee 

        ]

    DCD 0xffffffff  ;swinv 0xffffff is similar with NOP and run well in both endian mode.

    DCD 0xffffffff

    DCD 0xffffffff

    DCD 0xffffffff

    DCD 0xffffffff

    b ResetHandler

   

;进入掉电模式功能

; 1. SDRAM 必须在自刷新模式.

; 2. 所有中断必须屏蔽 for SDRAM/DRAM self-refresh.

; 3. LCD 关闭for SDRAM/DRAM self-refresh.

; 4. The I-cache 可能需要开启.

; 5. The location of the following code may have not to be changed.

;void EnterPWDN(int CLKCON);

EnterPWDN          

    mov r2,r0               ;r2=rCLKCON

    tst r0,#0x8             ;POWER_OFF mode?

    bne ENTER_POWER_OFF

ENTER_STOP 

    ldr r0,=REFRESH    

    ldr r3,[r0]                     ;r3=rREFRESH   

    mov r1, r3

    orr r1, r1, #BIT_SELFREFRESH

    str r1, [r0]                    ;Enable SDRAM self-refresh

    mov r1,#16          ;wait until self-refresh is issued. may not be needed.

0   subs r1,r1,#1

    bne %B0

    ldr r0,=CLKCON      ;enter STOP mode.

    str r2,[r0]   

    mov r1,#32

0   subs r1,r1,#1   ;1) wait until the STOP mode is in effect.

    bne %B0         ;2) Or wait here until the CPU&Peripherals will be turned-off

                    ;   Entering POWER_OFF mode, only the reset by wake-up is available.

    ldr r0,=REFRESH     ;exit from SDRAM self refresh mode.

    str r3,[r0]

   

    MOV_PC_LR

ENTER_POWER_OFF

    ;NOTE.

    ;1) rGSTATUS3 should have the return address after wake-up from POWER_OFF mode.

   

    ldr r0,=REFRESH    

    ldr r1,[r0]                     ;r1=rREFRESH   

    orr r1, r1, #BIT_SELFREFRESH

    str r1, [r0]                    ;Enable SDRAM self-refresh

    mov r1,#16          ;Wait until self-refresh is issued,which may not be needed.

0   subs r1,r1,#1

    bne %B0

    ldr     r1,=MISCCR

    ldr r0,[r1]

    orr r0,r0,#(7<<17)  ;Make sure that SCLK0:SCLK->0, SCLK1:SCLK->0, SCKE="L" during boot-up

    str r0,[r1]

    ldr r0,=CLKCON

    str r2,[r0]   

    b .                 ;CPU will die here.

   

WAKEUP_POWER_OFF

    ;Release SCLKn after wake-up from the POWER_OFF mode.

    ldr r1,=MISCCR

    ldr r0,[r1]

    bic r0,r0,#(7<<17)      ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:L->H

    str r0,[r1]

   

    ;Set memory control registers

    ldr r0,=SMRDATA

    ldr r1,=BWSCON      ;BWSCON Address

    add r2, r0, #52     ;End address of SMRDATA

0      

    ldr r3, [r0], #4   

    str r3, [r1], #4   

    cmp r2, r0     

    bne %B0

    mov r1,#256

0   subs r1,r1,#1       ;1) wait until the SelfRefresh is released.

    bne %B0

    ldr r1,=GSTATUS3    ;GSTATUS3 has the start address just after POWER_OFF wake-up

    ldr r0,[r1]

    mov pc,r0

    LTORG

    ;下面是具体的中断处理函数跳转的宏，通过上面的$HandlerLabel的宏定义展开后跳转到对应的中断处理;函数（对于向量中断）

HandlerFIQ      HANDLER HandleFIQ

HandlerIRQ      HANDLER HandleIRQ

HandlerUndef    HANDLER HandleUndef

HandlerSWI      HANDLER HandleSWI

HandlerDabort   HANDLER HandleDabort

HandlerPabort   HANDLER HandlePabort

;下面这段程序是用来处理非向量中断，具体判断I_ISPR中各位是否置1 置1表示目前此中断等待响应（每次只能有一位置1），从最高优先级中断位开始判断，检测到等待服务

;中断就将pc置为中断服务函数首地址

IsrIRQ 

    sub     sp,sp,#4       ;预留返回指针的存储位置

    stmfd   sp!,{r8-r9}  

   

    ldr     r9,=INTOFFSET

    ldr     r9,[r9];载入I_ISR

    ldr     r8,=HandleEINT0

    add     r8,r8,r9,lsl #2

    ldr     r8,[r8]

    str     r8,[sp,#8]

    ldmfd   sp!,{r8-r9,pc}

;=======

; ENTRY 

;=======

;扳子上电和复位后 程序开始从位于0x0执行b ResetHandler 程序从跳转到这里执行

;板子上电复位后 执行几个步骤这里通过标号在注释中加1，2，3....标示 标号表示执行顺序

;1.禁止看门狗 屏蔽所有中断

ResetHandler

    ldr r0,=WTCON           ;watch dog disable

    ldr r1,=0x0        

    str r1,[r0]

    ldr r0,=INTMSK

    ldr r1,=0xffffffff      ;all interrupt disable

    str r1,[r0]

    ldr r0,=INTSUBMSK

    ldr r1,=0x7ff           ;all sub interrupt disable, 2002/04/10

    str r1,[r0]

    [ {FALSE}

        ; rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);   

        ; Led_Display

    ldr r0,=GPFCON

    ldr r1,=0x5500     

    str r1,[r0]

    ldr r0,=GPFDAT

    ldr r1,=0x10

    str r1,[r0]

    ]

;2.根据工作频率设置pll

;这里介绍一下计算公式

;Fpllo=(m*Fin)/(p*2^s)

;m=MDIV+8,p=PDIV+2,s=SDIV

;Fpllo必须大于20Mhz小于66Mhz

;Fpllo*2^s必须小于170Mhz

;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中

;#elif (MCLK==40000000)

;#define PLL_M (0x48)

;#define PLL_P (0x3)

;#define PLL_S (0x2)

;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2

;硬件使用晶振为10Mhz,即Fin=10Mhz

;Fpllo=80*10/5*2^2=40Mhz

    ;To reduce PLL lock time, adjust the LOCKTIME register.

    ldr r0,=LOCKTIME

    ldr r1,=0xffffff

    str r1,[r0]

       

        [ PLL_ON_START

    ;Configure MPLL

    ldr r0,=MPLLCON         

    ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV)  ;Fin=12MHz,Fout=50MHz

    str r1,[r0]

    ]

    ;Check if the boot is caused by the wake-up from POWER_OFF mode.

    ldr r1,=GSTATUS2

    ldr r0,[r1]

    tst r0,#0x2

        ;In case of the wake-up from POWER_OFF mode, go to POWER_OFF_WAKEUP handler.

    bne WAKEUP_POWER_OFF

    EXPORT StartPointAfterPowerOffWakeUp

StartPointAfterPowerOffWakeUp

;3.置存储相关寄存器的程序

;这是设置SDRAM,flash ROM 存储器连接和工作时序的程序,片选定义的程序

;SMRDATA map在下面的程序中定义

;SMRDATA中涉及的值请参考memcfg.s程序

;具体寄存器各位含义请参考s3c44b0 spec

    ;Set memory control registers

    ldr r0,=SMRDATA

    ldr r1,=BWSCON      ;BWSCON Address

    add r2, r0, #52     ;End address of SMRDATA

0      

    ldr r3, [r0], #4   

    str r3, [r1], #4   

    cmp r2, r0     

    bne %B0

   

        ;Initialize stacks

    bl  InitStacks

;5.设置缺省中断处理函数   

    ; Setup IRQ handler

    ldr r0,=HandleIRQ       ;This routine is needed

    ldr r1,=IsrIRQ          ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c

    str r1,[r0]

    ;Copy and paste RW data/zero initialized data

    ldr r0, =|Image$$RO$$Limit|     ; Get pointer to ROM data

    ldr r1, =|Image$$RW$$Base|      ; and RAM copy

    ldr r3, =|Image$$ZI$$Base| 

;6.将数据段拷贝到ram中 将零初始化数据段清零 跳入C语言的main函数执行 到这步结束bootloader初步引导结束    

    ;Zero init base => top of initialised data

    cmp r0, r1      ; Check that they are different

    beq %F2

1      

    cmp r1, r3      ; Copy init data

    ldrcc   r2, [r0], #4    ;--> LDRCC r2, [r0] + ADD r0, r0, #4        

    strcc   r2, [r1], #4    ;--> STRCC r2, [r1] + ADD r1, r1, #4

    bcc %B1       ;r1 < r3 继续循环

2      

    ldr r1, =|Image$$ZI$$Limit| ; Top of zero init segment

    mov r2, #0

3      

    cmp     r3, r1      ; Zero init

    strcc   r2, [r3], #4

    bcc     %B3

   

    [ :LNOT:THUMBCODE

        bl  Main        ;Don't use main() because ......

        b   .                      

    ]

    [ THUMBCODE         ;for start-up code for Thumb mode

        orr lr,pc,#1

        bx  lr

        CODE16

        bl  Main        ;Don't use main() because ......

        b   .

        CODE32

    ]

;function initializing stacks

InitStacks

    ;Don't use DRAM,such as stmfd,ldmfd......

    ;SVCstack is initialized before

    ;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'

    mrs r0,cpsr

    bic r0,r0,#MODEMASK ;位清零指令,清r0,再附给ro

    orr r1,r0,#UNDEFMODE|NOINT

    msr cpsr_cxsf,r1                ;UndefMode

    ldr sp,=UndefStack

   

    orr r1,r0,#ABORTMODE|NOINT

    msr cpsr_cxsf,r1                ;AbortMode

    ldr sp,=AbortStack

    orr r1,r0,#IRQMODE|NOINT

    msr cpsr_cxsf,r1                ;IRQMode

    ldr sp,=IRQStack

   

    orr r1,r0,#FIQMODE|NOINT

    msr cpsr_cxsf,r1                ;FIQMode

    ldr sp,=FIQStack

    bic r0,r0,#MODEMASK|NOINT

    orr r1,r0,#SVCMODE

    msr cpsr_cxsf,r1                ;SVCMode

    ldr sp,=SVCStack

   

    ;USER mode has not be initialized.

   

    mov pc,lr

    ;The LR register won't be valid if the current mode is not SVC mode.

   

;这是上面提到的对存储寄存器初始化的数据map

    LTORG

SMRDATA DATA

; Memory configuration should be optimized for best performance

; The following parameter is not optimized.                    

; Memory access cycle parameter strategy

; 1) The memory settings is  safe parameters even at HCLK="75Mhz".

; 2) SDRAM refresh period is for HCLK="75Mhz".

    DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))

    DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))   ;GCS0

    DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))   ;GCS1

    DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))   ;GCS2

    DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))   ;GCS3

    DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))   ;GCS4

    DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))   ;GCS5

    DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))    ;GCS6

    DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))    ;GCS7

;   DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)    ;Tchr not used bit

    DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+REFCNT)  ;设置刷新周期    

 

;   DCD 0x32            ;SCLK power saving mode, ARM core burst disable, BANKSIZE 128M/128M

    DCD 0xb2            ;SCLK power saving mode, ARM core burst enable , BANKSIZE 128M/128M - 11/29/2002

    DCD 0x30            ;MRSR6 CL="3clk"

    DCD 0x30            ;MRSR7

;   DCD 0x20            ;MRSR6 CL="2clk"

;   DCD 0x20            ;MRSR7

    ALIGN

    AREA RamData, DATA, READWRITE

;这里将中断异常向量建立在sdram中

    ^   _ISR_STARTADDRESS

HandleReset     #   4

HandleUndef     #   4

HandleSWI       #   4

HandlePabort    #   4

HandleDabort    #   4

HandleReserved  #   4

HandleIRQ       #   4

HandleFIQ       #   4

;Don't use the label 'IntVectorTable',

;The value of IntVectorTable is different with the address you think it may be.

;IntVectorTable

HandleEINT0     #   4

HandleEINT1     #   4

HandleEINT2     #   4

HandleEINT3     #   4

HandleEINT4_7   #   4

HandleEINT8_23  #   4

HandleRSV6      #   4

HandleBATFLT    #   4

HandleTICK      #   4

HandleWDT       #   4

HandleTIMER0    #   4

HandleTIMER1    #   4

HandleTIMER2    #   4

HandleTIMER3    #   4

HandleTIMER4    #   4

HandleUART2     #   4

HandleLCD       #   4

HandleDMA0      #   4

HandleDMA1      #   4

HandleDMA2      #   4

HandleDMA3      #   4

HandleMMC       #   4

HandleSPI0      #   4

HandleUART1     #   4

HandleRSV24     #   4

HandleUSBD      #   4

HandleUSBH      #   4

HandleIIC       #   4

HandleUART0     #   4

HandleSPI1      #   4

HandleRTC       #   4

HandleADC       #   4

    END

本文来自CSDN博客，转载请标明出处：http://blog.csdn.net/ymzhou117/archive/2010/04/22/5517863.aspx