将数据分页的存储过程

过程1：
 

CREATE PROCEDURE sp_page
  @tb         varchar(50), --表名
  @col        varchar(50), --按该列来进行分页
  @coltype    int,         --@col列的类型,0-数字类型,1-字符类型,2-日期时间类型
  @orderby    bit,         --排序,0-顺序,1-倒序
  @collist    varchar(800),--要查询出的字段列表,*表示全部字段
  @pagesize   int,         --每页记录数
  @page       int,         --指定页
  @condition  varchar(800),--查询条件
  @pages      int OUTPUT   --总页数
AS
/*
功能描述：对指定表中满足条件的记录按指定列进行分页查询，分页可以顺序、倒序
         查询可以指定页大小、指定查询任意页、指定输出字段列表，返回总页数
作    者：pbsql
版    本：1.10
最后修改：2004-11-29
*/
DECLARE @sql nvarchar(4000),@where1 varchar(800),@where2 varchar(800)
IF @condition is null or rtrim(@condition)=''
BEGIN--没有查询条件
  SET @where1=' WHERE '
  SET @where2='  '
END
ELSE
BEGIN--有查询条件
  SET @where1=' WHERE ('+@condition+') AND '--本来有条件再加上此条件
  SET @where2=' WHERE ('+@condition+') '--原本没有条件而加上此条件
END
SET @sql='SELECT @pages=CEILING((COUNT(*)+0.0)/'+CAST(@pagesize AS varchar)+
         ') FROM '+@tb+@where2
EXEC sp_executesql @sql,N'@pages int OUTPUT',@pages OUTPUT--计算总页数
IF @orderby=0
  SET @sql='SELECT TOP '+CAST(@pagesize AS varchar)+' '+@collist+
           ' FROM '+@tb+@where1+@col+'>(SELECT MAX('+@col+') '+
           ' FROM (SELECT TOP '+CAST(@pagesize*(@page-1) AS varchar)+' '+
           @col+' FROM '+@tb+@where2+'ORDER BY '+@col+') t) ORDER BY '+@col
ELSE
  SET @sql='SELECT TOP '+CAST(@pagesize AS varchar)+' '+@collist+
           ' FROM '+@tb+@where1+@col+'<(SELECT MIN('+@col+') '+
           ' FROM (SELECT TOP '+CAST(@pagesize*(@page-1) AS varchar)+' '+
           @col+' FROM '+@tb+@where2+'ORDER BY '+@col+' DESC) t) ORDER BY '+
           @col+' DESC'
IF @page=1--第一页
  SET @sql='SELECT TOP '+CAST(@pagesize AS varchar)+' '+@collist+' FROM '+@tb+
    @where2+'ORDER BY '+@col+CASE @orderby WHEN 0 THEN '' ELSE ' DESC' END
EXEC(@sql)
GO

本存储过程高效，曾用500万条数据测试（已建索引），只返回分页只需3秒，影响效率的地方是计算总页数，若不需要可以注释掉

--测试示例
declare @pages int
select identity(int,1,1) id,getdate() dt,xx=cast('' as varchar(10)) into #t
 from sysobjects
update #t set dt=dateadd(day,id-200,dt),
              xx='xxxx'+right('000000'+cast(id as varchar(10)),6)

exec sp_page '#t','id',0,0,'*',10,2,'',@pages output--按id顺序取第二页
exec sp_page '#t','id',0,1,'*',10,2,'',@pages output--按id倒序取第二页
exec sp_page '#t','xx',1,0,'*',10,3,'',@pages output--按xx顺序取第三页
exec sp_page '#t','xx',1,1,'*',10,3,'',@pages output--按xx倒序取第三页
exec sp_page '#t','dt',2,0,'*',10,2,'',@pages output--按dt顺序取第二页
exec sp_page '#t','dt',2,1,'*',10,2,'',@pages output--按dt倒序取第二页

select 总页数=@pages

drop table #t

过程2：
CREATE PROCEDURE [dbo].[GetPageData]
@FieldsName nvarchar(4000),--字段名
@TableName nvarchar(500),--表名
@Condition nvarchar(4000),
@Sort nvarchar(4000),--排序
@PageSize int=10,
@PageNum int=1 out,
@RowCount int=0 out,
@PageCount int=0 out,
@Debug nvarchar(4000) out
AS
if @Condition!=''
   set @Condition=' where '+@Condition

if @Sort!=''
   set @Sort=' order by '+@Sort
else
begin
   set @Debug='排序有错 fields [asc|desc]'
   return
end

declare @SqlStr nvarchar(4000) -- 主语句
declare @unSort nvarchar (4000)
declare @Count int
declare @LastCount int
set @unSort=REPLACE(@Sort,'asc','xs')
set @unSort=REPLACE(@unSort,'desc','asc')
set @unSort=REPLACE(@unSort,'xs','desc')

set @SqlStr='select @Count=Count(*) from '+@TableName+' '+@Condition
exec sp_executesql @SqlStr,N'@Count int out ',@Count out 

set @RowCount=@Count
set @PageCount=@Count/@PageSize
set @LastCount=@Count%@PageSize

if @LastCount>0 
begin
   set @PageCount=@PageCount+1
end

if(@PageNum<=0)
begin
   set @PageNum=1
end

if((@PageNum*@PageSize)>=@RowCount)
begin
   set @PageNum=@PageCount
end

if ((@PageNum*@PageSize)>=@RowCount) and (@LastCount>0)
begin
   set @SqlStr='select * from (select top '+cast(@LastCount as varchar) +' '+@FieldsName+' from (select top '+cast(@PageNum*@PageSize as varchar)  +' '+@FieldsName+' from '+@TableName+' '+@Condition+' '+@Sort+') as tmp '+@unSort+' ) as tmp '+@Sort
end
else
begin
   set @SqlStr='select * from (select top '+cast(@PageSize as varchar) +' '+@FieldsName+' from (select top '+cast(@PageNum*@PageSize as varchar)  +' '+@FieldsName+' from '+@TableName+' '+@Condition+' '+@Sort+') as tmp '+@unSort+' ) as tmp '+@Sort
end
set @Debug=@SqlStr
exec (@SqlStr)
GO