[原创]10^9进制高精度大整数加法(MMX版本)

原创 2004年07月13日 12:17:00

// 本代码使用在分治法的时候,不必考虑数据对齐的问题(如果考虑就复杂了),len也是偶数,所以后面的len为奇数的检查部分是没有必要的,跟一般的方法快不了多少,微乎其微,在此仅提供另外一种思路,本人原创的,如果你有更好的方法请告知

// 实现 dest = a + b ,dest, a, b都是高位在前,低位在后,即dest[0]表示数的最高位,a,b也类似

const unsigned int Base = 1000000000;    // 10^9

const unsigned __int64 Base64     = 0x3B9ACA003B9ACA00;
const unsigned __int64 CarryFirst = 0x0000000100000000;
const unsigned __int64 CarryNext  = 0x0000000000000001;

/* add_mmx() mmx指令版本 */
__declspec(naked)
long add_mmx(unsigned long *dest, unsigned long *a, unsigned long *b, size_t len)
{
    __asm
    {
        mov ecx, dword ptr [esp+0x10]   // len
        xor eax, eax
        test ecx, ecx
        jz add_exit

        push ebp
        mov ebp, ecx

        push ebx
        mov ebx, dword ptr [esp+0x14]   // ebx = b
        push esi
        mov esi, dword ptr [esp+0x14]   // esi = a
        push edi
        mov edi, dword ptr [esp+0x14]   // edi = dest
        sub esi, ebx                    // esi = a - b
        lea edx, dword ptr [ebx+4*ecx-8]    // &b[i]
        sub edi, ebx                    // edi = dest - b

        shr ecx, 1                      // len = len / 2

        movq mm7, Base64                // 0x3B9ACA003B9ACA00
        movq mm5, CarryFirst            // 0x0000000100000000
        movq mm6, CarryNext             // 0x0000000000000001
       
        pxor mm2, mm2                   // carry 清零

add_loop:
        movq mm0, dword ptr [esi+edx]   // a[i]
        movq mm1, dword ptr [edx]       // b[i]

        paddd mm0, mm2                  // sum = a[i]+carry
        movq mm3, mm7                   // mm7 = Base64
        paddd mm0, mm1                  // sum += b[i]

        pcmpgtd mm3, mm0                // sum >= Base(10^9) ? 这里比较复杂,有讲究,必须比较2次
        pandn mm3, mm5                  // mm5 = CarryFirst
        psrlq mm3, 32                   // 获得进位 CarryFirst, mm3 >> 32
       
        movq mm4, mm7                   // mm7 = Base64
        paddd mm0, mm3                  // 累加进位

        pcmpgtd mm4, mm0                // sum >= Base(10^9) ? 进位以后,第二次比较

        movq mm2, mm4                   // 备份比较结果
        pandn mm4, mm7                  // 获得进位减法变量, 用于sum -= Base
        pandn mm2, mm6                  // 获得下一次的进位, CarryNext

        psubd mm0, mm4                  // 相当于 sum -= Base
        psllq mm2, 32                   // carry = CarryNext << 32

        movq dword ptr [edi+edx], mm0   // dest[i] = sum
        sub edx, 8                      // edx = &b[i] - 8, 相当于i-=2
        dec ecx                         // len--
        jne add_loop

        test ebp, 1                     // 如果len是奇数,则累加最后一个数
        jz add_fast_ret

        mov ecx, dword ptr [esi+edx]    // esi = a[i]
        mov ebx, dword ptr [edx]        // edx = b[i]
        add ecx, ebx                    // sum = a[i] + b[i]
        mov ebx, Base                   // esi = Base
        add ecx, eax                    // sum += carry
        xor eax, eax                    // carry = 0
        cmp ecx, ebx                    // sum >= Base ?
        jb  add_sum                     // <
        mov eax, 1                      // carry = 1
        sub ecx, ebx                    // sum -= Base

add_sum:
        mov dword ptr [edi+edx], ecx    // dest[i] = sum

        pop edi
        pop esi
        pop ebx
        pop ebp

        emms
add_exit:
        ret

add_fast_ret:

        psrlq mm2, 32                   // carry >> 32
        movd eax, mm2                   // 返回 carry

        pop edi
        pop esi
        pop ebx
        pop ebp

        emms
        ret
    }
}

版权声明:本文为博主原创文章,未经博主允许不得转载。

高精度整数(n进制,n<=10)加法

一、概述高精度整数的意思即是数据范围极大,已经无法用unsigned long long存储的数据的运算。很多OJ中都有相关练习题(如a+b升级版等),而对于故意给出极大数据的题目此算法为常用算法。 ...
  • KSkun
  • KSkun
  • 2016年12月15日 17:57
  • 381

c语言高精度大整数加法运算

#include #include #include #include #define MAX_LEN 2000 //仅限正整数相加 int an1[MAX_LEN + 10]; int an2[M...
  • xiongyangg
  • xiongyangg
  • 2014年03月06日 15:18
  • 1688

任意长度的高精度大整数和浮点数的加法和乘法

任意长度的高精度大整数加法 方法:这里用了数据结构栈,实际上栈更方便实现高精度加法。 步骤:1、第一个数据加数按输入顺序(高位到低位)入栈1。此时栈顶为最低位             2、‍第...
  • chenglinhust
  • chenglinhust
  • 2013年09月20日 10:45
  • 2095

HDU 1042(高精度)(大数)(万进制)

这个是高精度问题,要用数组解决,核心思想:用数组储存数值,将每个数组元素当成“大数”一位数,如果元素值大于9999,则要进位,进位的值为元素值%10000;这也可以理解为一个“万进制”,可以存储的值,...
  • huatian5
  • huatian5
  • 2016年04月05日 22:40
  • 1375

基础练习 高精度加法

问题描述   输入两个整数a和b,输出这两个整数的和。a和b都不超过100位。 算法描述   由于a和b都比较大,所以不能直接使用语言中的标准数据类型来存储。对于这种问题,一般使用数...
  • Stephan14
  • Stephan14
  • 2015年03月06日 22:16
  • 795

大整数加法计算思路与算法实现

大整数加法
  • lnnnd
  • lnnnd
  • 2016年06月12日 10:17
  • 2954

(浮点数及整数)高精度乘除法

思想 高精度计算的核心思想很简单,就是模拟我们笔算的过程,因此,关键在于如何准确地模拟笔算基础代码 因为高精度乘除法中会用到高精度加减法和比较大小函数,所以就先把加减和比较函数贴出来咯int co...
  • qq_30172585
  • qq_30172585
  • 2015年12月27日 14:22
  • 1017

高精度整数相加减

include include using namespace std; string _sub(string s1, string s2);inline int compareData(const...
  • u011954296
  • u011954296
  • 2016年04月01日 16:18
  • 377

高精度大整数加法

本程序是实现一个高精度的大数加法,当然。两个数的格式仅仅只考虑了大整数的各种形态。关于数字中出现小数点,或者乱乱七八糟的字符,并未考虑在内 如例子:  -00212 + 000012345 这样的 ...
  • aiXdeweidao
  • aiXdeweidao
  • 2013年05月20日 15:33
  • 490

大数据十进制转32进制

大数据进制转换,先转出十六进制(参考网上例子),再转成二进制,再转成32进制; #include "stdio.h" #include "stdlib.h" #include "string.h" ...
  • edw200
  • edw200
  • 2016年12月05日 10:23
  • 1058
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:[原创]10^9进制高精度大整数加法(MMX版本)
举报原因:
原因补充:

(最多只允许输入30个字)