深入探讨用位掩码代替分支(6):VB6速度测试

原创 2012年03月30日 16:53:32

  前面我们测试了C系列语言,验证了位掩码算法的确实性能不错。那么对于Basic系列语言,该算法的效率怎样呢?于是本文对此进行探讨。
  VB.Net与C#一样,也是由.Net虚拟机执行的,没有多大的测试价值。所以我决定测试VB6。

一、移植要点

  VB6的功能与C系列语言差很多。很多地方需要换另一种方法去实现,甚至不能实现。
  要点有——
1.VB6不支持控制台程序,只支持窗口程序。所以我们的测试程序得修改为窗口程序。
2.VB6不支持指针,所以依靠数组。幸好现在的操作比较简单,用数组的性能损失不大。
3.VB6没有带符号移位运算法,所以无法实现f3_sar函数。
4.VB6和C#一样不支持宏,所以得手动实现代码。虽然可以将LIMITSU_BYTE这些宏改写为函数,但函数调用开销会影响性能。于是增加了f2_negB这个测试函数来验证这一论断。
5.VB6不支持条件运算符(?:)。所以只能利用单行If语句来实现f0_if函数。
6.虽然VB6提供了IIf函数,但它是靠变体类型来传递参数的,性能十分低下。于是增加了f1_iif这个测试函数来验证这一论断。
7.VB6的Not、And、Or、Xor运算符实际上是位运算符,可用来代替C语言中的~、&、|、^。
8.VB6默认的参数传递模式时ByRef(传引用)模式。在编写函数时,最好明确写清楚参数传递模式。因为对数组元素进行操作时,ByRef会造成额外的锁定/解锁操作,影响性能。(例如将LIMITSU_BYTE的参数改为ByRef,速度会慢一些)
9.VB6不支持函数指针或委托,所以得为每一个测试函数编写代码。


二、全部代码

  全部代码——

' Win32 API
Private Declare Function timeGetTime Lib "winmm.dll" () As Long


' 数据规模
Private Const DATASIZE As Long = 16384   ' 128KB / (sizeof(signed short) * 4)

' 缓冲区
Private bufS(0 To DATASIZE * 4 - 1) As Integer    ' 源缓冲区。64位的颜色(4通道,每通道16位)
Private bufD(0 To DATASIZE * 4 - 1) As Byte   ' 目标缓冲区。32位的颜色(4通道,每通道8位)

' 用if分支做饱和处理
Private Sub f0_if(ByRef pbufD() As Byte, ByRef pbufS() As Integer, ByVal cnt As Long)
    Dim i As Long
    Dim p As Long   ' 当前位置
    p = 0
    For i = 0 To cnt - 1
        ' 分别对4个通道做饱和处理
        If pbufS(p) < 0 Then pbufD(p) = 0 Else If pbufS(p) > 255 Then pbufD(p) = 255 Else pbufD(p) = pbufS(p)
        p = p + 1
        If pbufS(p) < 0 Then pbufD(p) = 0 Else If pbufS(p) > 255 Then pbufD(p) = 255 Else pbufD(p) = pbufS(p)
        p = p + 1
        If pbufS(p) < 0 Then pbufD(p) = 0 Else If pbufS(p) > 255 Then pbufD(p) = 255 Else pbufD(p) = pbufS(p)
        p = p + 1
        If pbufS(p) < 0 Then pbufD(p) = 0 Else If pbufS(p) > 255 Then pbufD(p) = 255 Else pbufD(p) = pbufS(p)
        p = p + 1
    Next i
End Sub

' 用IIF函数做饱和处理
Private Sub f1_iif(ByRef pbufD() As Byte, ByRef pbufS() As Integer, ByVal cnt As Long)
    Dim i As Long
    Dim p As Long   ' 当前位置
    p = 0
    For i = 0 To cnt - 1
        ' 分别对4个通道做饱和处理
        pbufD(p) = IIf(pbufS(p) < 0, 0, IIf(pbufS(p) > 255, 255, pbufS(p)))
        p = p + 1
        pbufD(p) = IIf(pbufS(p) < 0, 0, IIf(pbufS(p) > 255, 255, pbufS(p)))
        p = p + 1
        pbufD(p) = IIf(pbufS(p) < 0, 0, IIf(pbufS(p) > 255, 255, pbufS(p)))
        p = p + 1
        pbufD(p) = IIf(pbufS(p) < 0, 0, IIf(pbufS(p) > 255, 255, pbufS(p)))
        p = p + 1
    Next i
End Sub

' 用位掩码做饱和处理.用求负生成掩码
Private Sub f2_neg(ByRef pbufD() As Byte, ByRef pbufS() As Integer, ByVal cnt As Long)
    Dim i As Long
    Dim p As Long   ' 当前位置
    p = 0
    For i = 0 To cnt - 1
        ' 分别对4个通道做饱和处理
        pbufD(p) = ((pbufS(p) And (pbufS(p) >= 0) Or (pbufS(p) >= 256)) And &HFF)
        p = p + 1
        pbufD(p) = ((pbufS(p) And (pbufS(p) >= 0) Or (pbufS(p) >= 256)) And &HFF)
        p = p + 1
        pbufD(p) = ((pbufS(p) And (pbufS(p) >= 0) Or (pbufS(p) >= 256)) And &HFF)
        p = p + 1
        pbufD(p) = ((pbufS(p) And (pbufS(p) >= 0) Or (pbufS(p) >= 256)) And &HFF)
        p = p + 1
    Next i
End Sub

Private Function LIMITSU_BYTE(ByVal n As Integer) As Byte
    LIMITSU_BYTE = ((n And (n >= 0) Or (n >= 256)) And &HFF)
End Function

' 调用LIMITSU_BYTE函数
Private Sub f2_negB(ByRef pbufD() As Byte, ByRef pbufS() As Integer, ByVal cnt As Long)
    Dim i As Long
    Dim p As Long   ' 当前位置
    p = 0
    For i = 0 To cnt - 1
        ' 分别对4个通道做饱和处理
        pbufD(p) = LIMITSU_BYTE(pbufS(p))
        p = p + 1
        pbufD(p) = LIMITSU_BYTE(pbufS(p))
        p = p + 1
        pbufD(p) = LIMITSU_BYTE(pbufS(p))
        p = p + 1
        pbufD(p) = LIMITSU_BYTE(pbufS(p))
        p = p + 1
    Next i
End Sub

Private Sub OutLog(ByRef s As String)
    txtOut.Text = txtOut.Text & s & Chr(13) & Chr(10)
    txtOut.Refresh
    DoEvents    ' 响应界面事件
End Sub

' 进行测试
Private Sub runTest(ByVal bFull As Boolean)
    Const MaxI As Long = 3  ' 多次测试
    Const MaxJ As Long = 4000   ' 重复运算几次延长时间,避免计时精度问题
    Dim tm0 As Long, tm1 As Long    ' 执行时 间
    Dim i As Long, j As Long
    
    ' begin
    btnTest.Enabled = False
    btnTestFull.Enabled = False
    txtOut.Text = ""
    Call OutLog("== noif:VB6 ==")
    
    ' f0_if
    For i = 1 To MaxI   ' 多次测试
        tm0 = timeGetTime()
        For j = 1 To MaxJ   ' 重复运算几次延长时间,避免计时精度问题
            Call f0_if(bufD, bufS, DATASIZE)
        Next j
        tm1 = timeGetTime() - tm0
        Call OutLog("f0_if[" & i & "]:" & Chr(9) & tm1)
    Next i
    
    ' f1_iif
    If bFull Then
        For i = 1 To MaxI   ' 多次测试
            tm0 = timeGetTime()
            For j = 1 To MaxJ   ' 重复运算几次延长时间,避免计时精度问题
                Call f1_iif(bufD, bufS, DATASIZE)
            Next j
            tm1 = timeGetTime() - tm0
            Call OutLog("f1_iif[" & i & "]:" & Chr(9) & tm1)
        Next i
    End If
    
    ' f2_neg
    For i = 1 To MaxI   ' 多次测试
        tm0 = timeGetTime()
        For j = 1 To MaxJ   ' 重复运算几次延长时间,避免计时精度问题
            Call f2_neg(bufD, bufS, DATASIZE)
        Next j
        tm1 = timeGetTime() - tm0
        Call OutLog("f2_neg[" & i & "]:" & Chr(9) & tm1)
    Next i
    
    ' f2_negB
    For i = 1 To MaxI   ' 多次测试
        tm0 = timeGetTime()
        For j = 1 To MaxJ   ' 重复运算几次延长时间,避免计时精度问题
            Call f2_negB(bufD, bufS, DATASIZE)
        Next j
        tm1 = timeGetTime() - tm0
        Call OutLog("f2_negB[" & i & "]:" & Chr(9) & tm1)
    Next i
    
    ' end
    btnTest.Enabled = True
    btnTestFull.Enabled = True
End Sub

Private Sub btnTest_Click()
    Call runTest(False)
    btnTest.SetFocus
End Sub

Private Sub btnTestFull_Click()
    Call runTest(True)
    btnTestFull.SetFocus
End Sub

Private Sub Form_Load()
    Dim i As Long
    ' 初始化
    Randomize
    For i = 0 To DATASIZE * 4 - 1
        bufS(i) = CInt(Rnd() * 512) - 128   ' 使数值在 [-128, 383] 区间
    Next i
    Exit Sub
End Sub

Private Sub Form_Resize()
    ' 是文本框自适应窗口尺寸
    Call txtOut.Move(0, txtOut.Top, Me.ScaleWidth, Me.ScaleHeight - txtOut.Top)
End Sub

Private Sub Form_Unload(Cancel As Integer)
    '
End Sub


 


三、配置与编译

3.1 配置编译优化

  步骤如下——
1.点击菜单栏 “工程”->“属性”,打开工程属性对话框。
2.点击“编译”,切换到“编译”页面。
3.点击选择“编译为本机代码”、“代码速度优化”。

4.点击“高级优化”,打开“高级优化”对话框。
5.勾选所有的复选框,点击“确定”关闭“高级优化”对话框。

6.点击“确定”关闭工程属性对话框。


3.2 获取编译器生成的汇编代码

  获取编译器生成的汇编代码有助于分析程序性能。虽然VB6集成开发环境没有提供该功能,但可以通过替换“C2.exe”来获得汇编代码。详见——
http://sunh.hosp.ncku.edu.tw/~cww/html/q00545.html
获取VB编译后的LST文件


3.3 编译

  虽然可以在开发环境中按F5运行,但它实际上是以解释方式运行的。
  应该点击菜单栏 “文件”->“发布”,生成编译后的exe。
  因现在已经用上了“C2.exe”补丁,所以在编译过程中会提醒保存lst文件。

四、测试结果

  运行编译后的“noifVB6.exe”。在32位winXP上的测试结果——

== noif:VB6 ==
f0_if[1]:	2844
f0_if[2]:	2859
f0_if[3]:	2844
f1_iif[1]:	83422
f1_iif[2]:	83453
f1_iif[3]:	83422
f2_neg[1]:	1078
f2_neg[2]:	1063
f2_neg[3]:	1078
f2_negB[1]:	2125
f2_negB[2]:	2125
f2_negB[3]:	2140


  在64位win7上的测试结果——

== noif:VB6 ==
f0_if[1]:	2839
f0_if[2]:	2824
f0_if[3]:	2839
f1_iif[1]:	90137
f1_iif[2]:	90137
f1_iif[3]:	90199
f2_neg[1]:	1061
f2_neg[2]:	1061
f2_neg[3]:	1061
f2_negB[1]:	2090
f2_negB[2]:	2090
f2_negB[3]:	2090


  硬件环境——
CPU:Intel Core i3-2310M, 2100 MHz
内存:DDR3-1066


源码下载——
http://files.cnblogs.com/zyl910/noifVB6.rar
(建议阅读编译器生成的汇编代码,位于“FrmNoifVB6.lst”)

相关文章推荐

深入探讨用位掩码代替分支(3):VC6速度测试

wuhanbingwhdx提到了数据相关也会影响流水线(http://blog.csdn.net/zyl910/article/details/1330614)。   他的说法是有一定道理的。但是,...
  • zyl910
  • zyl910
  • 2012年03月27日 15:51
  • 1274

深入探讨用位掩码代替分支(5):C#2010速度测试

前面我们测试了C语言这样纯编译型语言。那么对于像C#这样由虚拟机执行的语言,“位掩码代替分支”法是否也有效果呢?于是本文对此进行探讨。 一、移植要点   C#的语法与C语言很相像,多数代码可以直接...
  • zyl910
  • zyl910
  • 2012年03月29日 17:15
  • 1749

深入探讨用位掩码代替分支(7):MMX指令集速度测试

前面我们测试了高级语言做饱和处理的性能。其实,对于这样的大批量数据处理,使用SIMD(Single Instruction Multiple Data,单指令多数据流)技术能极大的提高性能。MMX指令...
  • zyl910
  • zyl910
  • 2012年04月09日 23:08
  • 1988

深入探讨用位掩码代替分支(8):SSE指令集速度测试

在上一篇测试了MMX指令集,这次我们来测试SSE指令集。说的更精确一点,是测试SSE2指令集。   本篇致力于解决以下问题—— 1.SSE/SSE2指令集是什么? 2.如何阅读Intel/AMD...
  • zyl910
  • zyl910
  • 2012年04月12日 22:30
  • 2348

深入探讨用位掩码代替分支(9):测试成绩总结

一、测试结果汇总   将前面的测试结果进行汇总,按照三点取中方式筛选结果,整理为表格(单位是毫秒,数值越小越好)—— 测试 f0_if f1_min f2_neg f3_s...
  • zyl910
  • zyl910
  • 2012年04月13日 17:29
  • 2660

VB6获取本机网络适配器信息(网卡名称、IP地址、子网掩码、默认网关等)

Function PrintAll_NICAdapter_information() Dim NIC_Info As String strComputer = "." Set objW...

深入探讨用位掩码代替分支(1):利用带符号移位生成掩码

几年前我写了一篇“优化分支代码——避免跳转指令堵塞流水线”(http://blog.csdn.net/zyl910/article/details/1330614)。因当时是整理笔记,有些粗略。这几年...
  • zyl910
  • zyl910
  • 2012年03月12日 17:09
  • 1711

正则表达式测试工具 for vb6

正则表达式测试工具,当然也可以做为一般数据处理工具。 下载地址:http://www.symental.com/sfw/RegTestTool.zip 有时我们经常需要对html页面源代码进行分析,所...
  • sysdzw
  • sysdzw
  • 2011年01月15日 13:41
  • 8952

测试用VB6源代码文本

  • 2012年10月10日 21:55
  • 4KB
  • 下载
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:深入探讨用位掩码代替分支(6):VB6速度测试
举报原因:
原因补充:

(最多只允许输入30个字)