HIVE实战：官方案例练习

测试文件下载

本案例来自hive官方文档

需求：一份有关观看电影的日志（u.data），有10W条数据，分析出一周内那天观影人数多

1、创建原表

CREATE TABLE u_data (
  userid INT,
  movieid INT,
  rating INT,
  unixtime STRING)
ROW FORMAT DELIMITED
FIELDS TERMINATED BY '\t'
STORED AS TEXTFILE;

LOAD DATA LOCAL INPATH '/usr/datas/u.data' into table u_data;

2、创建新表

CREATE TABLE u_data_new (
  userid INT,
  movieid INT,
  rating INT,
  weekday INT)
ROW FORMAT DELIMITED
FIELDS TERMINATED BY '\t';

3、编写python脚本用来处理unixtime转化为星期数

import sys
import datetime

for line in sys.stdin:
  line = line.strip()
  userid, movieid, rating, unixtime = line.split('\t')
  weekday = datetime.datetime.fromtimestamp(float(unixtime)).isoweekday()
  print '\t'.join([userid, movieid, rating, str(weekday)])

4、使用脚本并插入数据到新表

add FILE /usr/datas/weekday_mapper.py;

INSERT OVERWRITE TABLE u_data_new
SELECT
  TRANSFORM (userid, movieid, rating, unixtime)
  USING 'python weekday_mapper.py'
  AS (userid, movieid, rating, weekday)
FROM u_data;

5、查询

SELECT weekday, COUNT(1) count
FROM u_data_new
GROUP BY weekday order by count desc;