DOS命令添加, 删除, 查询系统环境变量(永久/临时生效)

原创 2015年07月07日 01:24:30


DOS命令添加, 删除, 查询系统环境变量(永久/临时生效)


参考:
cmd - Is there a command to refresh environment variables from the command prompt in Windows? - Stack Overflow  
https://stackoverflow.com/questions/171588/is-there-a-command-to-refresh-environment-variables-from-the-command-prompt-in-w


1、修改注册表的方法要重启/注销/重启explorer进程才生效(永久的)

reg add "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v path /d "%path%;C:\" /f


2、使用WMIC,立即生效(永久的)(不影响已经打开的cmd, 只影响新打开的cmd)

wmic ENVIRONMENT create name="test1",username="<system>",VariableValue="test_val1"           新增变量

wmic ENVIRONMENT where "name='temp'" get UserName,VariableValue    获取变量
wmic ENVIRONMENT where "name='test1' and username='<system>'" set VariableValue="%path%;e:\tools"      修改变量
wmic ENVIRONMENT where "name='test1'" delete     删除变量


3、要在批处理中立即生效(只是临时的,退出批处理后消失),

批处理中加一句:

path=%path%;C:\





如果使用了上面的第2个方法(WMIC命令), 想要给当前正在运行的cmd刷新修改后的环境变量, 2个办法:

方法1:

::  在批处理脚本中添加以下代码即可
@echo off
::
:: RefreshEnv.cmd
::
:: Batch file to read environment variables from registry and
:: set session variables to these values.
::
:: With this batch file, there should be no need to reload command
:: environment every time you want environment changes to propagate

echo | set /p dummy="Reading environment variables from registry. Please wait... "

goto main

:: Set one environment variable from registry key
:SetFromReg
    "%WinDir%\System32\Reg" QUERY "%~1" /v "%~2" > "%TEMP%\_envset.tmp" 2>NUL
    for /f "usebackq skip=2 tokens=2,*" %%A IN ("%TEMP%\_envset.tmp") do (
        echo/set "%~3=%%B"
    )
    goto :EOF

:: Get a list of environment variables from registry
:GetRegEnv
    "%WinDir%\System32\Reg" QUERY "%~1" > "%TEMP%\_envget.tmp"
    for /f "usebackq skip=2" %%A IN ("%TEMP%\_envget.tmp") do (
        if /I not "%%~A"=="Path" (
            call :SetFromReg "%~1" "%%~A" "%%~A"
        )
    )
    goto :EOF

:main
    echo/@echo off >"%TEMP%\_env.cmd"

    :: Slowly generating final file
    call :GetRegEnv "HKLM\System\CurrentControlSet\Control\Session Manager\Environment" >> "%TEMP%\_env.cmd"
    call :GetRegEnv "HKCU\Environment">>"%TEMP%\_env.cmd" >> "%TEMP%\_env.cmd"

    :: Special handling for PATH - mix both User and System
    call :SetFromReg "HKLM\System\CurrentControlSet\Control\Session Manager\Environment" Path Path_HKLM >> "%TEMP%\_env.cmd"
    call :SetFromReg "HKCU\Environment" Path Path_HKCU >> "%TEMP%\_env.cmd"

    :: Caution: do not insert space-chars before >> redirection sign
    echo/set "Path=%%Path_HKLM%%;%%Path_HKCU%%" >> "%TEMP%\_env.cmd"

    :: Cleanup
    del /f /q "%TEMP%\_envset.tmp" 2>nul
    del /f /q "%TEMP%\_envget.tmp" 2>nul

    :: Set these variables
    call "%TEMP%\_env.cmd"

    echo | set /p dummy="Done"
    echo .




方法2:

以下代码保存为resetvars.vbs

Set oShell = WScript.CreateObject("WScript.Shell")
filename = oShell.ExpandEnvironmentStrings("%TEMP%\resetvars.bat")
Set objFileSystem = CreateObject("Scripting.fileSystemObject")
Set oFile = objFileSystem.CreateTextFile(filename, TRUE)

set oEnv=oShell.Environment("System")
for each sitem in oEnv 
    oFile.WriteLine("SET """ & sitem & """")
next
path = oEnv("PATH")

set oEnv=oShell.Environment("User")
for each sitem in oEnv 
    oFile.WriteLine("SET """ & sitem & """")
next

path = path & ";" & oEnv("PATH")
oFile.WriteLine("SET ""PATH=" & path & """")
oFile.Close

在需要刷新环境变量的批处理中添加以下代码:

@echo off
%~dp0resetvars.vbs
call "%TEMP%\resetvars.bat"





以下批处理是通过操作注册表来添加, 删除, 查询系统环境变量


::DOS命令添加, 查询系统环境变量 
@echo off
echo 添加java环境变量
set regpath=HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment
set evname=JAVA_HOME
set javapath=c:\java\jdk
reg add "%regpath%" /v %evname% /d %javapath% /f

echo.
echo 查询path环境变量
REG QUERY "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path

echo.
echo 查询evname环境变量
REG QUERY "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v %evname%|findstr jdk

echo.
echo 获取path环境变量的具体值(具体值中不能有空格)
::delims=后面有一个空格
for /f "tokens=3 delims= " %%a in ('REG QUERY "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path') do (
  set "a=%%a"
  echo %%a
)

echo.
echo 获取evname环境变量的具体值(具体值中不能有空格)
::delims=后面有一个空格
for /f "tokens=3 delims= " %%a in ('REG QUERY "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v %evname%') do (
  set "a=%%a"
  echo %%a
)

echo.
echo 删除java环境变量
reg delete "%regpath%" /v "%evname%" /f
pause>nul
exit



                    
版权声明:本文为博主原创文章,未经博主允许不得转载。

相关文章推荐

DOS设置环境变量永久写入注册表

(ZZ)DOS设置环境变量永久写入注册表 博客分类: DOS DOSJavaJDKWindowsXP 最近在实现一个在Windows下的java可执行程序,这个可执行程序需要调用第...
  • felix_f
  • felix_f
  • 2014年03月20日 11:28
  • 1026

dos 设置环境变量

1  查看环境变量 echo %path% 2 设置环境变量 set path=%path%;C:/your/path

java在dos中设置环境变量和重定向

一、我的dos命令行为: Rscript test3.R >> c:\t.txt 2 >$1 意思是:将test3.R脚本运行的输出流和错误流,全部重定向到t.txt文件中。。。这个>>表示追加,>表...

使用Dos命令查看,修改环境变量

1,查看环境变量 set 用于查看全部的环境变量。 set 环境变量名 用于查看指定环境变量 2,往某一环境变量添加内容 set path=C:\Users\Paul;%p...
  • Jakawn
  • Jakawn
  • 2016年09月15日 15:53
  • 617

dos命令行设置环境变量

环境变量不一定要到属性的高级选项里面设置,还可以通过dos命令行的方式: for example: set path=%path%;C:\python26这样就会在环境变量的path后面追加pytho...

批处理设置系统环境变量

在软件运行过程中,可能需要配置计算机的环境变量,在这里以配置Java环境变量为例讲解几种配置方式。 1.  SET命令:这种语法只能在cmd Shell环境中有效,关闭运行环境环境变量将不保存。 例子...
  • peng790
  • peng790
  • 2016年09月11日 14:54
  • 4578

DOS下用于设置、修改和查看环境变量的命令之一

DOS下用于设置、修改和查看环境变量的命令之一   2011-11-09 21:03:39|  分类: 软件使用 |  标签:set  dos  设置环境变量  |字号 订阅       ...
  • haiross
  • haiross
  • 2014年02月20日 17:03
  • 788

详解Windows不重启使环境变量修改生效(经典)

http://hi.baidu.com/xckouy/item/ff135263dfd92a97c4d2496b 在“我的电脑”->“属性”->“高级”->“环境变量”中增加或修改环...

Windows 如何在cmd命令行中查看、修改、删除与添加环境变量

转载地址:http://www.cnblogs.com/saptechnique/archive/2013/02/17/2914222.html 首先明确一点:      所有的在cmd命令...
  • stpeace
  • stpeace
  • 2016年12月08日 00:14
  • 2630

如何在cmd命令行中查看、修改、删除与添加环境变量

首先明确一点: 所有的在cmd命令行下对环境变量的修改只对当前窗口有效,不是永久性的修改。也就是说当关闭此cmd命令行窗口后,将不再起作用。永久性修改环境变量的方法有两种:一种是直接修改注册表(此种...
  • wzsbll
  • wzsbll
  • 2011年08月16日 10:36
  • 74000
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:DOS命令添加, 删除, 查询系统环境变量(永久/临时生效)
举报原因:
原因补充:

(最多只允许输入30个字)