Oracle触发器

--触发器是当特定事件出现时自动执行的存储过程
--特定事件可以是执行更新的DML语句和DDL语句
--触发器不能被显式调用

--触发器的功能： 
--自动生成数据 
--自定义复杂的安全权限 
--提供审计和日志记录 
--启用复杂的业务逻辑

--Oracle触发器类型：
--行级触发器         	对DML语句影响的每一行执行一次
--语句级触发器       对每个DML语句只执行一次
--instead of 触发器   用于用户不能直接使用 DML 语句修改的视图 一般用于连接视图
--模式级触发器       DDL语句触发
--数据库级触发器    在发生打开、关闭、登录和退出数据库等系统事件时执行

--注意事项：
--不能有参数
--不能包含事务控制
--不能声明long和blob clob变量


/********************行级触发器******************/
--对DML语句影响的每一行执行一次
--例1： 
create or replace trigger trig_one
before
insert or update of sal on emp
referencing new as mynew old as myold
for each row 
when (mynew.sal<0)
begin
    :mynew.sal:=0;
    dbms_output.put_line('行级触发器触发....');
end;


--:NEW    --修改
--:OLD    --旧行
--before  after  在触发事件之前和之后
--after insert触发器不允许插入值


--条件谓词:
        --inserting
        --deleting  
        --updating
--例2： 
create table test_trig(myid number,myname varchar2(20));
create sequence seq_trig;

create or replace trigger trig_two
before
insert or update of myid  on test_trig
for each row
begin
   if inserting then
      select SEQ_TRIG.Nextval into :new.myid from dual;
   else
      raise_application_error(-20001,'MYID列不允许更新');
   end if;
end;



--*******************语句级触发器*****************
--对每个DML语句只执行一次
create or replace trigger trig_name
    before|after
    insert [or delete or update]
    on table_name
declare   .....
begin     ....
end [trigger_name];

--例： 
create or replace trigger trig_emp
before 
insert or update or  delete on emp 
declare
  v_action varchar2(20);
begin
   if inserting then
      v_action:='插入';
   elsif updating  then
      v_action:='更新';
   elsif deleting  then
      v_action:='删除';
   end if; 
   dbms_output.put_line(user||'---'||sysdate||'----执行操作'||v_action);
end;