哈尔滨理工大学软件工程专业08-7李万鹏原创作品，转载请标明出处
http://blog.csdn.net/woshixingaaa/archive/2010/12/11/6069294.aspx
本文是我对bootloader中2440init.s文件的一些理解，详细注释了一下，希望对大家有所帮助，下一步我准备移植一下uboot。
;=========================================
; NAME: 2440INIT.S
; DESC: C start up codes
; Configure memory, ISR ,stacks
; Initialize C-variables
; HISTORY:
; 2002.02.25:kwtark: ver 0.0
; 2002.03.20:purnnamu: Add some functions for testing STOP,Sleep mode
; 2003.03.14:DonGo: Modified for 2440.
;=========================================
GET option.inc ；GET相当于C语言中的include，也就是包含一个源文件到当文
GET memcfg.inc ；件中，并将被包含的文件在当前位置进行汇编。
GET 2440addr.inc
BIT_SELFREFRESH EQU (1<<22) ；EQU相当于C语言中的define，为（1<<2）定义的符号名称
;Pre-defined constants
USERMODE EQU 0x10 ；预定义一下各种工作模式
FIQMODE EQU 0x11
IRQMODE EQU 0x12
SVCMODE EQU 0x13
ABORTMODE EQU 0x17
UNDEFMODE EQU 0x1b
MODEMASK EQU 0x1f
NOINT EQU 0xc0
；定义了一下堆栈的地址我只用的开发板SDRAM中堆栈的地址范围是0x33ff4800~0x33ff7fff。
;The location of stacks
UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~
SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~
FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~
；ARM有两种工作状态16位的Thumb和32位的Arm，编译器有相对应的16位和32位两种编译方式。16位环境使用tasm.exe编译。[|]相当于C语言中的IF ELSE ENDIF。
;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.
GBLL THUMBCODE
[ {CONFIG} = 16 ;CONFIG 是ADS编译器的内建变量
THUMBCODE SETL {TRUE} ；SETL伪操作给一个全局或局部变量赋值
CODE32 ；CODE32告诉我们下面是32位的arm指令
|
THUMBCODE SETL {FALSE}
]
/*******************************************************************
下面是一个宏，用来实现子程序返回的。也就是将LR(子程序链接寄存器)的内容放入PC中。如果是THUMBCODE为真，那么bx lr。也就是跳转到lr所指向的位置执行。bx可以用来进行工作状态的切换。
*******************************************************************/
MACRO
MOV_PC_LR
[ THUMBCODE
bx lr
|
mov pc,lr
]
MEND
；与上边的类似，只是加了一个是否相等的判断。
MACRO
MOVEQ_PC_LR
[ THUMBCODE
bxeq lr
|
moveq pc,lr
]
MEND
/*******************************************************************
这个宏用来把HandlerLabel这个地址标号和HandleLabel这个地址标号绑定在一起。注意前面比后面多了一个r。在后面可以看到这样的指令 b HandlerUndef ；这是硬件自动产生的中断向量表，也是第一级中断向量表。比如产生了一个ENT0中断，如果在矢量模式下，首先是跳转b HandlerIRQ，然后就是这个宏，进入HandleIRQ，可是到底是那个中断呢，在HandleIRQ这个位置，硬件会自动产生跳转到中断处理程序的指令，也就是说是哪个中断源由硬件自己判断，并将跳转指令自动送过来。如果是非矢量模式，首先跳转到b b HandlerIRQ，然后宏展开，跳转到HandleIRQ的位置，HandleIRQ里存放的是IsrIRQ，IsrIRQ用于找到是哪一个中断源，并定位它在中断向量表中的位置。这个中断向量表在SDRAM的0x33ffff00 ~ 0x33ffffff，共256个字节，一个中断向量占4个字节，即一个字，所以这个位置可以存放64个中断源。2440只能有60个中断源。这个位置也是SDRAM最后的地址。我的SDRAM是64M，从0x30000000~0x34000000。
*******************************************************************/
MACRO
$HandlerLabel HANDLER $HandleLabel
$HandlerLabel
sub sp,sp,#4 ;decrement sp(to store jump address) ;空出一个字，留着存Handlelabel
stmfd sp!,{r0} ;PUSH the work register to stack(lr does t push because it return to original address)
ldr r0,=$HandleLabel;load the address of HandleXXX to r0
ldr r0,[r0] ;load the contents(service routine start address) of HandleXXX
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack ;将Handlelabel存到刚才空的那个字，
ldmfd sp!,{r0,pc} ;POP the work register and pc(jump to ISR) ;PC(R15)>R0,栈中高地址Handlelabel→PC
MEND
；这些符号是ADS生成的，是根据我们填的RO，RW，ZI生成的。IMPORT伪操作是导入别的文件生命的变量
IMPORT |Image$$RO$$Base| ; Base of ROM code ;RO开始地址
IMPORT |Image$$RO$$Limit| ; End of ROM code (=start of ROM data);RO结束地址
IMPORT |Image$$RW$$Base| ; Base of RAM to initialise ;RW开始地址
IMPORT |Image$$ZI$$Base| ; Base and limit of area ;RW结束地址=ZI开始地址
IMPORT |Image$$ZI$$Limit| ; to zero initialise;ZI结束地址
IMPORT MMU_SetAsyncBusMode
IMPORT MMU_SetFastBusMode
IMPORT Main ; The main entry of mon program
;从这里开始就是真正的代码入口了!
AREA Init,CODE,READONLY ;这表明下面的是一个名为Init的代码段
ENTRY
EXPORT __ENTRY
__ENTRY
;========
;复位后入口
;========
ResetEntry
;1)The code, which converts to Big-endian, should be in little endian code.
;2)The following little endian code will be compiled in Big-Endian mode.
; The code byte order should be changed as the memory bus width.
;3)The pseudo instruction,DCD can t be used here because the linker generates error.
/*******************************************************************
是否进行大小端切换。ASSERT断言错误伪操作，如果表达式为假就报错，这里如果未定义ENDIAN_CHANGE就报错，如果ENDIAN_CHANGE为true，如果未定义ENTRY_BUS_WIDTH，就报错。根据不同的总线宽度32，16，8进行大小端的切换。andeq r14,r7,r0,lsl #20 ，streq r0,[r0,-r10,ror #1] ，与b ChangeBigEndian的作用相同。
*******************************************************************/
ASSERT :DEF:ENDIAN_CHANGE
[ ENDIAN_CHANGE ;ENDIAN_CHANGE、ENTRY_BUS_WIDTH在option.inc中定义的。
ASSERT :DEF:ENTRY_BUS_WIDTH
[ ENTRY_BUS_WIDTH=32
b ChangeBigEndian ;DCD 0xea000007
]
[ ENTRY_BUS_WIDTH=16
andeq r14,r7,r0,lsl #20 ;DCD 0x0007ea00
]
[ ENTRY_BUS_WIDTH=8
streq r0,[r0,-r10,ror #1] ;DCD 0x070000ea
]
|
；这段是异常中断向量表
b ResetHandler ；这段是复位程序，先进行大小端切换，然后进入复位异常处理程序
]
b HandlerUndef ;handler for Undefined mode
b HandlerSWI ;handler for SWI interrupt
b HandlerPabort ;handler for PAbort
b HandlerDabort ;handler for DAbort
b . ;reserved
b HandlerIRQ ;handler for IRQ interrupt
b HandlerFIQ ;handler for FIQ interrupt
；电源管理 EnterPWDN在后面进行了实现，主要是进入IDLE模式和SLEEP模式
;@0x20
b EnterPWDN ; Must be @0x20.
；从小端切换到大端的实现过程
ChangeBigEndian
;@0x24
[ ENTRY_BUS_WIDTH=32
DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0
DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80; //Big-endian
DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0
]
[ ENTRY_BUS_WIDTH=16
DCD 0x0f10ee11
DCD 0x0080e380
DCD 0x0f10ee01
]
[ ENTRY_BUS_WIDTH=8
DCD 0x100f11ee
DCD 0x800080e3
DCD 0x100f01ee
]
；相当于NOP指令，作用是等待从小端模式向大端模式切换
DCD 0xffffffff ;swinv 0xffffff is similar with NOP and run well in both endian mode.
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
DCD 0xffffffff
b ResetHandler
；将HandlerLabel与HandleLabel进行关联，所谓的“加载程序”
HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort
/*******************************************************************
下面这段代码用于非矢量中断。INTOFFSET中断偏移寄存器。中断偏移寄存器显示了哪个IRQ中断模式的请求在INTPND寄存器中。该位可以通过清除SRCPND和INTPND寄存器被自动清除。 在汇编中INTOFFSET等寄存器的名字是指寄存器的地址，比如INTOFFSET是INTOFFSET这个寄存器的地址，所以ldr r9 = INTOFFSET，在C语言中，INTOFFSET是INTOFFSET这个寄存器的内容。
*******************************************************************/
IsrIRQ
sub sp,sp,#4 ；首先在栈中留出一个字的位置
stmfd sp!,{r8-r9} ；由于要用到r8，r9所以先压栈，保存
ldr r9,=INTOFFSET ；把INTOFFSET寄存器的地址放入r9中
ldr r9,[r9] ；把INTOFFSET寄存器的内容放入r9寄存器中
ldr r8,=HandleEINT0 ；得到中断向量表的基地址
add r8,r8,r9,lsl #2 ；用基址加变址的方式得到中断向量表的地址
ldr r8,[r8] ；把中断处理程序的入口地址放入r8
str r8,[sp,#8] ；将r8压入栈中
ldmfd sp!,{r8-r9,pc} ； 使r8,r9和入口地址出栈，并跳转到中断服务程序中
LTORG
/*******************************************************************
这个是程序的入口，主要进行了关闭看门狗，屏蔽所有中断，设置时钟，设置内存控制，检查启动方式，如果是Nandflash，进行代码的搬运。如果是Norflash，将代码复制到RO指定的位置。初始化各个模式下的堆栈。
*******************************************************************/
;=======
; ENTRY
;=======
ResetHandler
ldr r0,=WTCON
ldr r1,=0x0 ；WTCON的第0位是复位信号输出允许位
str r1,[r0]
ldr r0,=INTMSK
ldr r1,=0xffffffff ；屏蔽所有的中断
str r1,[r0]
ldr r0,=INTSUBMSK ；屏蔽所有的子中断
ldr r1,=0x7fff
str r1,[r0]
;led显示
[ {FALSE} ;不在这里初始化led，所以用{FALSE}关掉。
; rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);
; Led_Display
ldr r0,=GPFCON
ldr r1,=0x5500
str r1,[r0]
ldr r0,=GPFDAT
ldr r1,=0x10
str r1,[r0]
]
/**********************************************************************************
设置系统时钟，主要设置PLL锁定时间和UPLL（USB时钟）和MPLL的主频。S3C2440A的时钟控制逻辑有两个PLL，一个是UPLL，一个是MPLL。MPLL可以产生FCLK（for CPU），HCLK(for AHB bus),PCLK(for APB bus)。
**********************************************************************************/
;To reduce PLL lock time, adjust the LOCKTIME register.
ldr r0,=LOCKTIME
ldr r1,=0xffffff ；复位后 LOCKTIME 是0xffffffff
str r1,[r0]
[ PLL_ON_START ;在option.inc中定义，初始化为真
; Added for confirm clock divide. for 2440.
; Setting value Fclk:Hclk:Pclk
ldr r0,=CLKDIVN
ldr r1,=CLKDIV_VAL ; 0=1:1:1, 1=1:1:2, 2=1:2:2, 3=1:2:4, 4=1:4:4, 5=1:4:8, 6=1:3:3, 7=1:3:6.
str r1,[r0] ;CLKDIV_VAL EQU x 在option.inc中定义；CLKDIVN为2440的寄存器，在 ;2440addr.inc中定义
[ CLKDIV_VAL>1 ; means Fclk:Hclk is not 1:1.
mrc p15,0,r0,c1,c0,0
orr r0,r0,#0xc0000000;R1_nF:OR:R1_iA
mcr p15,0,r0,c1,c0,0
|
mrc p15,0,r0,c1,c0,0
bic r0,r0,#0xc0000000;R1_iA:OR:R1_nF
mcr p15,0,r0,c1,c0,0
]
;Configure UPLL ;一定要使最后的频率为48MHz,不然你甭想用USB接口了,
ldr r0,=UPLLCON
ldr r1,=((U_MDIV<<12)+(U_PDIV<<4)+U_SDIV) ;U_MDIV、U_PDIV、U_SDIV在option.inc中定义
str r1,[r0]
nop ; Caution: After UPLL setting, at least 7-clocks delay must be inserted for setting hardware be completed.
nop
nop
nop
nop
nop
nop
;Configure MPLL
ldr r0,=MPLLCON
ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV) ;Fin=16.9344MHz ;M_MDIV、M_PDIV、M_SDIV在option.inc中定义
str r1,[r0]
]
;Check if the boot is caused by the wake-up from SLEEP mode.
ldr r1,=GSTATUS2
ldr r0,[r1]
tst r0,#0x2
;In case of the wake-up from SLEEP mode, go to SLEEP_WAKEUP handler.
bne WAKEUP_SLEEP
; EXPORT StartPointAfterSleepWakeUp
;StartPointAfterSleepWakeUp
;Set memory control registers ;设置存储器13个控制寄存器的值
;ldr r0,=SMRDATA
adrl r0, SMRDATA
ldr r1,=BWSCON ;BWSCON Address
add r2, r0, #52 ;End address of SMRDATA
0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0
;delay
mov r0, #&1000
1
subs r0, r0, #1
bne %B1
;===
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;; When EINT0 is pressed, Clear SDRAM
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; check if EIN0 button is pressed
；检查EIN0按钮是否被按下
ldr r0,=GPFCON
ldr r1,=0x0
str r1,[r0] ；GPFCON=0，F口为输入
ldr r0,=GPFUP
ldr r1,=0xff
str r1,[r0] ；GPFUP=0xff，上拉功能无效
ldr r1,=GPFDAT
ldr r0,[r1] ；读取F口数据
bic r0,r0,#(0x1e<<1) ；仅保留第1位数据，其他清0
tst r0,#0x1 ；判断第1位
bne %F1 ；不为0表示按钮没有被按下，则向前跳转，不执行清空SDRAM
; Clear SDRAM Start
；清空SDRAM
ldr r0,=GPFCON
ldr r1,=0x55aa
str r1,[r0] ；GPF7~4为输出，GPF3~0为中断
; ldr r0,=GPFUP
; ldr r1,=0xff
; str r1,[r0] ；上拉功能无效
ldr r0,=GPFDAT
ldr r1,=0x0
str r1,[r0] ;GPFDAT = 0
mov r1,#0
mov r2,#0
mov r3,#0
mov r4,#0
mov r5,#0
mov r6,#0
mov r7,#0
mov r8,#0
ldr r9,=0x4000000 ；64MB RAM
ldr r0,=0x30000000 ；RAM首地址
；清空64MB的RAM
0
stmia r0!,{r1-r8}
subs r9,r9,#32
bne %B0
;Clear SDRAM End
1
;Initialize stacks
bl InitStacks
; Setup IRQ handler//建立中断表
ldr r0,=HandleIRQ ;This routine is needed
ldr r1,=IsrIRQ ;if there isn t 'subs pc,lr,#4' at 0x18, 0x1c
str r1,[r0]
;===========================================================
;// 判断是从nor启动还是从nand启动
;===========================================================
；下面的代码为把ROM中的数据复制到RAM中
ldr r0, =BWSCON
ldr r0, [r0]
ands r0, r0, #6 ；读取OM[1:0]引脚状态
；为0表示从NAND Flash启动，不为0则从NOR Flash启动
bne copy_proc_beg ；跳转，不用读取NAND Flash
adr r0, ResetEntry ；OM[1:0] == 0，从NAND Flash启动
cmp r0, #0 ;if use Multi-ice,
bne copy_proc_beg ;do not read nand flash for boot
;nop
/*******************************************************************
这里是2440进行代码搬运。如果是从Nandflash中启动，首先要把启动代码的前4k拷贝到称为“SteppingStone”的4kSRAM中，然后在这4k代码中将剩下的代码从Nandflash拷贝到SDRAM中。
*******************************************************************/
nand_boot_beg
[ {TRUE}
bl RdNF2SDRAM ；复制NAND Flash到SDRAM
]
ldr pc, =copy_proc_beg
/*******************************************************************
比较ResetEntry和BaseOfROM，如果相等，在内存运行ICE，无需赋值code区中的RO段，但要复制code中的RW段。下面这个针对代码在NorFlash时的拷贝方法。功能为把从ResetEntry起，TopOfROM-BaseOfROM大小的数据拷贝到BaseOfROM。TopOfROM和BaseOfROM为|Image$$RO$$Limit|和|Image$$RO$$Base|，|Image$$RO$$Limit|和|Image$$RO$$Base|由连接器生成。为生成的代码的代码段运行时的起始和终止地址。开始时r0=RetEntry（source），r2=BaseOfROM(destination)。终止条件：复制了TopOfROM-BaseOfROM大小。
*******************************************************************/
copy_proc_beg
adr r0, ResetEntry
ldr r2, BaseOfROM
cmp r0, r2
ldreq r0, TopOfROM
beq InitRam
ldr r3, TopOfROM
0
ldmia r0!, {r4-r7}
stmia r2!, {r4-r7}
cmp r2, r3
bcc %B0
sub r2, r2, r3
sub r0, r0, r2
/*******************************************************************
比较BaseOfBSS和BaseOfZero，当代码在内存中运行时，r0(初始值)＝TopOfROM，这之后的BaseOfZero-BaseOfBSS仍属于code，需要拷贝到BaseOfBSS。
*******************************************************************/*
InitRam
ldr r2, BaseOfBS
ldr r3, BaseOfZero
0
cmp r2, r3
ldrcc r1, [r0], #4
strcc r1, [r2], #4
bcc %B0
/*******************************************************************
下面的循环体是为未初始化的全局变量赋值为0
*******************************************************************/
mov r0, #0
ldr r3, EndOfBSS
1
cmp r2, r3
strcc r0, [r2], #4
bcc %B1
ldr pc, =%F2 ;goto compiler address
2
; [ CLKDIV_VAL>1 ；if FCLK：HCLK≠1：1
; bl MMU_SetAsyncBusMode ；设置时钟模式为异步模式
; |
; bl MMU_SetFastBusMode ；设置时钟模式为快速总线模式
; ]
;===========================================================
;function initializing stacks
InitStacks
;Don t use DRAM,such as stmfd,ldmfd......
;SVCstack is initialized before
;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'
/*******************************************************************
修改状态寄存器一般是通过“读取－修改－写回”，先将cpsr中的内容取出，放入r0中，通过orr操作进行置位，然后通过指令msr写回到cpsr，这样就进行了工作状态的切换，栈的地址前面已经声明过了，所以这里直接赋值就可以。 系统复位后进入的是SVC模式，而且各种模式下的lr不同，因此要想从该函数内返回，要首先切换到SVC模式，再使用lr，这样可以返回了，
mov pc,lr 。
*******************************************************************/
mrs r0,cpsr
bic r0,r0,#MODEMASK
orr r1,r0,#UNDEFMODE|NOINT
msr cpsr_cxsf,r1 ;UndefMode
ldr sp,=UndefStack ; UndefStack=0x33FF_5C00
orr r1,r0,#ABORTMODE|NOINT
msr cpsr_cxsf,r1 ;AbortMode
ldr sp,=AbortStack ; AbortStack=0x33FF_6000
orr r1,r0,#IRQMODE|NOINT
msr cpsr_cxsf,r1 ;IRQMode
ldr sp,=IRQStack ; IRQStack=0x33FF_7000
orr r1,r0,#FIQMODE|NOINT
msr cpsr_cxsf,r1 ;FIQMode
ldr sp,=FIQStack ; FIQStack=0x33FF_8000
bic r0,r0,#MODEMASK|NOINT
orr r1,r0,#SVCMODE
msr cpsr_cxsf,r1 ;SVCMode
ldr sp,=SVCStack ; SVCStack=0x33FF_5800
;USER mode has not be initialized.
mov pc,lr
;The LR register won t be valid if the current mode is not SVC mode.
;--------------------LED test
EXPORT Led_Test
Led_Test
mov r0, #0x56000000
mov r1, #0x5500
str r1, [r0, #0x50]
0
mov r1, #0x50
str r1, [r0, #0x54]
mov r2, #0x100000
1
subs r2, r2, #1
bne %B1
mov r1, #0xa0
str r1, [r0, #0x54]
mov r2, #0x100000
2
subs r2, r2, #1
bne %B2
b %B0
mov pc, lr
LTORG
;GCS0->SST39VF1601
;GCS1->16c550
;GCS2->IDE
;GCS3->CS8900
;GCS4->DM9000
;GCS5->CF Card
;GCS6->SDRAM
;GCS7->unused
SMRDATA DATA
; Memory configuration should be optimized for best performance
; The following parameter is not optimized.
; Memory access cycle parameter strategy
; 1) The memory settings is safe parameters even at HCLK=75Mhz.
; 2) SDRAM refresh period is for HCLK<=75Mhz.
/*******************************************************************
这个是SMRDATA区域的13个寄存器的值，下面的一些符号在Memcfg.inc中定义。用于初始化各个bank。
Memory control
BWSCON EQU 0x48000000 ;Bus width & wait status
BANKCON0 EQU 0x48000004 ;Boot ROM control
BANKCON1 EQU 0x48000008 ;BANK1 control
BANKCON2 EQU 0x4800000c ;BANK2 control
BANKCON3 EQU 0x48000010 ;BANK3 control
BANKCON4 EQU 0x48000014 ;BANK4 control
BANKCON5 EQU 0x48000018 ;BANK5 control
BANKCON6 EQU 0x4800001c ;BANK6 control
BANKCON7 EQU 0x48000020 ;BANK7 control
REFRESH EQU 0x48000024 ;DRAM/SDRAM refresh
BANKSIZE EQU 0x48000028 ;Flexible Bank Size
MRSRB6 EQU 0x4800002c ;Mode register set for SDRAM Bank6
MRSRB7 EQU 0x48000030 ;Mode register set for SDRAM Bank7
*******************************************************************/
DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) ;GCS0
DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) ;GCS1
DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) ;GCS2
DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) ;GCS3
DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) ;GCS4
DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) ;GCS5
DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6
DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7
DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Tsrc<<18)+(Tchr<<16)+REFCNT)
DCD 0x32 ;SCLK power saving mode, BANKSIZE 128M/128M
;DCD 0x02 ;SCLK power saving disable, BANKSIZE 128M/128M
DCD 0x20 ;MRSR6 CL=2clk
DCD 0x20 ;MRSR7 CL=2clk
/*******************************************************************
运行域定义，比如|Image$$ZI$$Base|是ZI区在RAM中的起始地址，|Image$$ZI$$Limit|是ZI区在RAM中的结束地址。在CodeWarrior的设置中，RW Base选项保留为空，RO属性的输出段，RW属性的输出段以及ZI属性的输出段都包含在一个域中，这些可以在从List.txt文件中看出，3者定义的地址是顺序相连的，它们之间的相对位置不用重新加载已经是正确的了。所以直接把这三个段整体拷贝到SDRAM中就可以运行，而不需要再按照各段的值进行加载。如果RW设置某一固定值，这时就需要3个段值进行加载了。
*******************************************************************/
BaseOfROM DCD |Image$$RO$$Base|
TopOfROM DCD |Image$$RO$$Limit|
BaseOfBSS DCD |Image$$RW$$Base|
BaseOfZero DCD |Image$$ZI$$Base|
EndOfBSS DCD |Image$$ZI$$Limit|
ALIGN
;Function for entering power down mode
; 1. SDRAM should be in self-refresh mode.
; 2. All interrupt should be maksked for SDRAM/DRAM self-refresh.
; 3. LCD controller should be disabled for SDRAM/DRAM self-refresh.
; 4. The I-cache may have to be turned on.
; 5. The location of the following code may have not to be changed.
;void EnterPWDN(int CLKCON);
/*******************************************************************
进入电源管理部分，ATPCS定义了｛R0～R3｝作为参数传递和结果返回，超过4个放堆栈里。编程时尽可能4个之内的参数。所以这里R0是EnterPWDN的参数，r0=CLKCON。
*******************************************************************/
EnterPWDN
mov r2,r0 ;r2=rCLKCON
tst r0,#0x8 ;SLEEP mode?
bne ENTER_SLEEP
ENTER_STOP
ldr r0,=REFRESH ； 进入IDLE模式前要设置SDRAM的自刷新，否则数据丢失了
ldr r3,[r0] ;r3=rREFRESH
mov r1, r3
orr r1, r1, #BIT_SELFREFRESH
str r1, [r0] ;Enable SDRAM self-refresh
mov r1,#16 ;就是一个等待
0 subs r1,r1,#1
bne %B0
ldr r0,=CLKCON ；进入IDLE模式
str r2,[r0]
mov r1,#32
0 subs r1,r1,#1 ;1) wait until the STOP mode is in effect.
bne %B0 ;2) Or wait here until the CPU&Peripherals will be turned-off
; Entering SLEEP mode, only the reset by wake-up is available.
ldr r0,=REFRESH
str r3,[r0] ；这里的r3是设置了自刷新之前的值，改变的是r1，所以可以用r3直 接赋值
MOV_PC_LR
ENTER_SLEEP
;NOTE.
;1) rGSTATUS3 should have the return address after wake-up from SLEEP mode.
ldr r0,=REFRESH ；进入睡眠模式也要自刷新
ldr r1,[r0] ;r1=rREFRESH
orr r1, r1, #BIT_SELFREFRESH
str r1, [r0] ;Enable SDRAM self-refresh
mov r1,#16 ;Wait until self-refresh is issued,which may not be needed.
0 subs r1,r1,#1
bne %B0
ldr r1,=MISCCR
ldr r0,[r1]
orr r0,r0,#(7<<17) ;Set SCLK0=0, SCLK1=0, SCKE=0.
str r0,[r1]
ldr r0,=CLKCON ; Enter sleep mode
str r2,[r0]
b . ;CPU will die here.
WAKEUP_SLEEP
;Release SCLKn after wake-up from the SLEEP mode.
ldr r1,=MISCCR
ldr r0,[r1]
bic r0,r0,#(7<<17) ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:0->=SCKE.
str r0,[r1]
/*******************************************************************
设置内存控制寄存器，在SMRDATA中已经设定好，BWSCON总线宽度和等待状态寄存器，地址0x48000000，是13内存控制寄存器的起始地址。
*******************************************************************/
ldr r0,=SMRDATA
ldr r1,=BWSCON
add r2, r0, #52 ；r2是这13个寄存器结束的地址
0
ldr r3, [r0], #4 ；通过r3作为中介，把以r0为基址的内容向r1为基址的地方拷贝
str r3, [r1], #4
cmp r2, r0 ；如果没有结束继续拷贝
bne %B0
mov r1,#256
0 subs r1,r1,#1
bne %B0
ldr r1,=GSTATUS3 ;GSTATUS3 has the start address just after SLEEP wake-up
ldr r0,[r1]
mov pc,r0
;=====================================================================
; Clock division test
; Assemble code, because VSYNC time is very short
;=====================================================================
EXPORT CLKDIV124
EXPORT CLKDIV144
CLKDIV124
ldr r0, = CLKDIVN
ldr r1, = 0x3 ; 0x3 = 1:2:4
str r1, [r0]
; wait until clock is stable
nop
nop
nop
nop
nop
ldr r0, = REFRESH
ldr r1, [r0]
bic r1, r1, #0xff
bic r1, r1, #(0x7<<8)
orr r1, r1, #0x470 ; REFCNT135
str r1, [r0]
nop
nop
nop
nop
nop
mov pc, lr
CLKDIV144
ldr r0, = CLKDIVN
ldr r1, = 0x4 ; 0x4 = 1:4:4
str r1, [r0]
; wait until clock is stable
nop
nop
nop
nop
nop
ldr r0, = REFRESH
ldr r1, [r0]
bic r1, r1, #0xff
bic r1, r1, #(0x7<<8)
orr r1, r1, #0x630 ; REFCNT675 - 1520
str r1, [r0]
nop
nop
nop
nop
nop
mov pc, lr
ALIGN
；二级中断向量表，软件实现的
AREA RamData, DATA, READWRITE
^ _ISR_STARTADDRESS ; _ISR_STARTADDRESS=0x33FF_FF00
HandleReset # 4
HandleUndef # 4
HandleSWI # 4
HandlePabort # 4
HandleDabort # 4
HandleReserved # 4
HandleIRQ # 4
HandleFIQ # 4
;Don t use the label 'IntVectorTable',
;The value of IntVectorTable is different with the address you think it may be.
;IntVectorTable
;@0x33FF_FF20
HandleEINT0 # 4
HandleEINT1 # 4
HandleEINT2 # 4
HandleEINT3 # 4
HandleEINT4_7 # 4
HandleEINT8_23 # 4
HandleCAM # 4 ; Added for 2440.
HandleBATFLT # 4
HandleTICK # 4
HandleWDT # 4
HandleTIMER0 # 4
HandleTIMER1 # 4
HandleTIMER2 # 4
HandleTIMER3 # 4
HandleTIMER4 # 4
HandleUART2 # 4
;@0x33FF_FF60
HandleLCD # 4
HandleDMA0 # 4
HandleDMA1 # 4
HandleDMA2 # 4
HandleDMA3 # 4
HandleMMC # 4
HandleSPI0 # 4
HandleUART1 # 4
HandleNFCON # 4 ; Added for 2440.
HandleUSBD # 4
HandleUSBH # 4
HandleIIC # 4
HandleUART0 # 4
HandleSPI1 # 4
HandleRTC # 4
HandleADC # 4
;@0x33FF_FFA0
END
1195
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
