用 Delphi 实现报表的横向分组打印

原创 2003年09月23日 01:29:00

    Delphi 内置的 QuickReport 报表系统为我们快速制作报表提供了有力的支持。对于一些简单的报表,包括纵向分组多表头报表,我们几乎不用写一句代码,就可以方便地完成报表的制作。但是对于图一所示的横向分组的报表,我们还需要写一些代码来控制报表的打印格式。本文就以图一所示报表为例,向大家介绍横向分组报表的制作方法和技巧。

     

    首先添加一个报表窗体 QRForm1,在该窗体上添加报表控件 QuickRep1,设置其 Bands 属性,使包含标题、表头、表细节、表脚等属性。再在报表窗体上添加 ADOConnection1 连接控件和两个 ADODataSet 控件,分别命名为 ADODataSetShqk 和 ADODataSet1。其中 ADOConnection1 与数据库连接,ADODataSetShqk 与将要显示和打印的数据表绑定,该数据集必须添加永久性字段。
    然后用 QRShape 勾画报表的表头和细节。其中横线的 Shape 属性设为 qrsHorLine,height=1;竖线的 Shape 属性设为 qrsVertLine,width=1,竖线分割各字段,产生纵向表格线。这里的关键问题是:怎样产生报表记录的横向分组?为了达到代码控制的目的,我们在勾画报表细节时,在“序号”“道路名称”上方放置横向 QRShape100,在“损坏情况”“损坏时间”“面积”上方放置横向 QRShape200,在整个 DetailBand 下方放置横向 QRShape300。在 DetailBand 中的“序号”“道路名称”位置放置 QRLabel,分别命名为 QRLabelXh 和 QRLabelDlmc,在“损坏情况”“损坏时间”“面积”位置放置 QRDBText,分别与对应的字段对应。
    实现横向分组的原理是:在报表 DetailBand 的 BeforePrint 事件中进行判断,如果记录的“序号”“道路名称”与前一条记录相同,就不打印 QRShape100(使其 width=0),否则打印。如果报表打印到本页末或打印完所有记录,就打印 QRShape300,否则 QRShape300 的宽度为 0,即不打印。
    设计阶段有关控件的属性设置为:QuickRep1.Dataset=ADODataSetRptShqk,ADODataSetShqk 和 ADODataSet1 的 Connection=ADOConnection1,ADODataSetShqk 的 CommandText 属性需要填写 SQL 语句 Select … from …;ADODataSet1 的 Active 属性为 False。
    最后在主窗体上添加代码 QRForm1.QuickRep1.Preview; 和 QRForm1.QuickRep1.Print; 预览或直接打印报表。
unit Report1;
interface
uses ……
type ……
var
  QRForm1: TQRForm1;
  OldStr: string;
  LinesPerPage: Integer;      //每页已经打印的记录数
  LinePerItem: Integer;       //每个横向分组的记录数累计
  LinesTotal: Integer;        //已经打印的记录总数
  LineDisplayItem: Integer;   //该行显示横向分组公共信息
  ADODataSet1Count: Integer;  //每个横向分组的记录数
  Id: Integer;                //横向分组序号
implementation
{$R *.dfm}
//自定义函数:判断是否打印到本页页脚
function TQRForm1.isPagefoot(): boolean;
begin
 result :=False;
 LinesPerPage :=LinesPerPage + 1;
 { 根据报表预览结果手工确定每页的记录数,
   本程序第1页为33条记录,其他页为36条记录 }
 if QuickRep1.PageNumber = 1 then
 begin
  if LinesPerPage =33 then result :=True;
 end
 else
 begin
  if LinesPerPage =36 then result :=True;
 end;
end;

//自定义函数:判断是否打印完所有记录
function TQRForm1.isLastRecord(): boolean;
begin
  ADODataSetRptShqk.Next;
  if ADODataSetRptShqk.Eof then
   result :=true
  else
  Begin
    ADODataSetRptShqk.Prior;
    result :=false;
  end;
end;

//初始化变量:
procedure TQRForm1.QuickRep1BeforePrint(Sender: TCustomQuickRep;
  var PrintReport: Boolean);
begin
  oldstr :='';
  LinesPerPage :=0;
  LinePerItem :=0;
  LinesTotal :=0;
  LineDisplayItem :=0;
  Id :=0;
  ADODataSet1Count :=0;
end;

///写报表的细节-根据条件进行横向分组控制:
procedure TQRForm1.DetailBand1BeforePrint(Sender:TQRCustomBand;
                   var PrintBand:Boolean);
var
  NewStr: string;
begin
  LinesTotal :=LinesTotal + 1;
  NewStr :=trim(ADODataSetRptShqk.FieldbyName('dlmc').AsString);
  if NewStr=OldStr then
    QRShape100.Width :=0
  else
  begin
    ADODataSet1.CommandText :='select count(dlmc) as Count1 from rpt_Shqk where dlmc='+''''+NewStr+'''';
    ADODataSet1.Active :=True;
    ADODataSet1Count :=ADODataSet1.FieldByName('Count1').AsInteger;
    ADODataSet1.Active :=False;
    LinePerItem :=LinePerItem + ADODataSet1Count;
    LineDisplayItem :=LinePerItem - ADODataSet1Count div 2;
    QRShape100.Width :=285;
    OldStr :=trim(NewStr);
    Id :=Id + 1;
  end;
  if LinesTotal = LineDisplayItem then
  begin
    QRLabelXh.Caption :=InttoStr(Id);
    QRLabelDlmc.Caption :=trim(ADODataSetRptShqk.FieldbyName('dlmc').AsString);
  end
  else
  begin
    QRLabelXh.Caption :='';
    QRLabelDlmc.Caption :='';
  end;
 //根据条件画底线:
  QRShape300.Width :=0;
 //1,如果一页输出完毕,画底线:
  if isPagefoot() then
  begin
    QRShape300.Width :=697;
    LinesPerPage :=0;
  end;
 //2,如果记录输出完毕,画底线:
  if isLastRecord() then QRShape300.Width :=697;
end;

procedure TQRForm1.FormCloseQuery(Sender: TObject;var CanClose: Boolean);
begin
  QuickRep1.Free;
end;

procedure TQRForm1.QuickRep1StartPage(Sender: TCustomQuickRep);
begin
  ADODataSetRptShqk.Active :=True;
end;
end.
    张庆 Email: zhangking@263.net

delphi开发学习五:QuickReoprt报表控件使用实例

报表是数据库应用程序设计中非常重要的一部分,数据库应用程序通常都要生成报表,并且打印出来。      在Delphi7.0中,默认情况下没有直接使用的QuickReport组件,使用时需先进行手工安装...
  • u011846249
  • u011846249
  • 2015年08月20日 21:46
  • 2585

delphi初学者 Fastreport报表打印用法实例

  • 2016年11月24日 19:38
  • 6.69MB
  • 下载

Delphi中如何控制打印方向,纸张大小等

 如何在程序里控制打印纸张大小(A3,A4)和打印方向?不想打开设置窗口       ---------------------------------------------------------...
  • xinzheng_wang
  • xinzheng_wang
  • 2011年04月02日 16:37
  • 5307

用 Delphi 实现报表的横向分组打印

    Delphi 内置的 QuickReport 报表系统为我们快速制作报表提供了有力的支持。对于一些简单的报表,包括纵向分组多表头报表,我们几乎不用写一句代码,就可以方便地完成报表的制作。但是对...
  • zhangking
  • zhangking
  • 2003年09月23日 01:29
  • 2528

Delphi 打印 Tprinter(1)

打印          打印对于许多 Windows 程序员来说是十分棘手的问题。         Delphi 简化了打印时用户所必须了解的大部分内容。用户可以很轻松地写出简单的打印程序来输出...
  • lailai186
  • lailai186
  • 2013年04月08日 14:35
  • 13618

用Jasper report实现横向分栏报表

Jasper或BIRT等报表工具通常只支持纵向分栏,很难实现记录横向摆放并分栏的布局,比如下面的报表。   集算器具有结构化强计算引擎,集成简单,可以协助报表工具方便地实现此类需求。...
  • u012388497
  • u012388497
  • 2015年08月04日 08:06
  • 1383

RDLC报表设置横向打印

用ReportViewer 加载 RDLC报表,若报表内容宽度超出一张A4纸的纵向宽度,那么报表靠右部分打印出来会被分割到下一页 如果用户每次打印都需设置纵向横向,这样用户会感到麻烦。 如...
  • HK_5788
  • HK_5788
  • 2016年01月16日 14:33
  • 3545

Delphi开发范例宝典目录

  • 2014年03月07日 10:24
  • 21KB
  • 下载

.NET 横向打印,自定义纸张的横向打印

C#实现自定义纸张横向打印,设置pdoc.DefaultPageSettings.Landscape为 true的同时,还需要将纸张也旋转一下才能达到横向打印的效果!!...
  • vicent_ren
  • vicent_ren
  • 2010年06月08日 18:59
  • 4323

润乾报表横竖连续打印问题

 有些情况下,比如证书、单据等,浏览报表时希望连续查看在一个页面中,但打印时因为其证书、单据等的特性导致横纵向打印是有要求的,而对于润乾报表来说定义横纵向只能对整个报表进行设置,不能对报表的不同...
  • Alice_656
  • Alice_656
  • 2017年07月24日 13:43
  • 241
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:用 Delphi 实现报表的横向分组打印
举报原因:
原因补充:

(最多只允许输入30个字)