如何从数据库中提取文件？

在这篇文章里，我们演示了一个方法，使用ActiveX动态链接库和ASP，可以从微软SQL Server服务器把图片装载到Web浏览器。它已经表明，这个方法在快速开发、容易使用和自定义Web页面的灵活上都有优势。动态链接库被用来连接数据库，提取图片数据，把图片数据放入文件。ASP页面则负责与SQL数据库和动态链接库通信。我们已经介绍了设置SQL数据库和Web项目的操作过程。 

 

微软SQL Server数据库服务器能够在SQL数据库里保存图片和大量的文本。图片和文本使用的数据类型分别是image图片类型和text文本类型。假如使用VB或VC开发前端应用程序，在windows操作系统上运行，那么可以容易地从SQL数据库里提取图片数据，把它放入一个文件，并在屏幕上显示出来。但是，要是想从SQL Server得到图片，并在Web浏览器里显示，就不那么容易了。虽然在微软SQL Server 6.5里提供了Web助理和存储过程 sp_makewebtask、sp_runwebtask，它们能够把SQL数据库里的数据转化成HTML文件，但是我们有更好的解决办法。使用Web助理的一个问题是，它不接受图片数据类型的字段。另一方面，存储过程 sp_makewebtask 的参数太多，很难使用，而且也很难对Web页面进行自定义。

我们在这里提供了一个解决方案，把图片从SQL数据装载到Web浏览器，这个方案要比sp_makewebtask好。我们用一个ActiveX 动态链接库和ASP页面开发了一个Web项目。动态链接库负责打开到保存图片的SQL数据库的连接，从数据库提取图片并把它们保存在临时文件里。ASP和动态链接库进行通信，取得临时图片文件的位置。这样，当访问者点击Web站点时，图片就会下载到他的浏览器。在这篇文章里，我们要介绍设置SQL数据库的步骤。然后，我们还要介绍如何利用VB5和活动数据对象ADO 1.5建立ActiveX动态链接库。最后，我们还要讨论建立ASP Web项目、连接到SQL数据库以及编写ASP文件的处理过程。
设置SQL数据库

这篇文章里使用的数据库非常简单，只包含一个表，名字叫Products，代表普通小杂货店里的各种不同的商品。设置数据库的第一步是建在微软SQL Server里建立一个数据库设备（译者注：在SQL Server 7.0里，数据库设备的概念已经取消） 。虽然可以编写SQL脚本来设置数据库，但是使用SQL企业管理器操作更容易些。打开企业管理器，在树中选择数据库设备（Database Device）。单击鼠标右键，在快捷菜里选择新建设备（New Device）。在名称（Name ）字段里，输入Grocevb_dev，把这个设备的大小设置为2MB。然后，单击建立（Create Now ） 按钮，就建立了数据库。接着，用同样的方法建立另一个数据库设备，作为日志文件。给这个设备起名叫Grocevb_log ，把它的大小设置为1MB。

下一步，需要建立一个新的数据库。在树中选择数据库（Database），单击右键。然后，在弹出菜单里选择新建数据库（New Database）。在建立新数据库对话框里，输入数据库名称 grocevb，并从下拉列表里选择前面建立的Grocevb_dev 作为数据设备， Grocevb_log 作为日志设备。然后，单击建立（Create Now）按钮，数据库就建立了。我们暂时忽略有关数据库安全性、数据库备份、用户访问等方面的问题，因为它们跟这篇文章没有直接的关系。

我们建立的数据库只有一个表，表名是Products。在这个表里有几个字段，其中，有两个字段prod_image 和 prod_imagetype 需要特别说明。prod_image 字段的数据类型是image图片，在这个字段里保存某个产品的图片。prod_imagetype 字段保存图片的类型，比如.gif 或 .jpg，这是在互联网上最常用的两种图片类型。这个表的主关键字是prod_id，它是非集簇的索引。这样，每个图片都有一个唯一的 prod_id。在 列表 A里给出了建立 Products 表的SQL脚本。在这个表里，只放了四个产品，用于本文演示。

列表A:建立products表的脚本。

/** 用来建立ImageLoader VB动态链接库使用的产品表。**/
CREATE TABLE Products
(
prod_id int CONSTRAINT pk_prod PRIMARY KEY NONCLUSTERED IDENTITY(1, 1),
categ_id int NULL CONSTRAINT fk_prod REFERENCES categories(categ_id),
prod_name char(80) NOT NULL UNIQUE NONCLUSTERED,
prod_unitprice money NOT NULL,
prod_unitquant char(15) NOT NULL,
prod_desc varchar(255) NULL DEFAULT ('unknown'),
prod_imagetype char(3) NOT NULL,
prod_image image NOT NULL,)
GO

建立ActiveX 动态链接库

使用 VB 5.0，我们要开发一个ActiveX 动态链接库。这个动态链接库让我们能够连接到SQL数据库，提取图片数据，并把它们保存成文件，放在目录里。要建立动态链接库，请在打开VB程序之后执行下列步骤：首先：在文件（File）菜单里，选择新建项目（New Project）。接着，在新建立项目对话框里，双击ActiveX DLL 图标。VB自动地向项目里增加一个类，叫做Class1。然后，在属性容器里，双击名称（Name）属性，把它改成clsImageLoader，保持instancing 属性为缺省值MultiUse不动。最后，在项目（Project）菜单里，选择Project1 属性，打开项目属性对话框。选择通用（General）选项卡，把项目名称改为ImageLoader。其它字段可以不管，保持原样。单击确定（OK）完成对ImageLoader 这个工程的设置。

在类里，写入了5个Let属性，1个Get属性（只读）和两个方法。Let属性传递动态链接库需要的信息，Get属性提供动态链接库生成的图片文件的位置。两个方法用来打开到数据库的连接，以生成图片文件。表 A 总结了这些属性和方法的作用。当然，根据项目的需要，可以在类里加入更复杂的功能。

表A: 在ActiveX动态链接库里的属性和方法

属性/方法 作用

DbName 打开数据库连接所需的数据库名称。

TableName,
NameOfImageColumn, 打开记录集所需要的信息。
NameOfImageTypeColumn,
NameOfImageIdColumn

ImageFile (只读) 把图片文件的名称和位置返回给容器。

OpenConnection (方法) 打开数据库连接。

CreateTemplateImageFile (方法) 从数据库提取图片数据，并把它保存到目录里。


在类里还有其它的私有子程序，用来初始化类、终止类、打开记录集、建立图片文件，以及处理可能的错误。

注意微软活动数据对象ADO1.5(现在为2.0)被用来连接SQL数据库。也可以使用其它数据访问方法，比如远程数据对象RDO。在这个项目里，必须使用ADO。操作方法是，单击项目（Project）菜单，然后选择引用（References）菜单 项。在引用对话框里，选中微软ActiveX Data Objects 1.5 库，然后单击确定（OK）。

在列表 B里，列出了类ImageLoader 完整源代码。类里使用的变量定义都在代码内部给出，还有其它注释，帮助理解上下文。

列表 B:类 ImageLoader 的完整源代码

Private mAdoConn As New ADODB.Connection
Private mAdoRst As New ADODB.Recordset
Private mstrDbName As String
Private mstrTableName As String
Private mstrImageColumnName As String '图片字的名称。
Private mstrImageTypeColumnName As String '图片类型字段的名称。
Private mstrImageIdColumnName As String '图片ID字段的名称。
Private mstrFileName() As String '数组，里面包含文件名和路径。
Private mlngImageId() As Long '数组，里面包含图片ID
Private mlngNumberOfFiles As Long
Const BLOCKSIZE = 102400


Public Property Let DbName(ByVal strVal As String)
mstrDbName = strVal
End Property

Public Property Let TableName(ByVal strVal As String)
mstrTableName = strVal
End Property

Public Property Let NameOfImageColumn(ByVal strVal As String)
mstrImageColumnName = strVal
End Property

Public Property Let NameOfImageTypeColumn(ByVal strVal As String)
mstrImageTypeColumnName = strVal
End Property

Public Property Let NameOfImageIdColumn(ByVal strVal As String)
mstrImageIdColumnName = strVal
End Property

Public Property Get ImageFile(ByVal ImageId As Integer) As String
Dim intPos As Integer
Dim blnFindId As Boolean
Dim i As Integer

blnFindId = False
For i = 0 To mlngNumberOfFiles - 1
If mlngImageId(i) = ImageId Then
intPos = 5 + Len(ImageId) + 3
ImageFile = Right(mstrFileName(i), intPos) 'reformat the location of file.
blnFindId = True
End If
Next i

If blnFindId = False Then
Err.Clear
Err.Raise vbObjectError + 23, "Get ImageFile", "Can't find image file!"
End If

End Property


Public Sub OpenConnection()
'**********************************************************
'作用：打开数据库连接。
'**********************************************************

On Error GoTo Error_handler
If mstrDbName = "" Then GoTo Error_handler
If mAdoConn.State = adStateOpen Then mAdoConn.Close
mAdoConn.ConnectionString = "DRIVER={SQL Server};SERVER=(local);UID=sa;PWD=;WSID=JIA;DATABASE=" & mstrDbName
mAdoConn.ConnectionTimeout = 15
mAdoConn.Open
Exit Sub

Error_handler:
Call HandleError
End Sub

Public Sub CreateTempImageFile(ByVal ImageId As Integer)
Dim strImageType As String
Dim i As Integer
'**********************************************************
'作用：打开记录集，提取二进制数据，并把数据存入文件。注意文件名使用图片ID生成。
'输入：图片ID。
'**********************************************************
If mAdoConn.State = adStateClosed Then Exit Sub

Call OpenRecordset(ImageId)

If mAdoRst.State = adStateClosed Then Exit Sub

On Error GoTo Error_handler

For i = 0 To mlngNumberOfFiles - 1
'检测图片文件是否已经存在。
If mlngImageId(i) = ImageId Then Exit Sub
Next i

mlngNumberOfFiles = mlngNumberOfFiles + 1
ReDim Preserve mstrFileName(mlngNumberOfFiles) '改变数组大小。
ReDim Preserve mlngImageId(mlngNumberOfFiles) '改变数组大小。
mlngImageId(mlngNumberOfFiles - 1) = ImageId
strImageType = mAdoRst.Fields(mstrImageTypeColumnName) ' 取得图片类型。
mstrFileName(mlngNumberOfFiles - 1) = App.Path & "/images" & _
"/image" & LTrim(Str(ImageId)) & "." & strImageType '取得图片文件名称和位置。
Call ReadFromDB(mAdoRst.Fields(mstrImageColumnName), _
mstrFileName(mlngNumberOfFiles - 1), AdoRst.Fields(mstrImageColumnName).ActualSize)
Exit Sub

Error_handler:
Call HandleError

End Sub

Private Sub OpenRecordset(ByVal ImageId As Integer)
Dim SqlText As String
'**********************************************************
'作用：打开记录集。
'输入：图片ID。
'**********************************************************

On Error GoTo Error_handler
If mAdoRst.State = adStateOpen Then mAdoRst.Close
SqlText = "SELECT " & mstrImageColumnName & "," & _
mstrImageTypeColumnName & " FROM " & mstrTableName & _
" WHERE " & mstrImageIdColumnName & "=" & ImageId

Set mAdoRst.ActiveConnection = mAdoConn
mAdoRst.Open SqlText, , adOpenStatic, adLockReadOnly 'Open recordset.

Exit Sub


Error_handler:
Call HandleError
End Sub

Private Sub ReadFromDB(fld As ADODB.Field, ByVal DiskFile As String, _
FldSize As Long)
Dim NumBlocks As Integer
Dim LeftOver As Long
Dim byteData() As Byte '字节数组，用于长的可变二进制数据LongVarBinary。
Dim strData As String '字符串，用于长的可变二进制数据LongVarChar。
Dim DestFileNum As Integer
Dim pic As Variant
Dim i As Integer
'**********************************************************
'作用：提取二进制数据并把数据放入文件。
'输入：图片字段，文件名/位置和数据尺寸。
'**********************************************************

If Len(Dir(DiskFile)) > 0 Then '删除已经存在的目标文件。
Kill DiskFile
End If

DestFileNum = FreeFile
Open DiskFile For Binary As DestFileNum
NumBlocks = FldSize / BLOCKSIZE
LeftOver = FldSize Mod BLOCKSIZE

Select Case fld.Type
Case adLongVarBinary '用于图片数据类型。
byteData() = fld.GetChunk(LeftOver)
pic = fld.GetChunk(LeftOver)
Put DestFileNum, , byteData()

For i = 1 To NumBlocks
byteData() = fld.GetChunk(BLOCKSIZE)
Put DestFileNum, , byteData()
Next i

Case adLongVarChar '用于文本数据类型。
For i = 1 To NumBlocks
strData = String(BLOCKSIZE, 32)
strData = fld.GetChunk(BLOCKSIZE)
Put DestFileNum, , strData
Next i

strData = String(LeftOver, 32)
strData = fld.GetChunk(LeftOver)
Put DestFileNum, , strData
Case Else
Err.Clear
Err.Raise vbObjectError + 22, "Read from DB", "Not a Chunk Required column!"
End Select

Close DestFileNum

End Sub

Private Sub HandleError()
Dim adoErrs As ADODB.Errors
Dim errLoop As ADODB.Error
Dim strError As String
Dim i As Integer
'**********************************************************
'作用：处理可能的错误。
'**********************************************************

If mAdoConn.State = adStateClosed Then GoTo Done
i = 1
Set adoErrs = mAdoConn.Errors
For Each errLoop In adoErrs '枚举错误集。
With errLoop
strError = strError & vbCrLf & " ADO Error #" & .Number
strError = strError & vbCrLf & " Description " & .Description
strError = strError & vbCrLf & " Source " & .Source
i = i + 1
End With
Next

Done:
Err.Raise vbObjectError + 21, "", strError
End Sub

Private Sub Class_Initialize()
mlngNumberOfFiles = 0
End Sub

Private Sub Class_Terminate()
Dim i As Integer
On Error GoTo Error_handler
If mAdoRst.State = adStateOpen Then mAdoRst.Close '关闭记录集。
If mAdoConn.State = adStateOpen Then mAdoConn.Close '关闭连接。
Set mAdoRst = Nothing
Set mAdoConn = Nothing
Exit Sub

Error_handler:
Call HandleError
End Sub

Error_handler:
Call HandleError
End Sub


下一步是编译动态链接库。在文件（File）菜单里，单击建立（Make） ImageLoader.dll。VB会询问保存动态链接库的位置，然后就编译项目。在要ASP文件里使用ImageLoader.dll这个动态链接库，必须在Windows注册表里注册它。操作方法是，在NT的启动菜单里，选择运行（Run），然后在输入框里输入下面的命令行：

regsvr32 localpath/ImageLoader
注意，实际使用时要用动态链接库实际所在的完整路径替换上面命令行里的“localpath”。现在，就可以在程序里，比如ASP文件里使用这个动态链接库了。

建立Web项目和设置数据库连接

在注册了 ImageLoader 动态链接库之后，我们就可以建立Web项目了。我们使用微软Visual InterDev 1.0 建立ASP页面以及到微软SQL Server数据库的数据连接。

首先，打开微软Visual InterDev。在文件File 菜单里，选择新建（New）菜单项。在出现的对话框里，选中Web项目向导，在项目名称字段里输入ImageLoad 。单击确定（OK），完成后面两步，结束向导。

可以看到， Visual InterDev 在工作空间（Workspace）窗口里自动地生成了一个文件，叫做Global.asa。在用户第一次查看Web程序里的页面里，就会自动生成这个文件。要连接SQL Server里的数据库，选择项目 | 加入项目（Project | Add To Project），然后选择数据连接（Data Connection）。这里，选择数据源对话框出现，我们必须定义一个数据源名称（DSN）。

单击新建（New）按钮，在列出的可用数据驱动程序列表里，选择SQL Server，然后单击下一步（Next）。接着，在输入框里输入 Grocevb 作为DSN。接下来的几步很容易完成，不再详述。

下面，出现了SQL Server 登录对话框。输入服务器名称，登录ID和口令，并单击选项（Option）按钮。从列出的可用数据库列表里，选择Grocevb，单击确定（OK）。在结束了全部以上步骤之后，就返回到了选择数据源对话框。在这里，从DSN列表里单击文件名 Grocevb.dsn，然后完成后面几步结束这段操作。

现在，可以双击Global.asa，查看以上步骤在这个文件里生成的代码。代码定义了连接SQL Server数据库所必需的一些变量。

为了初始化类 clsImageLoader ，必须在Global.asp的开始放两行代码。我们在列表 C里列出了Global.asa里的代码。注意clsImageLoader 是一个会话范围内的对象。

列表 C: Global.asa

<OBJECT RUNAT=Server SCOPE=Session ID=objImageLoader PROGID="ImageLoader.clsImageLoader">
</OBJECT>
<SCRIPT LANGUAGE=VBScript RUNAT=Server>
Sub Session_OnStart
Session("Grocevb_ConnectionString") = "DRIVER=SQL Server; SERVER=(local);
UID=sa;PWD=;APP=Microsoft (R) Developer Studio;WSID=JIA;
DATABASE=Grocevb;UseProcForPrepare=0"
Session("Grocevb_ConnectionTimeout") = 15
Session("Grocevb_CommandTimeout") = 30
Session("Grocevb_RuntimeUserName") = "sa"
Session("Grocevb_RuntimePassword") = ""
End Sub

Sub Session_OnEnd
set objImageLoader = Nothing
End Sub

</SCRIPT>



建立ASP页面

为了连接到数据库，并和ImageLoader这个动态链接库通信，我们在Web项目里建立了一个ASP文件。方法是在文件（File）菜单里选择新建（New）菜单项，在文件（Files）标签卡中选择ASP页面图标，在输入框里输入文件名称。我们把这个页面命名为default.asp。在default.asp 里包含的代码如列表 D所示。

列表 D: default.asp

<% Set dbConn = Server.CreateObject("ADODB.Connection")
dbConn.ConnectionTimeout = Session("Grocevb_ConnectionTimeout")
dbConn.CommandTimeout = Session("Grocevb_CommandTimeout")
dbConn.Open Session("Grocevb_ConnectionString"), Session("Grocevb_RuntimeUserName"), _
Session("Grocevb_RuntimePassword")

Set cmdTemp = Server.CreateObject("ADODB.Command")
Set rstProduct = Server.CreateObject("ADODB.Recordset")
cmdTemp.CommandText = "SELECT prod_id, prod_name, prod_desc, prod_unitprice, & _
" prod_unitquant, prod_imagetype " & _
"FROM Products ORDER BY prod_name"
cmdTemp.CommandType = 1
Set cmdTemp.ActiveConnection = dbConn
rstProduct.Open cmdTemp, , 0, 1

objImageLoader.DbName = "Grocevb"
objImageLoader.TableName = "Products"
objImageLoader.NameOfImageColumn = "prod_image"
objImageLoader.NameOfImageTypeColumn = "prod_imagetype"
objImageLoader.NameOfImageIdColumn = "prod_id"
objImageLoader.OpenConnection
%>

<HTML>
<HEAD>
<TITLE>从SQL Server装载图片的示例</TITLE>
</HEAD>
<BODY bgcolor="#FFFFFF" TOPMARGIN=8 LEFTMARGIN=4>
<%Do While Not rstProduct.EOF %>
<%ProdId = rstProduct("prod_id") %>
<% objImageLoader.CreateTempImageFile(ProdId) %>
<% FileName = "images/" & objImageLoader.ImageFile(ProdId) %>

<TABLE border=1 cellpadding=0 cellspacing=0 width=100%>
<TABLE border=0 cellpadding=5 cellspacing=0 width=100% cols=2>
<td width=30%>
<IMG ALIGN=BOTTOM SRC= <% =FileName %>>
<p> </p>
<font size=2>Image type: <% = rstProduct("prod_imagetype") %>
</td>
<td width=70%>
<p align=center><font size=4><% =rstProduct("prod_name") %></font></p>
<p align=center><% =rstProduct("prod_desc") %></p>
</td>
</TABLE>
<p> </p>
<TABLE border=0 cellpadding=5, cellspacing=0 width=100% cols=2>
<td width=50%>
<p align=left>Unit quantity: <% = rstProduct("prod_unitquant") %></P>
</td>
<td width=50%>
<p align=left>Unit price: <% =rstProduct("prod_unitprice") %></p>
</td>
</TABLE>
</TABLE>
<p> </p>
<% rstProduct.MoveNext %>
<% Loop %>
</BODY>
</HTML>


注意：类ImageLoader 里定义的CreateTempImageFile 方法和ImageFile 属性（只读）需要图片ID作为参数。在这个例子里，图片ID就是表Products的主关键字(prod_id) 。所以， prod_id 的值必须传递给动态链接库。