导入/导出dBase

原创 2003年12月29日 17:30:00

从dBase文件中,导入数据到SQL数据库中,很简单,直接用下面的语句:

/*===================================================================*/
--如果接受数据导入的表已经存在
insert into 表 select * from
openrowset('MICROSOFT.JET.OLEDB.4.0'
,'dBase 5.0;DATABASE=c:/','select * from [test.dbf]')

--如果导入数据并生成表
select * into 表 from
openrowset('MICROSOFT.JET.OLEDB.4.0'
,'dBase 5.0;DATABASE=c:/','select * from [test.dbf]')


/*===================================================================*/
--如果从SQL数据库中,导出数据到dBase,如果dBase文件已经存在,就可以简单的用:
insert into
openrowset('MICROSOFT.JET.OLEDB.4.0'
,'dBase 5.0;DATABASE=c:/','select * from [test.dbf]')
select * from 表


/*--说明:
DATABASE=c:/               c:/是dbf文件的存放目录
'select * from [test.dbf]  test.dbf是指dbf文件名
--*/

 

--如果dBase文件不存在,就需要用到下面的存储过程了.


/*--数据导出dBase
 
 导出表中的数据到dBase,如果文件不存在,将自动创建文件
 基于通用性考虑,仅支持导出标准数据类型
--邹建 2003.07(引用请保留此信息)--*/

/*--调用示例

 --导出dBase
 p_exporttb @tbname='地区资料',@path='c:/',@over=0
--*/
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_exporttb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_exporttb]
GO

create proc p_exporttb
@tbname sysname,    --要导出的表名
@path nvarchar(1000),   --文件存放目录
@fname nvarchar(250)='',  --文件名,默认为表名
@over bit=0      --是否覆盖已经存在的文件,如果不覆盖,则直接追加
as
declare @err int,@src nvarchar(255),@desc nvarchar(255),@out int
declare @obj int,@constr nvarchar(1000),@sql varchar(8000),@fdlist varchar(8000)

--参数检测
if isnull(@fname,'')='' set @fname=@tbname+'.dbf'

--检查文件是否已经存在
if right(@path,1)<>'/' set @path=@path+'/'
create table #tb(a bit,b bit,c bit)
set @sql=@path+@fname
insert into #tb exec master..xp_fileexist @sql
if exists(select 1 from #tb where a=1)
 if @over=1
 begin
  set @sql='del '+@sql
  exec master..xp_cmdshell @sql,no_output
 end
 else
  set @over=0
else
 set @over=1

--数据库创建语句
set @sql=@path+@fname
set @constr='Provider=Microsoft.Jet.OLEDB.4.0;Extended Properties="dBASE 5.0;'
 +';HDR=NO;DATABASE='+@path+'"'

--连接数据库
exec @err=sp_oacreate 'adodb.connection',@obj out
if @err<>0 goto lberr

exec @err=sp_oamethod @obj,'open',null,@constr
if @err<>0 goto lberr

--创建表的SQL
select @sql='',@fdlist=''
select @fdlist=@fdlist+','+a.name
 ,@sql=@sql+',['+a.name+'] '
  +case when b.name in('char','nchar','varchar','nvarchar') then
     'text('+cast(case when a.length>250 then 250 else a.length end as varchar)+')'
   when b.name in('tynyint','int','bigint','tinyint') then 'int'
   when b.name in('smalldatetime','datetime') then 'datetime'
   when b.name in('money','smallmoney') then 'money'
   else b.name end
FROM syscolumns a left join systypes b on a.xtype=b.xusertype
where b.name not in('image','text','uniqueidentifier','sql_variant','ntext','varbinary','binary','timestamp')
 and object_id(@tbname)=id
select @sql='create table ['+@fname
 +']('+substring(@sql,2,8000)+')'
 ,@fdlist=substring(@fdlist,2,8000)

if @over=1
begin
 exec @err=sp_oamethod @obj,'execute',@out out,@sql
 if @err<>0 goto lberr
end

exec @err=sp_oadestroy @obj

set @sql='openrowset(''MICROSOFT.JET.OLEDB.4.0'',''dBase 5.0;DATABASE='
 +@path+''',''select * from ['+@fname+']'')'

--导入数据
exec('insert into '+@sql+'('+@fdlist+') select '+@fdlist+' from '+@tbname)

return

lberr:
 exec sp_oageterrorinfo 0,@src out,@desc out
lbexit:
 select cast(@err as varbinary(4)) as 错误号
  ,@src as 错误源,@desc as 错误描述
 select @sql,@constr,@fdlist

go

 

 


/*--数据导出dBase
 
 导出查询语句中的数据到dBase,如果文件不存在,将自动创建文件
 基于通用性考虑,仅支持导出标准数据类型
--邹建 2003.07(引用请保留此信息)--*/

/*--调用示例

 --导出dBase
 p_exporttb @sqlstr='select * from 地区资料',@path='c:/',@over=1
--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_exporttb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_exporttb]
GO

create proc p_exporttb
@sqlstr varchar(8000),   --要导出的查询名
@path nvarchar(1000),   --文件存放目录
@fname nvarchar(250)='temp.dbf',--文件名,默认为temp
@over bit=0      --是否覆盖已经存在的文件,如果不覆盖,则直接追加
as
declare @err int,@src nvarchar(255),@desc nvarchar(255),@out int
declare @obj int,@constr nvarchar(1000),@sql varchar(8000),@fdlist varchar(8000)

--参数检测
if isnull(@fname,'')='' set @fname='temp.dbf'

--检查文件是否已经存在
if right(@path,1)<>'/' set @path=@path+'/'
create table #tb(a bit,b bit,c bit)
set @sql=@path+@fname
insert into #tb exec master..xp_fileexist @sql
if exists(select 1 from #tb where a=1)
 if @over=1
 begin
  set @sql='del '+@sql
  exec master..xp_cmdshell @sql,no_output
 end
 else
  set @over=0
else
 set @over=1

--数据库创建语句
set @sql=@path+@fname
set @constr='Provider=Microsoft.Jet.OLEDB.4.0;Extended Properties="dBASE 5.0;'
 +';HDR=NO;DATABASE='+@path+'"'

--创建表的SQL
declare @tbname sysname
set @tbname='##tmp_'+convert(varchar(38),newid())
set @sql='select * into ['+@tbname+'] from('+@sqlstr+') a'
exec(@sql)

--连接数据库
exec @err=sp_oacreate 'adodb.connection',@obj out
if @err<>0 goto lberr

exec @err=sp_oamethod @obj,'open',null,@constr
if @err<>0 goto lberr

--创建表的SQL
select @sql='',@fdlist=''
select @fdlist=@fdlist+','+a.name
 ,@sql=@sql+',['+a.name+'] '
  +case when b.name in('char','nchar','varchar','nvarchar') then
     'text('+cast(case when a.length>250 then 250 else a.length end as varchar)+')'
   when b.name in('tynyint','int','bigint','tinyint') then 'int'
   when b.name in('smalldatetime','datetime') then 'datetime'
   when b.name in('money','smallmoney') then 'money'
   else b.name end
FROM tempdb..syscolumns a left join tempdb..systypes b on a.xtype=b.xusertype
where b.name not in('image','text','uniqueidentifier','sql_variant','ntext','varbinary','binary','timestamp')
 and a.id=(select id from tempdb..sysobjects where name=@tbname)
select @sql='create table ['+@fname
 +']('+substring(@sql,2,8000)+')'
 ,@fdlist=substring(@fdlist,2,8000)

if @over=1
begin
 exec @err=sp_oamethod @obj,'execute',@out out,@sql
 if @err<>0 goto lberr
end

exec @err=sp_oadestroy @obj

set @sql='openrowset(''MICROSOFT.JET.OLEDB.4.0'',''dBase 5.0;DATABASE='
 +@path+''',''select * from ['+@fname+']'')'

--导入数据
exec('insert into '+@sql+'('+@fdlist+') select '+@fdlist+' from ['+@tbname+']')

set @sql='drop table ['+@tbname+']'
exec(@sql)

return

lberr:
 exec sp_oageterrorinfo 0,@src out,@desc out
lbexit:
 select cast(@err as varbinary(4)) as 错误号
  ,@src as 错误源,@desc as 错误描述
 select @sql,@constr,@fdlist
go

 

导入/导出dBase

导入/导出dBase 分类: 导入与导出 2003-12-29 17:30 3239人阅读 评论(4) 收藏 举报 从dBase文件中,导入数据到SQL数据库中,很简单,...
  • xcntime
  • xcntime
  • 2012年06月28日 14:02
  • 442

DBASE数据库全集

  • 2012年09月14日 08:31
  • 1.49MB
  • 下载

数据库dbase3

  • 2012年06月28日 17:38
  • 142KB
  • 下载

MySql导入导出数据库命令

转载自:http://www.jb51.net/article/25257.htm MySQL命令行导出数据库 1,进入MySQL目录下的bin文件夹:cd MySQL中到bi...

visual dbase 5.5

  • 2014年06月14日 21:51
  • 9.21MB
  • 下载

web项目实现Excel数据导入导出

由于项目要求,需要实现一个数据库信息导出为Excel文件,并能将Excel文件中的信息导入数据库的功能,网上找了一下资料,发现大都只涉及到Excel文件的简单操作,所以特地在此分享了自己写的两个简单的...

dBase数据库引擎xdbfj21F(CrackedByUnmi)

  • 2014年03月01日 16:39
  • 363KB
  • 下载

XX水泥集团报表系统-dbase

  • 2006年02月23日 09:05
  • 869KB
  • 下载

Linux下Oracle数据导入导出方法

Oracle 11G在用EXPORT导出时,空表不能导出   11G R2中有个新特性,当表无数据时,不分配segment,以节省空间    解决方法:  一、    insert一行,再roll...
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:导入/导出dBase
举报原因:
原因补充:

(最多只允许输入30个字)