使用Beaglebone Black的PRU（二）——Hello World!

经过上一篇博客，已经安装好了am335x_pru_package，本文将用它来编写、编译一个最简单的PRU程序——闪烁BBB上的led灯。

大体来说每个PRU程序都包括两部分：

1. 在ARM核的Linux系统中运行的C语言程序
2. 在PRU中运行的汇编程序（编译成.bin文件）

其中c语言程序有两个作用：将汇编程序传到PRU中；与PRU程序互相传递数据和互动。

汇编程序源文件包括.p和.hp两种后缀的文件，最后编译成.bin文件被传到PRU执行。.hp文件类似于c语言的.h头文件，可以在.p文件中被include，它不是必须的，本例为了简单起见也不用.hp文件。

OK，我们开始做吧！

Step by step步骤

首先新建两个文件，内容分别如下：

//mytest.c
#include <stdio.h>
#include <prussdrv.h>
#include <pruss_intc_mapping.h>

#define PRU_NUM 0

int main (void)
{
    unsigned int ret;
    tpruss_intc_initdata pruss_intc_initdata = PRUSS_INTC_INITDATA;
    
    prussdrv_init ();//Initialize the PRU
    if (prussdrv_open(PRU_EVTOUT_0))//Open PRU Interrupt
    {
        printf("prussdrv_open open failed\n");
        return (-1);
    }
    prussdrv_pruintc_init(&pruss_intc_initdata);
    prussdrv_exec_program (PRU_NUM, "./prucode.bin");//Execute example on PRU
    prussdrv_pru_wait_event (PRU_EVTOUT_0);//Waiting for this instruction: MOV r31.b0, PRU0_ARM_INTERRUPT+16
    prussdrv_pru_clear_event (PRU_EVTOUT_0, PRU0_ARM_INTERRUPT);
    prussdrv_pru_disable (PRU_NUM);//Disable PRU and close memory mapping
    prussdrv_exit ();

    return(0);
}

//prucode.p
.origin 0
.entrypoint START

//Refer to this mapping in the file - \prussdrv\include\pruss_intc_mapping.h
#define PRU0_ARM_INTERRUPT      19
#define CONST_PRUCFG	        C4

//Refer to AM335X Technical Reference Manual & BBB SRM
#define GPIO1 0x4804c000
#define GPIO_CLEARDATAOUT 0x190
#define GPIO_SETDATAOUT 0x194

START:
    // Enable OCP master port
    LBCO      r0, CONST_PRUCFG, 4, 4
    CLR       r0, r0, 4         // Clear SYSCFG[STANDBY_INIT] to enable OCP master port
    SBCO      r0, CONST_PRUCFG, 4, 4

    MOV r1, 3 // loop 3 times
LOOP0:
    MOV r2, 1<<22
    MOV r3, GPIO1 | GPIO_SETDATAOUT
    SBBO r2, r3, 0, 4

    MOV r0, 100000000
DEL1:
    SUB r0, r0, 1
    QBNE DEL1, r0, 0

    MOV r2, 1<<22
    MOV r3, GPIO1 | GPIO_CLEARDATAOUT
    SBBO r2, r3, 0, 4

    MOV r0, 100000000
DEL2:
    SUB r0, r0, 1
    QBNE DEL2, r0, 0

    SUB r1, r1, 1
    QBNE LOOP0, r1, 0

    // Send notification to Host for program completion
    MOV       r31.b0, PRU0_ARM_INTERRUPT+16

    // Halt the processor
    HALT

然后编译它们。编译之前先从am335x_pru_package中复制一些必要文件到标准目录中，省得我们添加引用目录。

1. 把 pru_sw/app_loader/lib目录中的 libprussdrv.a 拷贝到 /usr/lib 中；
2. 把 pru_sw/app_loader/include 目录中的两个文件都拷贝到 /usr/include 中；
3. 把 pru_sw/utils 目录中的 pasm 拷贝到 /usr/bin 中。

下面开始编译，执行下面两条命令。

gcc mytest.c -lpthread -lprussdrv -o mytest
pasm -b prucode.p 

（其中 -lpthread -lprussdrv 参数是指要使用 libpthread.so 和 libprussdrv.a这两个库文件。）

编译完以后就生成了要在linux中运行的mytest程序和要传到PRU中的prucode.bin文件。

注意，在运行程序前，还需要做一件事。用lsmod命令查看一下uio_pruss模块有没有加载。如果没有的话，手动加载一下。这个应该加载一次就可以了。

modprobe uio_pruss

一切就绪！下面输入 ./mytest 来执行一下程序吧！

顺利的话你会看到第二个led灯亮灭了三次，每次亮和灭的时间是1秒钟。

几点分析

在执行过程中，终端处于忙碌状态，如果在这期间你按下Crtl+C终止了程序，会发现led还在按照原来的规律继续闪烁，可见灯的亮灭，或者说PRU的程序运行并不受linux程序的影响。

PRU简介中提到AM33xx中PRUSSv2的主频是200MHz，每条汇编指令执行时间是一个时钟周期。通过这个程序也可以得到验证：

    MOV r0, 100000000
DEL1:
    SUB r0, r0, 1
    QBNE DEL1, r0, 0

在这个循环等待的部分，不断对寄存器r0执行自减1和判断是否为零这两条指令，执行了100M次，所以延时为1秒。

汇编程序START:紧接着的第一部分

    // Enable OCP master port
    LBCO      r0, CONST_PRUCFG, 4, 4
    CLR       r0, r0, 4         // Clear SYSCFG[STANDBY_INIT] to enable OCP master port
    SBCO      r0, CONST_PRUCFG, 4, 4

它把SYSCFG寄存器的STANDBY_INIT位置零，否则的话将无法访问任何外部memory，包括ARM的内存和IO口等。所以记得在每个程序一开始都加上这三条指令。

Second choices

最后，如果你不想用官方工具，这里有second choice：http://www.element14.com/community/community/knode/single-board_computers/next-gen_beaglebone/blog/2013/06/16/bbb--getting-ace-working

如果你想用java脚本与PRU里的程序互动，可以参考这里：https://npmjs.org/package/pru

上面这两个东西我都没仔细看过，仅列出来供参考。

本文大量参考了这篇文章 http://www.element14.com/community/community/knode/single-board_computers/next-gen_beaglebone/blog/2013/05/22/bbb--working-with-the-pru-icssprussv2。在此感谢原作者的劳动成果。