[USACO 1.1.4] Broken Necklace

[题目描述]

Broken Necklace

破碎的项链

你有一条由N个红色的，白色的，或蓝色的珠子组成的项链(3<=N<=350)，珠子是随意安排的。 这里是 n=29的二个例子:

第一和第二个珠子在图片中已经被作记号。 

图片 A 中的项链可以用下面的字符串表示： 

brbrrrbbbrrrrrbrrbbrbbbbrrrrb . 

假如你要在一些点打破项链,展开成一条直线，然后从一端开始收集同颜色的珠子直到你遇到一个不同的颜色珠子，在另一端做同样的事。(颜色可能与在这之前收集的不同) 确定应该在哪里打破项链来收集到最大多数的数目的子。 Example 举例来说，在图片 A 中的项链，可以收集到8个珠子,在珠子 9 和珠子 10 或珠子 24 和珠子 25 之间打断项链。 在一些项链中，包括白色的珠子如图片 B 所示。 当收集珠子的时候，一个被遇到的白色珠子可以被当做红色也可以被当做蓝色。 表现项链的字符串将会包括三符号 r ， b 和 w 。 写一个程序来确定从一条被供应的项链最大可以被收集珠子数目。 

PROGRAM NAME: beads

INPUT FORMAT 

第 1 行:	N, 珠子的数目
第 2 行:	一串度为N的字符串, 每个字符是 r ， b 或 w。

SAMPLE INPUT (file beads.in) 

29 

wwwbbrwrbrbrrbrbrwrwwrbwrwrrb 

OUTPUT FORMAT 

单独的一行包含从被供应的项链可以被收集的珠子数目的最大值。 

SAMPLE OUTPUT (file beads.out) 

11

[解题思路]

N=350的数据范围，自然想到枚举断点，统计答案的搜索算法，总时间复杂度O(N^2)。

但是，本题还有一个更为高效的算法——DP。

用四个数组bl,br,rl,rr分别记录当前点蓝色与红色的最远扩展长度，类似于前缀和，可以O(N)的预处理出这四个数组。

所以最后答案就是：ans=max{max(bl[i]，rl[i])+max(br[i]，rr[i])}，其中1<=i<=2*n 。

值得一提的是，统计答案的时候要加判断，如果某一位置i的max(bl[i]，rl[i])+max(br[i]，rr[i])大于n（因为可能出现左右两段连通的情况），则答案就是n 。

[Code]

这个是搜素算法：

{
ID: zane2951
PROG: beads
LANG: PASCAL
}

program beads;
var
   n,ans,i:longint;
   s:ansistring;

//---------check-----------
procedure check(p:longint);
var
   s1,s2,ce,i:longint;
   lab:char;

begin
   s1:=0; lab:='w';
   for i:=p to p+n-1 do
      if (s[i]=lab) or (s[i]='w') then inc(s1) else
         if lab='w' then begin lab:=s[i]; inc(s1); end else break;
   s2:=0; lab:='w';
   for i:=p+n-1 downto p do
      if (s[i]=lab) or (s[i]='w') then inc(s2) else
         if lab='w' then begin lab:=s[i]; inc(s2); end else break;
   ce:=s1+s2;
   if ce>n then ce:=n;
   if ce>ans then ans:=ce;
end;

//----------main-----------
begin
   assign(input,'beads.in'); reset(input);
   assign(output,'beads.out'); rewrite(output);
   readln(n);
   readln(s);
   s:=s+s;
   ans:=0;
   for i:=1 to n do check(i);
   writeln(ans);
   close(input); close(output);
end.

这个是DP：

{
ID: zane2951
PROG: beads
LANG: PASCAL
}

program beads;
var
   bl,br,rl,rr:array[-11..1111] of longint;
   n,ans,i,ce:longint;
   s:ansistring;

//-----------max-----------
function max(a,b:longint):longint;
begin
   if a>b then exit(a) else exit(b);
end;

//----------main-----------
begin
   assign(input,'beads.in'); reset(input);
   assign(output,'beads.out'); rewrite(output);
   readln(n);
   readln(s);
   s:='#'+s+s+'#'; n:=n<<1;
   for i:=2 to n+1 do
      case s[i] of
         'w':begin bl[i]:=bl[i-1]+1; rl[i]:=rl[i-1]+1; end;
         'b':begin bl[i]:=bl[i-1]+1; rl[i]:=0; end;
         'r':begin rl[i]:=rl[i-1]+1; bl[i]:=0; end;
      end;
   for i:=n+1 downto 2 do
      case s[i] of
         'w':begin br[i]:=br[i+1]+1; rr[i]:=rr[i+1]+1; end;
         'b':begin br[i]:=br[i+1]+1; rr[i]:=0; end;
         'r':begin rr[i]:=rr[i+1]+1; br[i]:=0; end;
      end;
   ans:=0;
   for i:=2 to n+1 do
      begin
         ce:=max(bl[i],rl[i])+max(br[i+1],rr[i+1]);
         if ce>n>>1 then ce:=n>>1;
         if ce>ans then ans:=ce;
      end;
   writeln(ans);
   close(input); close(output);
end.