发送邮件的plsql代码

最新推荐文章于 2021-08-09 19:48:55 发布

huangwenkangz

最新推荐文章于 2021-08-09 19:48:55 发布

阅读量1.9k

点赞数

分类专栏： DB 文章标签： send mail 发送邮件 automail plsql send_mail

本文链接：https://blog.csdn.net/huangwenkangz/article/details/50495314

版权

DB 专栏收录该内容

12 篇文章 0 订阅

订阅专栏

用户肯定有需求说要发送邮件，对于系统一些情况，系统可以Schedule发送给指定用户，发送邮件有3种方法：

1、when before run concurrent，我们可以选择用户，当请求跑完之后系统会发邮件通知给此用户；

（此用户绑定了邮箱地址）；

2、使用预警管理系统，可以定时跑，可以对后台table触发情况下跑，然后可以发邮件，也可以运行指定的请求；

ps:第一种和第二种情况能使用的前提是要设置好系统的邮件服务器，需要配置邮件；而第二种预警管理系统要使用还要配置预警管理系统。

3、使用客制的发邮件程序，发送邮件，code如下：然后直接调用此包即可：

ps:要申请一个163邮箱，并开票POP3协议和SMTP协议，和授权密码

CREATE OR REPLACE PACKAGE BODY JW_SEND_MAIL_PKG IS

  PROCEDURE JW_SEND_MAIL_PROC(P_RECIPIENT VARCHAR2, -- 邮件接收人
                                         P_SUBJECT   VARCHAR2, -- 邮件标题
                                         P_MESSAGE   VARCHAR2 -- 邮件正文*/
                                         ) IS
    --下面四个变量请根据实际邮件服务器进行赋值
    V_MAILHOST VARCHAR2(30) := '220.181.12.17' ;--'220.181.12.17'; --SMTP服务器地址
    V_USER     VARCHAR2(30) := 'XXXXXXX'; --登录SMTP服务器的用户名；只是用户名，不包括163.com部分
    V_PASS     VARCHAR2(20) := 'XXXXXXXXXXXXXX'; --在163邮箱设置中开启POP3和SMTP协议，此处为授权密码
    V_SENDER   VARCHAR2(50) := 'XXXXXXX@163.com'; --发送都邮箱，一般与 ps_user 对应
    V_CONN     UTL_SMTP.CONNECTION; --到邮件服务器的连接
    V_MSG      VARCHAR2(32767); --邮件内容
     my_recipients VARCHAR2(32767) := P_RECIPIENT; 
  BEGIN
    V_CONN := UTL_SMTP.OPEN_CONNECTION(V_MAILHOST, 25);
    UTL_SMTP.EHLO(V_CONN, V_MAILHOST); --是用 ehlo() 而不是 helo() 函数
    --否则会报：ORA-29279: SMTP 永久性错误: 503 5.5.2 Send hello first.
  
    UTL_SMTP.COMMAND(V_CONN, 'AUTH LOGIN'); -- smtp服务器登录校验
    UTL_SMTP.COMMAND(V_CONN,
                     UTL_RAW.CAST_TO_VARCHAR2(UTL_ENCODE.BASE64_ENCODE(UTL_RAW.CAST_TO_RAW(V_USER))));
    UTL_SMTP.COMMAND(V_CONN,
                     UTL_RAW.CAST_TO_VARCHAR2(UTL_ENCODE.BASE64_ENCODE(UTL_RAW.CAST_TO_RAW(V_PASS))));
  
    UTL_SMTP.MAIL(V_CONN, '<' || V_SENDER || '>'); --设置发件人
    
    WHILE (my_recipients IS NOT NULL) --收件人
    LOOP
      utl_smtp.rcpt(V_CONN, '<' || get_address(my_recipients) || '>');   ----多个收件人用逗号隔开
    END LOOP; 
   -- UTL_SMTP.RCPT(V_CONN, '<' || P_RECIPIENT || '>'); --设置收件人
    -- UTL_SMTP.RCPT(V_CONN, '<' || 'tangr@scdtech.cn' || '>'); --设置收件人
    -- 创建要发送的邮件内容 注意报头信息和邮件正文之间要空一行
    V_MSG := 'Date:' || TO_CHAR(SYSDATE, 'dd mon yy hh24:mi:ss') ||
             UTL_TCP.CRLF || 'From: ' || V_SENDER || '<' || V_SENDER || '>' ||
             UTL_TCP.CRLF || 'To: ' || P_RECIPIENT || '<' || P_RECIPIENT || '>' || 
             UTL_TCP.CRLF || CONVERT('Subject: ' || P_SUBJECT ||
                                     UTL_TCP.CRLF || UTL_TCP.CRLF,
                                     'ZHS16GBK') -- 这前面是报头信息
             || CONVERT(P_MESSAGE || UTL_TCP.CRLF || UTL_TCP.CRLF, 'ZHS16GBK'); -- 这个是邮件正文
  
    UTL_SMTP.OPEN_DATA(V_CONN); --打开流
    UTL_SMTP.WRITE_RAW_DATA(V_CONN, UTL_RAW.CAST_TO_RAW(V_MSG)); --这样写标题和内容都能用中文
    UTL_SMTP.CLOSE_DATA(V_CONN); --关闭流
    UTL_SMTP.QUIT(V_CONN); --关闭连接
  
  EXCEPTION
    WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE(DBMS_UTILITY.FORMAT_ERROR_STACK);
      DBMS_OUTPUT.PUT_LINE(DBMS_UTILITY.FORMAT_CALL_STACK);
      UTL_SMTP.QUIT(V_CONN); --关闭连接 
  END JW_SEND_MAIL_PROC;
  
  FUNCTION get_address(addr_list IN OUT VARCHAR2) RETURN VARCHAR2 IS
    addr VARCHAR2(256);
    i    PLS_INTEGER;
  
    FUNCTION lookup_unquoted_char(str IN VARCHAR2, chrs IN VARCHAR2)
      RETURN PLS_INTEGER AS
      c            VARCHAR2(5);
      i            PLS_INTEGER;
      len          PLS_INTEGER;
      inside_quote BOOLEAN;
    
    BEGIN
      inside_quote := FALSE;
      i            := 1;
      len          := length(str);
      WHILE (i <= len)
      LOOP
        c := substr(str, i, 1);
        IF (inside_quote)
        THEN
          IF (c = '"')
          THEN
            inside_quote := FALSE;
          ELSIF (c = '\')
          THEN
            i := i + 1; -- Skip the quote character
          END IF;
        END IF;
        IF (c = '"')
        THEN
          inside_quote := TRUE;
        END IF;
        IF (instr(chrs, c) >= 1)
        THEN
          RETURN i;
        END IF;
      
        i := i + 1;
      END LOOP;
      RETURN 0;
    END;
  
  BEGIN
    addr_list := ltrim(addr_list);
    i         := lookup_unquoted_char(addr_list, ';');
    IF (i >= 1)
    THEN
      addr      := substr(addr_list, 1, i - 1);
      addr_list := substr(addr_list, i + 1);
    ELSE
      addr      := addr_list;
      addr_list := '';
    END IF;
    i := lookup_unquoted_char(addr, '<');
    IF (i >= 1)
    THEN
      addr := substr(addr, i + 1);
      i    := instr(addr, '>');
      IF (i >= 1)
      THEN
        addr := substr(addr, 1, i - 1);
      END IF;
    END IF;
    RETURN addr;
  END;

END JW_SEND_MAIL_PKG;