oracle对大对象类型操作:blob,clob,nclob

转载 2014年01月14日 16:50:02

1.基本介绍

Oracle和plsql都支持lob(large object) 类型,用来存储大数量数据,如图像文件,声音文件等。Oracle 9i realse2支持存储最大为4g的数据,oracle 10g realse1支持最大8到128万亿字节的数据存储,依赖于你的db的block size。

在plsql中可以申明的lob类型的变量如下: 

  • BFILE        二进制文件,存储在数据库外的操作系统文件,只读的。把此文件当二进制处理。 
  • BLOB        二进制大对象。存储在数据库里的大对象,一般是图像声音等文件。 
  • CLOB        字符型大对象。一般存储大数量文本信息。存储单字节,固定宽度的数据。 
  • NCLOB        字节字符大对象。存储单字节大块,多字节固定宽度,多字节变宽度数据。

Oracle将lob分类为两种:

  1. 存储在数据库里的,参与数据库的事务。BLOB,CLOB,NCCLOB。
  2. 存储在数据库外的BFILE,不参与数据库的事务,也就是不能rollback或commit等,它依赖于文件系统的数据完整性。
LONG和LONG RAW这两种数据类型也是存储字符的,但是有系列的问题,不建议使用,这里也就不讨论了。 

2.LOB的使用 

本部分不讨论lob的所有细节,只讨论lob的基本原理和在plsql中的基本使用,为plsql开发使用lob提供一个基础性指导。 
本部分使用的表是: 
/** 
table script 
**/ 
CREATE TABLE waterfalls ( 
       falls_name VARCHAR2(80),--name 
       falls_photo BLOB,--照片 
       falls_directions CLOB,--文字 
       falls_description NCLOB,--文字 
       falls_web_page BFILE);--指向外部的html页面 
/
这个表我们并不需要clob和nclob两个,只取一就可以,这里全部定义只是为了演示使用。

1. 理解LOB的Locator

表中的Lob类型的列中存储的只是存储指向数据库中实际存储lob数据的一个指针。 
在plsql中申明了一个lob类型的变量,然后从数据库中查询一个lob类型的值分配给变量,也只是将指针复制给了它,那么这个变量也会指向数据库中实际存放lob数据的地方。如:
--understanding lob locators 
  DECLARE 
       photo BLOB; 
    BEGIN 
       SELECT falls_photo 
         INTO photo 
         FROM waterfalls 
        WHERE falls_name='Dryer Hose'; 
Lob工作原理图解 
       从上面的图可以看出,要处理lob数据,必须先获得lob locators。我们可以通过一个select语句获取,当赋值给lob变量的时候,它也获得同样的lob locators。我们在plsql中处理可以使用dbms_lob包,里面内置了很多过程和函数来读取和修改我们的lob数据。下面给出处理lob数据的一般方法。 
1.        通过select语句获取一个lob locator。 
2.        通过调用dbms_lob.open打开lob。 
3.        调用dbms_lob.getchunksize获得最佳读写lob值。 
4.        调用dbms_lob.getlength获取lob数据的字节值。 
5.        调用dbms_lob.read获取lob数据。 
6.        调用dbms_lob.close关闭lob。 

2.Empty lob and Null lob

Empty的意思是我们已经获取了一个lob locator,但是没有指向任何lob数据。Null是定义了一个变量,但是没有获得lob locator。对lob类型的处理和其他类型不一样。如下面的例子:
/* null lob example*/
DECLARE
  directions CLOB; --定义了,但是没有分配值,为null 
BEGIN
  IF directions IS NULL THEN
    dbms_output.put_line('directions is null');
  ELSE
    dbms_output.put_line('directions is not null');
  END IF;
END;
/
DECLARE
  directions CLOB; --定义一个,并且分配值 
BEGIN
  --删除一行 
  DELETE FROM waterfalls WHERE falls_name = 'Munising Falls';
  --插入一行通过使用 EMPTY_CLOB(  ) to 建立一个lob locator 
  INSERT INTO waterfalls
    (falls_name, falls_directions)
  VALUES
    ('Munising Falls', empty_clob());
  --获得lob locator,上面插入的数据,因为我们插入的是一个empty_clob(),那么lob locator不指向任何数据,虽然给变量分配了只 
  SELECT falls_directions
    INTO directions
    FROM waterfalls
   WHERE falls_name = 'Munising Falls';
  IF directions IS NULL THEN
    dbms_output.put_line('directions is NULL');
  ELSE
    dbms_output.put_line('directions is not NULL'); --打印此句 
  END IF;
  dbms_output.put_line('Length = ' || dbms_lob.getlength(directions)); --结果为o 
END;
注意: 
  1. 上面例子中的empty_clob()是oracle的内置函数,创建了一个lob locator。但是我们没有让它指向任何数据,所以是empty。而且通过select语句给变量directions分配了lob locator,所以不是null,但是length为0,故为empty。 
  2. 在基本类型中,我们判断一个变量是不是有数据,只要is null就可以了。但是在lob类型中我们从以上的例子看出来是不正确的。Lob首先必须判断is null看是否分配lob locator,如果分配了还需要进一步检查length是否为0,看是否是empty,所以完整的是下面这样:
IF some_clob IS NULL THEN
    --如果is null为true表示未分配,肯定没有数据 
  ELSIF dbms_lob.getlength(some_clob) = 0 THEN
    --分配了length为0,也没有数据 
  ELSE
    --有数据 
  END IF;

3.建立LOB

在上面我们使用empty_clob()建立了一个空的clob,lob locator只是一个指针,真正的数据是存储在磁盘中或数据库文件中。我 们先建立一个空的clob,然后我们可以update来让变量真正指向有数据的lob。Empty_clob()可以用来处理clob和nclob。在oracle 8i中可以使用temporary lob达到同样的效果。

4. 向LOB里写入数据

当获得一个有效的lob locator之后,就可以使用dbms_lob包的下列procedure向lob中写入数据。 
       DBMS_LOB.WRITE:允许自动写入数据到lob中。 
       DBMS_LOB.WRITEAPPEND:向lob的末尾写入数据。
--write lob 
DECLARE
  directions      CLOB;
  amount          BINARY_INTEGER;
  offset          INTEGER;
  first_direction VARCHAR2(100);
  more_directions VARCHAR2(500);
BEGIN
  --Delete any existing rows for 'Munising Falls' so that this 
  --example can be executed multiple times 
  DELETE FROM waterfalls WHERE falls_name = 'Munising Falls';
  --Insert a new row using EMPTY_CLOB(  ) to create a LOB locator 
  INSERT INTO waterfalls
    (falls_name, falls_directions)
  VALUES
    ('Munising Falls', empty_clob());
  --Retrieve the LOB locator created by the previous INSERT statement 
  SELECT falls_directions
    INTO directions
    FROM waterfalls
   WHERE falls_name = 'Munising Falls';
  --Open the LOB; not strictly necessary, but best to open/close LOBs. 
  dbms_lob.open(directions, dbms_lob.lob_readwrite);
  --Use DBMS_LOB.WRITE to begin 
  first_direction := 'Follow I-75 across the Mackinac Bridge.';
  amount          := length(first_direction); --number of characters to write 
  offset          := 1; --begin writing to the first character of the CLOB 
  dbms_lob.write(directions, amount, offset, first_direction);
  --Add some more directions using DBMS_LOB.WRITEAPPEND 
  more_directions := ' Take US-2 west from St. Ignace to Blaney Park.' ||
                     ' Turn north on M-77 and drive to Seney.' ||
                     ' From Seney, take M-28 west to Munising.';
  dbms_lob.writeappend(directions,
                       length(more_directions),
                       more_directions);
  --Add yet more directions 
  more_directions := ' In front of the paper mill, turn right on H-58.' ||
                     ' Follow H-58 to Washington Street. Veer left onto' ||
                     ' Washington Street. You''ll find the Munising' ||
                     ' Falls visitor center across from the hospital at' ||
                     ' the point where Washington Street becomes' ||
                     ' Sand Point Road.';
  dbms_lob.writeappend(directions,
                       length(more_directions),
                       more_directions);
  --Close the LOB, and we are done. 
  dbms_lob.close(directions);
END;
在这个例子里,我们使用了write 和writeappend这两个过程来插入数据到lob中。因为开始的时候,我们插入了一个空的lob locator。要注意一点,我们最后使用了dbms_lob.close方法关闭lob。这是一个好的方法,特别是在处理oracle text的时候,任何oracle text domain和function-based indexes被update是在wirte和writeappend的时候调用的,而不是在close的时候被update的。        
我们向lob中写入数据的时候,没有必要更新表中的列。因为它保存的只是一个locator,我们的变量也获得同样的locator,当我们写入数据去lob的时候,locator并没有改变。改变的只是locator指向的物理数据。 

5. 从lob中读取数据

步骤:a.通过select查询获得lob locator初始化lob变量。2.调用dbms_lob.read过程读取lob数据。 
下面是dbms_lob.read过程的定义,注意参数.  
 
PROCEDURE READ(lob_loc IN BLOB, --初始化后的lob变量lob locator 
               amount  IN OUT NOCOPY INTEGER, --读取的数量(clob为字符数,blob,bfile是字节数) 
               offset  IN INTEGER, --开始读取位置 
               buffer  OUT RAW); --读到的数据,raw要显示用转换函数,见bfile 
PROCEDURE READ(lob_loc IN CLOB CHARACTER SET any_cs,
               amount  IN OUT NOCOPY INTEGER,
               offset  IN INTEGER,
               buffer  OUT VARCHAR2 CHARACTER SET lob_loc%charset);
PROCEDURE READ(file_loc IN BFILE,
               amount   IN OUT NOCOPY INTEGER,
               offset   IN INTEGER,
               buffer   OUT RAW);

--从lob中读取数据 
DECLARE
  directions   CLOB;
  directions_1 VARCHAR2(300);
  directions_2 VARCHAR2(300);
  chars_read_1 BINARY_INTEGER;
  chars_read_2 BINARY_INTEGER;
  offset       INTEGER;
BEGIN
  --首先获得一个lob locator 
  SELECT falls_directions
    INTO directions
    FROM waterfalls
   WHERE falls_name = 'Munising Falls';
  --记录开始读取位置 
  offset := 1;
  --尝试读取229个字符,chars_read_1将被实际读取的字符数更新 
  chars_read_1 := 229;
  dbms_lob.read(directions, chars_read_1, offset, directions_1);
  --当读取229个字符之后,更新offset,再读取225个字符 
  IF chars_read_1 = 229 THEN
    offset       := offset + chars_read_1; --offset变为offset+chars_read_1,也就是从300开始 
    chars_read_2 := 255;
    dbms_lob.read(directions, chars_read_2, offset, directions_2);
  ELSE
    chars_read_2 := 0; --否则后面不在读取 
    directions_2 := '';
  END IF;
  --显示读取的字符数 
  dbms_output.put_line('Characters read = ' ||
                       to_char(chars_read_1 + chars_read_2));
  --显示结果 
  dbms_output.put_line(directions_1);
  dbms_output.put_line(length(directions_1));
  dbms_output.put_line(directions_2);
  dbms_output.put_line(length(directions_2));
END;

Dbms_lob.read的第2个参数是传递要读取的数量。对于clob是字符数,blob和bfile都是字节数。它是随着读取的数目自动更新的,offset不会更新。所以分布读取需要手动更新offset,下个offset是上一个offset+读取的数量。我们可以通过dbms_lob.get_length(lob_locator)获得这个lob的长度,结果clob是字符数,blob和bfile是字节数,然后分布读取。




oracle中Blob和Clob类型的区别与用法

BLOB和CLOB都是大字段类型,BLOB是按二进制来存储的,而CLOB是可以直接存储文字的。其实两个是可以互换的的,或者可以直接用LOB字段代替这两个。但是为了更好的管理ORACLE数据库,通常像图...
  • baidu_25310663
  • baidu_25310663
  • 2015年04月25日 14:30
  • 4708

oracle对大对象类型操作:blob,clob,nclob,bfile

13-4 Lob类型          13.4.1 基本介绍          Oracle和plsql都支持lob(large object) 类型,用来存储大数量数据,如图像文件,声音文件等...
  • longwenze
  • longwenze
  • 2013年03月04日 09:33
  • 354

oracle varchar2改成大字段类型clob,读取大字段内容

oracle varchar2改成大字段类型,如果varchar2内容
  • cai7095576
  • cai7095576
  • 2014年04月18日 10:38
  • 3800

oracle对大对象类型操作:blob,clob,nclob

1.基本介绍 Oracle和plsql都支持lob(large object) 类型,用来存储大数量数据,如图像文件,声音文件等。Oracle 9i realse2支持存储最大为4g的数据,orac...
  • caixingyun
  • caixingyun
  • 2014年01月15日 17:43
  • 2029

oracle如何导出Blob和clob大字段

需要一个ExportBlobJianrong .java和config.xml,文件在下面提供: package thinkinjava; import java.io.BufferedW...
  • CNZYYH
  • CNZYYH
  • 2017年04月30日 15:24
  • 2126

java对Clob大数据字段类型的增删改查

前几天临时支援,帮pc端几个接口,主要是对一个表的CRUD操作,虽然快两年多没写后台相关的东西了,但还不至于连一个表的基本的CRUD操作都忘了。但悲剧往往就来的这么及时,表中有一个字段是Clob类型的...
  • lishihong108
  • lishihong108
  • 2016年08月17日 17:18
  • 3824

CLOB、BLOB , CLOB与BLOB的区别

原文链接:http://blog.csdn.net/magister_feng/article/details/7825892 CLOB 定义   数据库中的一种保存文件所使用的类型。 ...
  • u013063153
  • u013063153
  • 2016年11月16日 11:02
  • 725

关于ODBC的配置、访问ORACLE的BLOB及CString的保存

在使用C++访问ORACLE的时候,ODBC是一种选择,然后再使用CDatabase来进行openex的时候,DSN是需要配置的。以下是配置DSN的方法 打开ODBC数据源管理器(orc...
  • swping
  • swping
  • 2014年05月30日 15:26
  • 1135

kettle能抽取oracle的clob字段么?

本文转自:http://www.360doc.com/content/15/0811/09/27089714_490902857.shtml 学习使用kettle,在学习的过程中遇到一些连接数据...
  • zhaoxinglin123
  • zhaoxinglin123
  • 2015年08月11日 09:49
  • 2641

Oracle 11g中CLOB字段类型的数据读取

Oracle 11g中的CLOB字段类型的数据读取 LOB 类型的数据库列仅存储定位符,该定位符指向大型对象的存储位置.用DBMS_LOB程序包操纵 LOB 数据. 读取Oracle字段类型为CLO...
  • m0_37934173
  • m0_37934173
  • 2017年05月15日 11:02
  • 940
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:oracle对大对象类型操作:blob,clob,nclob
举报原因:
原因补充:

(最多只允许输入30个字)