汇编语言实现偏移量二进制倒序并与原偏移量下数据交换

原创 2005年06月02日 08:08:00
.MODEL SMALL
.STACK 200H
.DATA
ERRMSG DB 'The data are insufficient,unable to change$' ;当LEN设置过大而BUF1中的数据较少时提示错误
BUF1 DB '0123456789ABCDEFGHIJKLMNOPQRSTUV',0DH,0AH,'$'  ;欲交换的数据,最大65536个
DATALEN EQU $-BUF1-3                                        ;数据长度
LEN EQU 4                                                ;数据表示位数,最大为16
.CODE
SWAP MACRO PARAMETER1,PARAMETER2                        ;两个字节的交换
        MOV AL,PARAMETER1
        MOV AH,PARAMETER2
        MOV PARAMETER2,AL
        MOV PARAMETER1,AH
ENDM
REVERSE MACRO PARAMETER1,PARAMETER2                        ;实现二进制数据倒序
;如欲交换数据长度大于65536可将对应寄存器改用32位积存器,为避免程序混乱,参数1和参数2不能为本宏中的用到的寄存器
LOCAL   LOP,OVER                                        ;为避免重复调用该宏时程序发生混乱,应将标识本地化
        PUSH CX                                                ;保存CX,因为该宏可能在一个loop循环中被调用
        MOV AX,0                                        ;AX初值赋0
        MOV DX,PARAMETER1                                ;欲倒序的数据存入DX
        MOV CX,LEN-1                                        ;
        MOV BX,1                                        ;
        SHL BX,CL                                        ;使BX中低LEN位中的最高位为1
        MOV CX,LEN                                        ;欲循环次数送入CX
LOP:    SHR DX,1                                        ;欲交换数据最低位送入CF
        JNC OVER                                        ;如果CF不为1则不对AX进行操作
        OR AX,BX                                        ;如果CF为1则设置AX中对应(逆值后)位置为1
OVER:   SHR BX,1                                        ;BX右移,准备设置下一位
        LOOP LOP
        MOV PARAMETER2,AX                                ;结果存入参数2中
        POP CX                                                ;恢复CX的值
ENDM
PUTBUF  MACRO                                                ;输出BUF1中的值
        MOV AX,@DATA
        MOV DS,AX                                        ;数据段对齐
        LEA DX,BUF1                                        ;BUF1偏移地址送入DX
        MOV AH,9
        INT 21H                                                ;开始输出
ENDM                                                        ;宏结束
MAIN    PROC FAR                                        ;主程序开始
        MOV CL,LEN                                        ;
        MOV BX,1                                        ;
        SHL BX,CL                                        ;设置BX为2的LEN次方
        CMP BX,DATALEN                                        ;比较欲交换数据个数和实际数据个数的大小
        JA  ERROR                                        ;给出的实际数据不足,跳出
        PUTBUF                                                ;输出交换前缓冲区数据
        SHR BX,1                                        ;设置循环次数为欲交换的数据个数的一半
        MOV CX,BX                                        ;循环次数次数送入CX
        MOV DI,0                                        ;设置偏移量(欲二进制逆置的数据)的初始值
LOP:    REVERSE DI,SI                                        ;对DI逆置并送入SI(注意:实际参数不可使用REVERSE宏中用到的寄存器)
        CMP DI,SI                                        ;比较DI和SI的大小,防止逆置重复
        JLE NEXT                                        ;没有重复则跳过下面代码段
        PUSH CX                                                ;保存循环寄存器
        MOV CL,LEN                                        ;欲交换数据表示位数送入CL
        MOV DX,1                                        ;DX送入值1
        SHL DX,CL                                        ;
        DEC DX                                                ;置DX中低LEN位为1
        XOR DI,DX                                        ;对DI中低LEN位取反
        XOR SI,DX                                        ;对SI中低LEN位取反
        SWAP BUF1[DI],BUF1[SI]                                ;交换该偏移位置处的数据
        XOR DI,DX                                        ;还原DI中的数据
        XOR SI,DX                                        ;还原SI中的数据
        POP CX                                                ;恢复循环寄存器
        JMP NEXT2                                        ;跳到NEXT2准备下次循环
NEXT:   JE NEXT2                                        ;如果相等则不操作,跳到NEXT2准备下次循环
        SWAP BUF1[DI],BUF1[SI]                                ;交换该偏移位置处的数据
NEXT2:  INC DI                                                ;偏移位置加1
        LOOP LOP                                        ;如果CX不等于0进入下次循环
        PUTBUF                                                ;输出BUF1中的数据
EXIT:   MOV AH,1                                        ;
        INT 21H                                                ;暂停
        MOV AX,4C00H
        INT 21H                                                ;返回操作系统
ERROR:  MOV AX,@DATA
        MOV DS,AX                                        ;数据段地址送入DS
        MOV AH,9
        LEA DX,ERRMSG
        INT 21H                                                ;输出错误信息
        JMP EXIT                                        ;跳出,按任意键返回操作系统
MAIN    ENDP                                                ;主函数结束
        END  MAIN                                          ;主程序结束
       

理解逻辑地址(基地址:偏移量)的汇编程序

写一个程序判定从地址0040:0000H开始的2048个内存字节单元是否有字符A.如果有则把第一个含此指定字符的存储单元的地址偏移送到0000:03FEH单元中;如眉宇则把特征值0FFFFH送到上述指...
  • yunhaiC
  • yunhaiC
  • 2006年11月22日 14:55
  • 2519

Kafka 消息偏移量的维护

Kafka是大数据领域常用的消息队列,其高效的吞吐量和分布式容错等特性是其收到青睐的重要原因。kafka消息的位置用好Kafka,维护其消息偏移量对于避免消息的重复消费与遗漏消费,确保消息的Exact...
  • OiteBody
  • OiteBody
  • 2017年08月02日 17:11
  • 2566

偏移量详解

在网络分析领域,偏移 量是一个频繁出现的术语,如IP分段偏移 量、TCP偏移 量、位偏移 ,基于数据包偏移 、基于协议偏移 等等。那它们到底是什么含义,有什么区别呢?带着这些疑问,我查阅了...
  • cybertan
  • cybertan
  • 2010年10月23日 17:57
  • 2281

Android城市列表实现及listview偏移量恢复请教。

这些天需求改变,要求像某些app那样,左边是一个省份的列,右边是城市的列,接触Android 这半年来,大部分东西都能从百度上找到资料来完成,但是有些基础性的东西还是需要沉淀,因为之前java的底子还...
  • struggleflea
  • struggleflea
  • 2016年09月26日 13:58
  • 928

DES加密和解密

using System.Security.Cryptography; using System.IO; using System.Text; //加密: public static ...
  • sinat_15155817
  • sinat_15155817
  • 2016年09月06日 09:41
  • 734

Spark+Kafka的Direct方式将偏移量发送到Zookeeper的实现

Apache Spark 1.3.0引入了Direct API,利用Kafka的低层次API从Kafka集群中读取数据,并且在Spark Streaming系统里面维护偏移量相关的信息,并且通过这种方...
  • LW_GHY
  • LW_GHY
  • 2016年03月18日 21:41
  • 1400

MySQL分页查询偏移量问题

如果偏移量大于1000,返回速度较慢, 如select * from t_pass where hm like 'B%' order by sj asc limit 1210,10; 如何...
  • mlz_2
  • mlz_2
  • 2017年07月28日 16:40
  • 378

偏移量

偏移量汇编语言中的定义为: 把存储单元的实际地址与其所在段的段地址之间的距离称为段内偏移,也称为“有效地址或偏移量”。 亦: 存储单元的实际地址与其所在段的段地址之间的距离。本质其实就是“实际地址与...
  • qq_17242957
  • qq_17242957
  • 2016年03月02日 23:28
  • 327

移动鼠标计算鼠标偏移量

移动鼠标计算鼠标偏移量
  • gegsdvgdsg
  • gegsdvgdsg
  • 2017年09月27日 15:27
  • 142

js获取元素的偏移量offset

null和undefined都代表没有,但是null是属性存在值不存在,undefined是连这个属性都不存在 //例如 document.parentNode//浏览器天生自带的一个属性:...
  • liang5603
  • liang5603
  • 2017年08月04日 17:46
  • 353
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:汇编语言实现偏移量二进制倒序并与原偏移量下数据交换
举报原因:
原因补充:

(最多只允许输入30个字)