关闭

图论-桥/割点/双连通分量/缩点/LCA

430人阅读 评论(0) 收藏 举报
分类:

基本概念

1.割点:若删掉某点后,原连通图分裂为多个子图,则称该点为割点

2.割点集合:在一个无向连通图中,如果有一个顶点集合,删除这个顶点集合,以及这个集合中所有顶点相关联的边以后,原图变成多个连通块,就称这个点集为割点集合

3.点连通度:最小割点集合中的顶点数。

4.割边():删掉它之后,图必然会分裂为两个或两个以上的子图。

5.割边集合:如果有一个边集合,删除这个边集合以后,原图变成多个连通块,就称这个点集为割边集合

6.边连通度:一个图的边连通度的定义为,最小割边集合中的边数。

7.缩点:把没有割边的连通子图缩为一个点,此时满足任意两点之间都有两条路径可达。

注:求块<>求缩点。缩点后变成一棵k个点k-1条割边连接成的树。而割点可以存在于多个块中。

8.双连通分量:分为点双连通和边双连通。它的标准定义为:点连通度大于1的图称为点双连通图,边连通度大于1的图称为边双连通图。通俗地讲,满足任意两点之间,能通过两条或两条以上没有任何重复边的路到达的图称为双连通图。无向图G的极大双连通子图称为双连通分量

Tarjan算法的应用论述:

1.求强连通分量、割点、桥、缩点:

对于Tarjan算法中,我们得到了dfnlow两个数组,

low[u]:=min(low[u],dfn[v])——(u,v)为后向边,v不是u的子树;

low[u]:=min(low[u],low[v])——(u,v)为树枝边,vu的子树;

下边对其进行讨论:

low[v]>=dfn[u],u为割点u和它的子孙形成一个块。因为这说明u的子孙不能够通过其他边到达u的祖先,这样去掉u之后,图必然分裂为两个子图。

low[v]>dfn[u],(u,v)为割边。理由类似于上一种情况。

Tarjan求有向图强连通分量、割点、割边的代码

Var
 n,m,i,j,x,y,z:longint;
 a,b:array[0..1000,0..1000]of longint;//
 dfn,low,s:array[0..1000]of longint;//dfn为时间戳,low为祖先,s为栈
 vis,ins:array[0..1000]of boolean;//vis为是否访问,ins为是否在栈中
 num,p:longint;

function min(x,y:longint):longint;
 begin
  if x<y then exit(x) else exit(y);
 end;

procedure tarjan(u:longint);
 var
  i,v:longint;
 begin
  inc(num);//给定一个时间戳
  dfn[u]:=num;
  low[u]:=num;
  vis[u]:=true;
  inc(p);//入栈
  s[p]:=u;
  ins[u]:=true;
  for i:=1 to b[u,0] do//注意只有ui相连才进行下面的操作
   if not vis[b[u,i]] then//未被访问
    begin
     tarjan(b[u,i]);
     low[u]:=min(low[u],low[b[u,i]]);//是树枝边,取两个lowmin
  {如果是求割点或者割边,在这里判断dfn[u]low[v]的大小并进行弹栈即可。}
    end
   else if ins[b[u,i]] then//在栈中
    low[u]:=min(low[u],dfn[b[u,i]]);//非树枝边,取lowdfnmin
  if dfn[u]=low[u] then//已经找到一个强连通分量,弹栈。
   repeat
    v:=s[p];
    write(v,' ');
    ins[v]:=false;
    dec(p);
    if u=v then writeln;
   until u=v;
 end;

begin
 readln(n,m);
 for i:=1 to m do//构图
  begin
   readln(x,y);
   inc(b[x,0]);
   b[x,b[x,0]]:=y;
  end;
 tarjan(1);
End.

 2.求双连通分量以及构造双连通分量:

对于点双连通分支,实际上在求割点的过程中就能顺便把每个点双连通分支求出。建立一个栈,存储当前双连通分支,在搜索图时,每找到一条树枝边或后向边(非横叉边),就把这条边加入栈中。如果遇到某时满足DFS(u)<=Low(v),说明u是一个割点,同时把边从栈顶一个个取出,直到遇到了边(u,v),取出的这些边与其关联的点,组成一个点双连通分支。割点可以属于多个点双连通分支,其余点和每条边只属于且属于一个点双连通分支。

对于边双连通分支,求法更为简单。只需在求出所有的桥以后,把桥边删除,原图变成了多个连通块,则每个连通块就是一个边双连通分支。桥不属于任何一个边双连通分支,其余的边和每个顶点都属于且只属于一个边双连通分支。

一个有桥的连通图,如何把它通过加边变成边双连通图?方法为首先求出所有的桥,然后删除这些桥边,剩下的每个连通块都是一个双连通子图。把每个双连通子图收缩为一个顶点,再把桥边加回来,最后的这个图一定是一棵树,边连通度为1。

统计出树中度为1的节点的个数,即为叶节点的个数,记为leaf。则至少在树上添加(leaf+1)/2条边,就能使树达到边二连通,所以至少添加的边数就是(leaf+1)/2。具体方法为,首先把两个最近公共祖先最远的两个叶节点之间连接一条边,这样可以把这两个点到祖先的路径上所有点收缩到一起,因为一个形成的环一定是双连通的。然后再找两个最近公共祖先最远的两个叶节点,这样一对一对找完,恰好是(leaf+1)/2次,把所有点收缩到了一起。

3.求最近公共祖先(LCA)

在遍历到u时,先tarjan遍历完u的子树,则u和u的子树中的节点的最近公共祖先就是u,并且u和【u的兄弟节点及其子树】的最近公共祖先就是u的父亲。注意到由于我们是按照DFS顺序遍历的,我们可用一个color数组标记,正在访问的染色为1,未访问的标记为0,已经访问到即在【u的子树中的】及【u的已访问的兄弟节点及其子树中的】染色标记为2,这样我们可以通过并查集的不断合并更新,通过find实现以上目标。

 

 function find(x:longint):longint;
  begin
    if f[x]<>x then f[x]:=find(f[x]);
    find:=f[x];
  end;
procedure tarjan(u:longint);
  begin
     f[u]:=u; color[u]:=1;
     for i:=1 to n do
     if (g[u,i])and(color[i]=0) then//g[u,i]表示u连着i
        begin
          tarjan(i); f[i]:=u;
        end;
     for i:=1 to n do
     if ((ask[u,i])or(ask[i,u]))and(color[i]=2) then//ask[u,i]表示询问了u,i
       begin
         lca[u,i]:=find(i); lca[i,u]:=lca[u,i];
       end;
     color[u]:=2;
  end;

注:用链表存储边和问题,可以使得该算法的时间复杂度降低为O(n+m+q),其中n、m、q分别为点、边、问题数目。本文中为了书写简便,采用的是矩阵的存储方式。
 

参考例题Poj 1523294236943352、3177  Tyvj P1111 

0
0

查看评论
* 以上用户言论只代表其个人观点,不代表CSDN网站的观点或立场
    个人资料
    • 访问:95133次
    • 积分:2750
    • 等级:
    • 排名:第13058名
    • 原创:189篇
    • 转载:1篇
    • 译文:0篇
    • 评论:5条
    最新评论