在vb中实现真正锁定的带自定义菜单的文本控件

原创 2002年08月21日 09:51:00

     在vb中实现真正锁定的带自定义菜单的文本控件

///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
///这个东西的出台,是由于一个网友的帖子,太气人,我才写的,很匆忙,又什么问题,请指出!谢谢////
//////////////////////////QQ:9181729/////////////mail:shawfile@163.net/////////////http://shawls.yeah.net
///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


     vb中的textbox控件,虽然可以设置locked属性来实现对文本的锁定,但是,如果用户使用右键菜单,那么就不起作用了,仍然可以对文本进行编辑,有没有办法使用户不能对文本框进行编辑而且替换掉控件的那个右键菜单呢?

     完整实现代码如下:
     ’核心代码的代码
     'uTextBox 是你要屏蔽的文本控件   m_Menu 是你要弹出的菜单  m_Read标记是否锁定
Private Sub uTextBox_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 2 And m_Read = True Then
        OldWindowProc = GetWindowLong(uTextBox.hWnd, GWL_WNDPROC)
        ' 取得窗口函数的地址
        Call SetWindowLong(uTextBox.hWnd, GWL_WNDPROC, AddressOf SubClass_WndMessage)
       ' 用SubClass_WndMessage代替窗口函数处理消息
    End If
End Sub

Private Sub uTextBox_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 2 And m_Read = True Then
        Call SetWindowLong(uTextBox.hWnd, GWL_WNDPROC, OldWindowProc)
        ' 恢复窗口的默认函数
        ' 弹出自定义菜单
        If Not m_Menu Is Nothing Then
            If TypeOf m_Menu Is Menu Then
                PopupMenu m_Menu
            End If
        End If
    End If
End Sub

'以下放置在模块中

Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long


Public Function SubClass_WndMessage(ByVal hWnd As OLE_HANDLE, ByVal Msg As OLE_HANDLE, ByVal wp As OLE_HANDLE, ByVal lp As Long) As Long
    If Msg <> WM_CONTEXTMENU Then
       SubClass_WndMessage = CallWindowProc(OldWindowProc, hWnd, Msg, wp, lp)
       ' 如果消息不是WM_CONTEXTMENU,就调用默认的窗口函数处理
       Exit Function
    End If
    SubClass_WndMessage = True
End Function

'一下是一个完整的自定义的控件的例子“
'下面放置到一个自定义控件中
VERSION 5.00
Begin VB.UserControl UTextBox
   ClientHeight    =   525
   ClientLeft      =   0
   ClientTop       =   0
   ClientWidth     =   1425
   ScaleHeight     =   525
   ScaleWidth      =   1425
   Begin VB.TextBox uTextBox
      Appearance      =   0  'Flat
      BackColor       =   &H80000018&
      Height          =   345
      Left            =   30
      TabIndex        =   0
      Top             =   90
      Width           =   1275
   End
End
Attribute VB_Name = "UTextBox"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Option Explicit

Private m_BackColor As OLE_COLOR   '颜色
Private m_MaxLength As Integer     '长度
Private m_TextAlig As VBRUN.AlignmentConstants  '文本位置
Private m_Menu As Menu     '自定义菜单
Private m_Read As Boolean    '是否可读
Private m_Enabled  As Boolean   'Enabled
'Private m_MulitLine As Boolean '换行
Private Const m_DefBackColor = &H80000018   '默认文本背景颜色
Public Event Change()          '文本修改事件
Public Event Click()           'click事件

Private Sub UserControl_Initialize()
    Call UserControl_Resize
End Sub

Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
    Let BackColor = PropBag.ReadProperty("BackColor", m_DefBackColor)
    Let MaxLength = PropBag.ReadProperty("MaxLength", 0)
    Let Text = PropBag.ReadProperty("Text", "")
    Let Alignment = PropBag.ReadProperty("Alignment", 0)
    Set Menu = PropBag.ReadProperty("Menu", Nothing)
    Let ReadOnly = PropBag.ReadProperty("Read", False)
    Let Enabled = PropBag.ReadProperty("Enabled", True)
'    Let uTextBox.MultiLine = PropBag.ReadProperty("MultiLine", False)
    'Let uTextBox.ScrollBars = PropBag.ReadProperty("ScrollBars", 0)
End Sub

Private Sub UserControl_WriteProperties(PropBag As PropertyBag)
    Call PropBag.WriteProperty("BackColor", BackColor, m_DefBackColor)
    Call PropBag.WriteProperty("MaxLength", MaxLength, 0)
    Call PropBag.WriteProperty("Text", Text, "")
    Call PropBag.WriteProperty("Alignment", Alignment, 0)
    Call PropBag.WriteProperty("Menu", Menu, Nothing)
    Call PropBag.WriteProperty("Read", ReadOnly, False)
    Call PropBag.WriteProperty("Enabled", Enabled, True)
    'Call PropBag.WriteProperty("MultiLine", MultiLine, False)
    'Call PropBag.WriteProperty("ScrollBars", ScrollBars, 0)
End Sub

Private Sub uTextBox_Click()
    RaiseEvent Click
End Sub

Private Sub uTextBox_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 2 And m_Read = True Then
        OldWindowProc = GetWindowLong(uTextBox.hWnd, GWL_WNDPROC)
        ' 取得窗口函数的地址
        Call SetWindowLong(uTextBox.hWnd, GWL_WNDPROC, AddressOf SubClass_WndMessage)
       ' 用SubClass_WndMessage代替窗口函数处理消息
    End If
End Sub

Private Sub uTextBox_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 2 And m_Read = True Then
        Call SetWindowLong(uTextBox.hWnd, GWL_WNDPROC, OldWindowProc)
        ' 恢复窗口的默认函数
        ' 弹出自定义菜单
        If Not m_Menu Is Nothing Then
            If TypeOf m_Menu Is Menu Then
                PopupMenu m_Menu
            End If
        End If
    End If
End Sub

Private Sub UserControl_Resize()
With UserControl
    uTextBox.Move .ScaleLeft, .ScaleTop, .ScaleWidth, .ScaleHeight
End With
End Sub

Public Property Let BackColor(ByVal vNewValue As OLE_COLOR)
    Let m_BackColor = vNewValue
    Let uTextBox.BackColor = vNewValue
    Let UserControl.BackColor = vNewValue
End Property

Public Property Get BackColor() As OLE_COLOR
    Let BackColor = m_BackColor
End Property

Public Property Let Text(ByVal vNewValue As String)
    Let uTextBox.Text = vNewValue
End Property

Public Property Get Text() As String
    Let Text = uTextBox.Text
End Property

Public Property Let Alignment(ByVal vNewValue As VBRUN.AlignmentConstants)
    Let m_TextAlig = vNewValue
    Let uTextBox.Alignment = vNewValue
End Property

Public Property Get Alignment() As VBRUN.AlignmentConstants
    Let Alignment = m_TextAlig
End Property

Public Property Let ReadOnly(ByVal vNewValue As Boolean)
    Let m_Read = vNewValue
    Let uTextBox.Locked = vNewValue
End Property

Public Property Get ReadOnly() As Boolean
    Let ReadOnly = m_Read
End Property

Private Sub uTextBox_Change()
    RaiseEvent Change
End Sub

Public Property Set Menu(ByRef vNewValue As Menu)
    Set m_Menu = vNewValue
End Property

Public Property Get Menu() As Menu
    Set Menu = m_Menu
End Property

Public Property Let MaxLength(ByVal vNewValue As Integer)
    Let m_MaxLength = vNewValue
    Let uTextBox.MaxLength = vNewValue
End Property

Public Property Get MaxLength() As Integer
    Let MaxLength = m_MaxLength
End Property

Public Property Let SelLength(ByVal vNewValue As Integer)
    'Let m_SelLength = vNewValue
    Let uTextBox.SelLength = vNewValue
End Property

Public Property Get SelLength() As Integer
    Let SelLength = uTextBox.SelLength
End Property

Public Property Let SelStart(ByVal vNewValue As Integer)
    Let uTextBox.SelStart = vNewValue
End Property

Public Property Get SelStart() As Integer
    Let SelStart = uTextBox.SelStart
End Property

Public Property Let SelText(ByVal vNewValue As String)
    Let uTextBox.SelText = vNewValue
End Property

Public Property Get SelText() As String
    Let SelText = uTextBox.SelText
End Property

'Public Property Let MulitLine(ByVal vNewValue As Boolean)
'    Let uTextBox.MultiLine = vNewValue
'End Property

'Public Property Get MultiLine() As Boolean
'    Let MulitLine = uTextBox.MulitLine
'End Property

'Public Property Let ScrollBars(ByVal vNewValue As VBRUN.ScrollBarConstants)
'    Let uTextBox.ScrollBars = vNewValue
'End Property

'Public Property Get ScrollBars() As VBRUN.ScrollBarConstants
'    Let ScrollBars = uTextBox.ScrollBars
'End Property

Public Property Let Enabled(ByVal vNewValue As Boolean)
    Let m_Enabled = vNewValue
    Let uTextBox.Enabled = vNewValue
    Let UserControl.Enabled = vNewValue
End Property

Public Property Get Enabled() As Boolean
    Let Enabled = m_Enabled
End Property


'将前面模块中的代码保留


'新建一个窗体,看现在这个自定义的真正锁定的文本控件如何?


 

在vb中实现真正锁定的带自定义菜单的文本控件

  • zgqtxwd
  • zgqtxwd
  • 2008年05月01日 05:06
  • 138

VB文本框textbox的那点事

1、限制文本框中只允许输入数字 在textbox的keypress事件里面写上 (1)判断输入的数字是否为小数 IfkeyAscii=46 and not(InStr(txtnumber,"."...
  • IstarI
  • IstarI
  • 2015年08月10日 10:43
  • 1954

Tiger小屋:微信的多客服功能,在自定义菜单中的实现

Tiger小屋
  • lingxiyidian001
  • lingxiyidian001
  • 2016年01月26日 21:46
  • 1232

常用算法在VB中的实现

[ 今日无聊至此,特转贴一篇以测试一下]常用算法在VB中的实现        这是根据网上获得的资料改编的,因为通常的算法都是用C程序实现的,几乎见不到用VB实现的程序,对于不熟悉C语言的人会有许多困...
  • haokexiao
  • haokexiao
  • 2006年07月10日 23:08
  • 1671

vb如何将数据库中某个字段显示在一个文本框

Dim mrc As ADODB.Recordset Private Sub cmdQuery_Click() Dim txtSQL As String Dim Ms...
  • u010066934
  • u010066934
  • 2013年09月13日 20:31
  • 2712

用VB执行带输入输出的存储过程

Dim backvalue As Integer '返回值 Dim adocmd As New ADODB.Command adocm...
  • yilin54
  • yilin54
  • 2011年07月25日 17:05
  • 633

静态文本控件类CStaticText的使用

文本是我们
  • cp32212116
  • cp32212116
  • 2014年10月22日 16:20
  • 592

带滚动条的文本控件特点

在WepApp领域,表现大段文字的
  • tiangej
  • tiangej
  • 2014年04月04日 11:41
  • 613

MyBatis实现动态代理

实现原理 Mapper接口开发只需要程序员编写Mapper接口(相当于DAO接口),由MyBatis框架根据接口定义创建接口的动态代理对象。 Mapper接口开发需要遵循以下规范: Mapper...
  • qzc70919700
  • qzc70919700
  • 2017年04月08日 15:04
  • 472

vb中rnd是什么意思

返回一个包含随机数值的 Single。 语法 Rnd[(number)] 可选的 number 参数是 Single 或任何有效的数值表达式。 返回值 如果 number 的值是 Rnd 生...
  • hello026911026
  • hello026911026
  • 2014年06月08日 15:17
  • 676
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:在vb中实现真正锁定的带自定义菜单的文本控件
举报原因:
原因补充:

(最多只允许输入30个字)