在托盘图标中添加气球提示

转载 2004年07月11日 18:31:00
很多朋友都见到过能在托盘图标上出现气球提示的软件,不说软件,就是在“磁盘空间不足”时Windows给出的提示就属于气球提示,那么怎样在自己的程序中添加这样的气球提示呢?

    其实并不难,关键就在添加托盘图标时所使用的NOTIFYICONDATA结构,源代码如下:

窗体模块:

Option Explicit

Private Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long

Private Type NOTIFYICONDATA
    cbSize As Long              ' 结构大小(字节)
    hwnd As Long                ' 处理消息的窗口的句柄
    uId As Long                 ' 唯一的标识符
    uFlags As Long              ' Flags
    uCallBackMessage As Long    ' 处理消息的窗口接收的消息
    hIcon As Long               ' 托盘图标句柄
    szTip As String * 128       ' Tooltip 提示文本
    dwState As Long             ' 托盘图标状态
    dwStateMask As Long         ' 状态掩码
    szInfo As String * 256      ' 气球提示文本
    uTimeoutOrVersion As Long   ' 气球提示消失时间或版本
                                ' uTimeout - 气球提示消失时间(单位:ms, 10000 -- 30000)
                                ' uVersion - 版本(0 for V4, 3 for V5)
    szInfoTitle As String * 64  ' 气球提示标题
    dwInfoFlags As Long         ' 气球提示图标
End Type

' dwState to NOTIFYICONDATA structure
Private Const NIS_HIDDEN = &H1              ' 隐藏图标
Private Const NIS_SHAREDICON = &H2          ' 共享图标

' dwInfoFlags to NOTIFIICONDATA structure
Private Const NIIF_NONE = &H0               ' 无图标
Private Const NIIF_INFO = &H1               ' "消息"图标
Private Const NIIF_WARNING = &H2            ' "警告"图标
Private Const NIIF_ERROR = &H3              ' "错误"图标

' uFlags to NOTIFYICONDATA structure
Private Const NIF_ICON As Long = &H2
Private Const NIF_INFO As Long = &H10
Private Const NIF_MESSAGE As Long = &H1
Private Const NIF_STATE As Long = &H8
Private Const NIF_TIP As Long = &H4

' dwMessage to Shell_NotifyIcon
Private Const NIM_ADD As Long = &H0
Private Const NIM_DELETE As Long = &H2
Private Const NIM_MODIFY As Long = &H1
Private Const NIM_SETFOCUS As Long = &H3
Private Const NIM_SETVERSION As Long = &H4

Private Sub Form_Load()
    ' 向托盘区添加图标
    Dim IconData As NOTIFYICONDATA
    Dim title As String
    title = "托盘程序" & vbNullChar
    With IconData
        .cbSize = Len(IconData)
        .hwnd = Me.hwnd
        .uId = 0
        .uFlags = NIF_TIP Or NIF_ICON Or NIF_MESSAGE Or NIF_INFO Or NIF_STATE
        .uCallBackMessage = WM_NOTIFYICON
        .szTip = title
        .hIcon = Me.Icon.Handle
        .dwState = 0
        .dwStateMask = 0
        .szInfo = "这是气球提示" & vbNullChar
        .szInfoTitle = title
        .dwInfoFlags = NIIF_INFO
        .uTimeoutOrVersion = 10000
    End With
    Shell_NotifyIcon NIM_ADD, IconData
    preWndProc = SetWindowLong(Me.hwnd, GWL_WNDPROC, AddressOf WindowProc)
End Sub

Private Sub Form_Unload(Cancel As Integer)
    ' 删除托盘区图标
    Dim IconData As NOTIFYICONDATA
    With IconData
        .cbSize = Len(IconData)
        .hwnd = Me.hwnd
        .uId = 0
        .uFlags = NIF_TIP Or NIF_ICON Or NIF_MESSAGE
        .uCallBackMessage = WM_NOTIFYICON
        .szTip = "托盘程序"
        .hIcon = Me.Icon.Handle
    End With
    Shell_NotifyIcon NIM_DELETE, IconData
    SetWindowLong Me.hwnd, GWL_WNDPROC, preWndProc

    ' 卸载所有窗体
    Dim frm As Form
    For Each frm In Forms
        Unload frm
    Next
End Sub

标准模块:

Option Explicit

Public Declare Function SetWindowLong Lib "user32.dll" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function CallWindowProc Lib "user32.dll" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Public Const WM_RBUTTONUP = &H205
Public Const WM_USER = &H400
Public Const WM_NOTIFYICON = WM_USER + 1            ' 自定义消息
Public Const WM_LBUTTONDBLCLK = &H203
Public Const GWL_WNDPROC = (-4)

' 关于气球提示的自定义消息, 2000下不产生这些消息
Public Const NIN_BALLOONSHOW = (WM_USER + &H2)      ' 当 Balloon Tips 弹出时执行
Public Const NIN_BALLOONHIDE = (WM_USER + &H3)      ' 当 Balloon Tips 消失时执行(如 SysTrayIcon 被删除),
                                                    ' 但指定的 TimeOut 时间到或鼠标点击 Balloon Tips 后的消失不发送此消息
Public Const NIN_BALLOONTIMEOUT = (WM_USER + &H4)   ' 当 Balloon Tips 的 TimeOut 时间到时执行
Public Const NIN_BALLOONUSERCLICK = (WM_USER + &H5) ' 当鼠标点击 Balloon Tips 时执行。
                                                    ' 注意:在XP下执行时 Balloon Tips 上有个关闭按钮,
                                                    ' 如果鼠标点在按钮上将接收到 NIN_BALLOONTIMEOUT 消息。

Public preWndProc As Long

' Form1 窗口入口函数
Function WindowProc(ByVal hwnd As Long, ByVal msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    ' 拦截 WM_NOTIFYICON 消息
    If msg = WM_NOTIFYICON Then
        Select Case lParam
            Case WM_RBUTTONUP
                ' 右键单击图标是运行这里的代码, 可以在这里添加弹出右键菜单的代码
            Case WM_LBUTTONDBLCLK
                Unload Form1
            Case NIN_BALLOONSHOW
                Debug.Print "显示气球提示"
            Case NIN_BALLOONHIDE
                Debug.Print "删除托盘图标"
            Case NIN_BALLOONTIMEOUT
                Debug.Print "气球提示消失"
            Case NIN_BALLOONUSERCLICK
                Debug.Print "单击气球提示"
        End Select
    End If
    WindowProc = CallWindowProc(preWndProc, hwnd, msg, wParam, lParam)
End Function

*************************************************************************************
* 转载请通知作者并注明出处
* 作者:卢培培(goodname008)
* 邮箱:goodname008@163.com
*************************************************************************************

在托盘图标中添加气球提示

  • zgqtxwd
  • zgqtxwd
  • 2008年04月24日 13:22
  • 228

在托盘图标中添加气球提示

在托盘图标中添加气球提示document.title="在托盘图标中添加气球提示 - "+document.title     很多朋友都见到过能在托盘图标上出现气球提示的软件,不说软件,就是在“磁盘...
  • ntdll
  • ntdll
  • 2005年10月17日 20:39
  • 990

给托盘图标增加气球提示

先看一下下面这篇文章,可能对你会有帮助http:blog.csdn.net/XXKKFF/archive/2007/05/06/1598526.aspx在vc 6.0里要给托盘增加气球提示的确要费一番...
  • XXKKFF
  • XXKKFF
  • 2007年05月11日 21:27
  • 2459

MFC 托盘中添加程序图标

因为转载的这篇文章的作者也是转载的,所以找不到原作者的URL,在此只做对自己的技术储备。 1、在资源中的Icon中导入一个自己喜欢的图标,ID命名为IDR_MAINFRAME,将先前的IDR...
  • lxp116
  • lxp116
  • 2013年11月22日 14:25
  • 1849

vc添加任务栏托盘图标

添加一个托盘图标是很有必要的,如果要实现程序的隐藏和唤醒的话。 令一方面添加了托盘图标的程序比较方便用户进行退出等操作,而且有时候我们可以添加一些信息,让用户移动到图标上时候显示。最后还可以搞个简单...
  • fanzheng220112583
  • fanzheng220112583
  • 2012年10月10日 20:36
  • 980

VC6系统托盘类|崩溃自动重建图标|HOOK窗口消息|气泡效果更新SDK

解决制作托盘气泡提示中遇到的NIF_INFO : undeclared identifier VC6下实现托盘气泡提示的关键是要更新SDK,实际上应该就是要更新SHELLAPI.h,SHELL32.l...
  • djimon
  • djimon
  • 2009年07月16日 14:33
  • 2717

使用jQuery实现显示文字气球的提示

使用jQuery实现显示文字气球的提示 本文由 arthinking 发表于884 天前 ⁄ Javascript ⁄ 暂无评论 ⁄ 被围观 3,115 views+ 为了使页...
  • xiyang_1990
  • xiyang_1990
  • 2013年10月15日 22:33
  • 1109

C#下实现动态系统托盘图标

  Visual   C#是微软公司推出的下一代程序开发语言,是微软.Net框架中的的一个重要组成部分。微软的.Net平台堪称为新一代的互联网平台。对于技术开发人员来说,.Net平台的两大特性是非常卓...
  • WSJ741
  • WSJ741
  • 2008年02月11日 16:21
  • 449

托盘图标提示

2004年10月14日 10:02:00 窗体代码***********************************************************************...
  • softart
  • softart
  • 2007年10月27日 12:02
  • 207

托盘图标提示

***************************************************************************模 块 名:frmTest**说    明:YFs...
  • yefanqiu
  • yefanqiu
  • 2004年10月14日 10:02
  • 8194
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:在托盘图标中添加气球提示
举报原因:
原因补充:

(最多只允许输入30个字)