修改tomcat catalina.bat调整jvm内存及tomcat窗口标题

开发这么久了，总会时不时碰到内存溢出的错误，知道应该去 catalina 中去设置一下jvm的内存大小。可是每次都忘记具体在哪个位置。而且，很多时候，出现内存溢出的环境都不是本机，而是服务器搭建环境的时候，而此时也没太多时间让自己去读一下 catalina.bat 这个脚本，只能每次都上网搜。今天正好有时间，就读了一下catalina.bat 这个脚本，记录一下。
以windows下的tomcat6.0.45 为例
脚本其实并不复杂。tomcat的启动一般是通过 startup.bat 这个脚本，一般是直接双击启动。
而catalina.bat 是在startup.bat 调用启动的。

startup.bat 脚本：

rem 判断当前系统版本，若是Windows_NT   则 setlocal 开启环境变量本地化
if "%OS%" == "Windows_NT" setlocal
rem ---------------------------------------------------------------------------
rem Start script for the CATALINA Server
rem ---------------------------------------------------------------------------

rem Guess CATALINA_HOME if not defined

rem 设置当前CURRENT_DIR变量值为当前目录%cd%
set "CURRENT_DIR=%cd%"
rem 若CATALINA_HOME 不为空，则跳转到gotHome，我一般不设置CATALINA_HOME，则不跳转，继续执行
if not "%CATALINA_HOME%" == "" goto gotHome
rem  设置CATALINA_HOME 为 上面定义的 CURRENT_DIR
set "CATALINA_HOME=%CURRENT_DIR%"
rem catalina.bat如果存在，则跳转到okHome
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
cd ..
set "CATALINA_HOME=%cd%"
cd "%CURRENT_DIR%"
:gotHome
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
echo The CATALINA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
goto end
:okHome

set "EXECUTABLE=%CATALINA_HOME%\bin\catalina.bat"

rem 再次跳转到okExec

rem Check that target executable exists
if exist "%EXECUTABLE%" goto okExec
echo Cannot find "%EXECUTABLE%"
echo This file is needed to run this program
goto end
:okExec

rem 判断 第一个输入参数：%1 是否为空，若为空，则到 doneSetArgs
rem Get remaining unshifted command line arguments and save them in the
set CMD_LINE_ARGS=
:setArgs
if ""%1""=="""" goto doneSetArgs
set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
shift
goto setArgs
:doneSetArgs

rem 执行 EXECUTABLE 即 catalina.bat 并传递一个参数 start ： catalina.bat start
call "%EXECUTABLE%" start %CMD_LINE_ARGS%

:end

当前窗口关闭，并开启catalina.bat的窗口。

set "CURRENT_DIR=%cd%"
if not "%CATALINA_HOME%" == "" goto gotHome
set "CATALINA_HOME=%CURRENT_DIR%"
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
cd ..
set "CATALINA_HOME=%cd%"
cd "%CURRENT_DIR%"
:gotHome
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
echo The CATALINA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
goto end
:okHome

rem Copy CATALINA_BASE from CATALINA_HOME if not defined
if not "%CATALINA_BASE%" == "" goto gotBase
set "CATALINA_BASE=%CATALINA_HOME%"
:gotBase

rem Ensure that any user defined CLASSPATH variables are not used on startup,
rem but allow them to be specified in setenv.bat, in rare case when it is needed.
set CLASSPATH=


rem 上述的代码主要是设置CATALINA_HOME和CATALINA_BASE 方法基本和startup.bat一样，tomcat5的时候需要配置CATALINA_HOME 而在6之后就不需要配置了，因为通过上述代码可以看到，启动的时候会先去检查，是否设置过该变量，若没有则设置为当前目录。

rem Get standard environment variables
if not exist "%CATALINA_BASE%\bin\setenv.bat" goto checkSetenvHome
call "%CATALINA_BASE%\bin\setenv.bat"
goto setenvDone
:checkSetenvHome
if exist "%CATALINA_HOME%\bin\setenv.bat" call "%CATALINA_HOME%\bin\setenv.bat"
:setenvDone

rem Get standard Java environment variables
if exist "%CATALINA_HOME%\bin\setclasspath.bat" goto okSetclasspath
echo Cannot find "%CATALINA_HOME%\bin\setclasspath.bat"
echo This file is needed to run this program
goto end
:okSetclasspath
set "BASEDIR=%CATALINA_HOME%"
call "%CATALINA_HOME%\bin\setclasspath.bat" %1
if errorlevel 1 goto end


rem  上面这一段作用是，判断是否存在setenv.bat或者setclasspath.bat 若存在就执行该脚本


if not "%CATALINA_TMPDIR%" == "" goto gotTmpdir
set "CATALINA_TMPDIR=%CATALINA_BASE%\temp"
:gotTmpdir

rem Add tomcat-juli.jar and bootstrap.jar to classpath
rem tomcat-juli.jar can be over-ridden per instance
rem Note that there are no quotes as we do not want to introduce random
rem quotes into the CLASSPATH
if "%CLASSPATH%" == "" goto emptyClasspath
set "CLASSPATH=%CLASSPATH%;"
:emptyClasspath
if "%CATALINA_BASE%" == "%CATALINA_HOME%" goto juliClasspathHome
if not exist "%CATALINA_BASE%\bin\tomcat-juli.jar" goto juliClasspathHome
set "CLASSPATH=%CLASSPATH%%CATALINA_BASE%\bin\tomcat-juli.jar;%CATALINA_HOME%\bin\bootstrap.jar"
goto juliClasspathDone
:juliClasspathHome
set "CLASSPATH=%CLASSPATH%%CATALINA_HOME%\bin\bootstrap.jar"
:juliClasspathDone

if not "%LOGGING_CONFIG%" == "" goto noJuliConfig
set LOGGING_CONFIG=-Dnop
if not exist "%CATALINA_BASE%\conf\logging.properties" goto noJuliConfig
set LOGGING_CONFIG=-Djava.util.logging.config.file="%CATALINA_BASE%\conf\logging.properties"
:noJuliConfig
set JAVA_OPTS=%JAVA_OPTS% %LOGGING_CONFIG%

rem  执行到此处后，判断LOGGING_MANAGER是否存在，不存在跳转到noJuliManager
if not "%LOGGING_MANAGER%" == "" goto noJuliManager
set LOGGING_MANAGER=-Djava.util.logging.manager=org.apache.juli.ClassLoaderLogManager
:noJuliManager
rem  此处设置java_opt环境变量。windows下是没有引号包裹的，否则设置了也会不生效！！！
set JAVA_OPTS=%JAVA_OPTS% %LOGGING_MANAGER% 

rem 覆写JAVA_OPTS的赋值，替换成我们需要的jvm参数即可。在生产环境推荐 增加 -server 参数。 sun的jdk推荐将启动内存和最大内存设置为同一个值，这样在空间不足时，缩短请求空间的时间。但是ibm的jdk千万不要这样，否则容易宕机。

set JAVA_OPTS=-server  -Xmx2500m -Xms2500m -Xmn1g -Xss512k -XX:+UseParallelGC -XX:ParallelGCThreads=20 -XX:+UseParallelGC 

rem 设置 启动和最大值均为2500m，新生代区域为1g，每条线程的空间为512k ，调整GC策略。

rem ----- Execute The Requested Command ---------------------------------------

echo Using CATALINA_BASE:   "%CATALINA_BASE%"
echo Using CATALINA_HOME:   "%CATALINA_HOME%"
echo Using CATALINA_TMPDIR: "%CATALINA_TMPDIR%"
if ""%1"" == ""debug"" goto use_jdk
echo Using JRE_HOME:        "%JRE_HOME%"
goto java_dir_displayed
:use_jdk
echo Using JAVA_HOME:       "%JAVA_HOME%"
:java_dir_displayed
echo Using CLASSPATH:       "%CLASSPATH%"

set _EXECJAVA=%_RUNJAVA%
set MAINCLASS=org.apache.catalina.startup.Bootstrap
set ACTION=start
set SECURITY_POLICY_FILE=
set DEBUG_OPTS=
set JPDA=

if not ""%1"" == ""jpda"" goto noJpda
set JPDA=jpda
if not "%JPDA_TRANSPORT%" == "" goto gotJpdaTransport
set JPDA_TRANSPORT=dt_socket
:gotJpdaTransport
if not "%JPDA_ADDRESS%" == "" goto gotJpdaAddress
set JPDA_ADDRESS=8000
:gotJpdaAddress
if not "%JPDA_SUSPEND%" == "" goto gotJpdaSuspend
set JPDA_SUSPEND=n
:gotJpdaSuspend
if not "%JPDA_OPTS%" == "" goto gotJpdaOpts
set JPDA_OPTS=-agentlib:jdwp=transport=%JPDA_TRANSPORT%,address=%JPDA_ADDRESS%,server=y,suspend=%JPDA_SUSPEND%
:gotJpdaOpts
shift
:noJpda


rem 根据当前参数决定如何启动，默认是 start 即从startup.bat启动时。跳转到doStart

if ""%1"" == ""debug"" goto doDebug
if ""%1"" == ""run"" goto doRun
if ""%1"" == ""start"" goto doStart
if ""%1"" == ""stop"" goto doStop
if ""%1"" == ""version"" goto doVersion



 ........ 

rem  判断 TITLE 是否为空，若为空则默认设置为Tomcat，这里我们可以修改为自己需要的值。
:doStart
shift
if not "%OS%" == "Windows_NT" goto noTitle
if "%TITLE%" == "" set TITLE=Tomcat
set _EXECJAVA=start "%TITLE%" %_RUNJAVA%
goto gotTitle
:noTitle
set _EXECJAVA=start %_RUNJAVA%
:gotTitle
if not ""%1"" == ""-security"" goto execCmd
shift
echo Using Security Manager
set "SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy"
goto execCmd



:execCmd
rem Get remaining unshifted command line arguments and save them in the
set CMD_LINE_ARGS=
:setArgs
if ""%1""=="""" goto doneSetArgs
set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
shift
goto setArgs
:doneSetArgs

:end

通过上面两个地方的设置，则完成jvm内存的调整和标题的调整。
太多东西不写下来，过段时间就会忘记。