关于VLOOKUP函数的用法

关于VLOOKUP函数的用法

 

“Lookup”的汉语意思是“查找”，在Excel中与“Lookup”相关的函数有三个：VLOOKUP、HLOOKUO和LOOKUP。下面介绍VLOOKUP函数的用法。

 

一、功能

在表格的首列查找指定的数据，并返回指定的数据所在行中的指定列处的数据。

 

二、语法

标准格式：

VLOOKUP(lookup_value,table_array,col_index_num , range_lookup)

 

解释：

 

VLOOKUP(‘你要检索的内容或指定单元格’,‘你要检索的范围,检索到内容时返回你检索表的第几列中的内容’, ‘真或假参数真代表查询的表已经排序，假代表没有排序’)

 

例：VLOOKUP(A2,Sheet2!$A1:$B10,2,FALSE)

 

说明：在表SHEET2中检索当前表中A2中的内容，如果检索到，就返回表SHEET2中B2中的内容，因为B2是表SHEET2中的第二列，所以 VLOOKUP的第三个参数，使用2，表示如果满足条件，就返回查询表的第二列，最后的参数FALSE表示‘假’，意思是被查询的表，没有排序，这种情况下，会从被查询的表中第一行开始，一直查询到结束。

 

三、语法解释

VLOOKUP(lookup_value,table_array,col_index_num,range_lookup)可以写为：

VLOOKUP(需在第一列中查找的数据,需要在其中查找数据的数据表,需返回某列值的列号,逻辑值True或False)

1.Lookup_value为“需在数据表第一列中查找的数据”，可以是数值、文本字符串或引用。

2.Table_array 为“需要在其中查找数据的数据表”，可以使用单元格区域或区域名称等。

⑴如果 range_lookup 为 TRUE或省略，则 table_array 的第一列中的数值必须按升序排列，否则，函数 VLOOKUP 不能返回正确的数值。

如果 range_lookup 为 FALSE，table_array 不必进行排序。

⑵Table_array 的第一列中的数值可以为文本、数字或逻辑值。若为文本时，不区分文本的大小写。

3.Col_index_num 为table_array 中待返回的匹配值的列序号。

Col_index_num 为 1 时，返回 table_array 第一列中的数值；

Col_index_num 为 2 时，返回 table_array 第二列中的数值，以此类推。

如果Col_index_num 小于 1，函数 VLOOKUP 返回错误值 #VALUE!；

如果Col_index_num 大于 table_array 的列数，函数 VLOOKUP 返回错误值 #REF!。

4.Range_lookup 为一逻辑值，指明函数 VLOOKUP 返回时是精确匹配还是近似匹配。如果为 TRUE 或省略，则返回近似匹配值，也就是说，如果找不到精确匹配值，则返回小于lookup_value 的最大数值；如果 range_value 为 FALSE，函数 VLOOKUP 将返回精确匹配值。如果找不到，则返回错误值 #N/A。

 

四、应用例子

A B C D

1 编号 姓名 工资 科室

2 2005001 周杰伦 2870 办公室

3 2005002 萧亚轩 2750 人事科

4 2005006 郑智化 2680 供应科

5 2005010 屠洪刚 2980 销售科

6 2005019 孙楠 2530 财务科

7 2005036 孟庭苇 2200 工 会

 

A列已排序（第四个参数缺省或用TRUE）

VLOOKUP(2005001,A1:D7,2,TRUE) 等于“周杰伦”

VLOOKUP(2005001,A1:D7,3,TRUE) 等于“2870”

VLOOKUP(2005001,A1:D7,4,TRUE) 等于“办公室”

VLOOKUP(2005019,A1:D7,2,TRUE) 等于“孙楠”

VLOOKUP(2005036,A1:D7,3,TRUE) 等于“2200”

VLOOKUP(2005036,A1:D7,4,TRUE) 等于“工 会”

VLOOKUP(2005036,A1:D7,4) 等于“工 会”

 

若A列没有排序，要得出正确的结果，第四个参数必须用FALAE

VLOOKUP(2005001,A1:D7,2,FALSE) 等于“周杰伦”

VLOOKUP(2005001,A1:D7,3,FALSE) 等于“2870”

VLOOKUP(2005001,A1:D7,4,FALSE) 等于“办公室”

VLOOKUP(2005019,A1:D7,2,FALSE) 等于“孙楠”

VLOOKUP(2005036,A1:D7,3,FALSE) 等于“2200”

VLOOKUP(2005036,A1:D7,4,FALSE) 等于“工 会”

 

五、关于TRUE和FALSE的应用

先举个例子，假如让你在数万条记录的表格中查找给定编号的某个人，假如编号已按由小到大的顺序排序，你会很轻松地找到这个人；假如编号没有排序，你只好从上到下一条一条地查找，很费事。

用VLOOKUP查找数据也是这样，当第一列已排序，第四个参数用TRUE（或确省），Excel会很轻松地找到数据，效率较高。当第一列没有排序，第四个参数用FALSE，Excel会从上到下一条一条地查找，效率较低。

 

笔者觉得，若要精确查找数据，由于计算机运算速度很快，可省略排序操作，直接用第四个参数用FALSE即可。

 

VLOOKUP

全部显示

全部隐藏

在表格数组的首列查找值，并由此返回表格数组当前行中其他列的值。

 

VLOOKUP 中的 V 表示垂直方向。当比较值位于需要查找的数据左边的一列时，可以使用 VLOOKUP，而不用 HLOOKUP。

 

语法

VLOOKUP(lookup_value,table_array,col_index_num,range_lookup)

 

Lookup_value 为需要在表格数组（数组：用于建立可生成多个结果或可对在行和列中排列的一组参数进行运算的单个公式。数组区域共用一个公式；数组常量是用作参数的一组常量。）第一列中查找的数值。Lookup_value 可以为数值或引用。若 lookup_value 小于 table_array 第一列中的最小值，VLOOKUP 将返回错误值 #N/A。

 

Table_array 为两列或多列数据。请使用对区域的引用或区域名称。table_array 第一列中的值是由 lookup_value 搜索的值。这些值可以是文本、数字或逻辑值。不区分大小写。

 

Col_index_num 为 table_array 中待返回的匹配值的列序号。Col_index_num 为 1 时，返回 table_array 第一列中的数值；col_index_num 为 2，返回 table_array 第二列中的数值，以此类推。如果 col_index_num ：

 

小于 1，VLOOKUP 返回错误值 #VALUE!。

大于 table_array 的列数，VLOOKUP 返回错误值 #REF!。

Range_lookup 为逻辑值，指定希望 VLOOKUP 查找精确的匹配值还是近似匹配值：

 

如果为 TRUE 或省略，则返回精确匹配值或近似匹配值。也就是说，如果找不到精确匹配值，则返回小于 lookup_value 的最大数值。

table_array 第一列中的值必须以升序排序；否则 VLOOKUP 可能无法返回正确的值。可以选择“数据”菜单上的“排序”命令，再选择“递增”，将这些值按升序排序。有关详细信息，请参阅默认排序次序。

 

如果为 FALSE，VLOOKUP 将只寻找精确匹配值。在此情况下，table_array 第一列的值不需要排序。如果 table_array 第一列中有两个或多个值与 lookup_value 匹配，则使用第一个找到的值。如果找不到精确匹配值，则返回错误值 #N/A。

说明

在 table_array 第一列中搜索文本值时，请确保 table_array 第一列中的数据没有前导空格、尾随空格、不一致的直引号（' 或 "）、弯引号（‘或“）或非打印字符。在上述情况下，VLOOKUP 可能返回不正确或意外的值。有关用于清除文本数据的函数的详细信息，请参阅文本和数据函数。

在搜索数字或日期值时，请确保 table_array 第一列中的数据未保存为文本值。否则，VLOOKUP 可能返回不正确或意外的值。有关详细信息，请参阅将保存为文本的数字转换为数字值。

如果 range_lookup 为 FALSE 且 lookup_value 为文本，则可以在 lookup_value 中使用通配符、问号 (?) 和星号 (*)。问号匹配任意单个字符；星号匹配任意字符序列。如果您要查找实际的问号或星号本身，请在该字符前键入波形符 (~)。

示例 1

本示例搜索大气特征表的“密度”列以查找“粘度”和“温度”列中对应的值。（该值是在海平面 0 摄氏度或 1 个大气压下对空气进行测定的结果。）

 

 

1

2

3

4

5

6

7

8

9

10

A B C

密度 粘度 温度

0.457 3.55 500

0.525 3.25 400

0.616 2.93 300

0.675 2.75 250

0.746 2.57 200

0.835 2.38 150

0.946 2.17 100

1.09 1.95 50

1.29 1.71 0

公式 说明（结果）

=VLOOKUP(1,A2:C10,2) 使用近似匹配搜索 A 列中的值 1，在 A 列中找到小于等于 1 的最大值 0.946，然后返回同一行中 B 列的值。(2.17)

=VLOOKUP(1,A2:C10,3,TRUE) 使用近似匹配搜索 A 列中的值 1，在 A 列中找到小于等于 1 的最大值 0.946，然后返回同一行中 C 列的值。(100)

=VLOOKUP(.7,A2:C10,3,FALSE) 使用精确匹配在 A 列中搜索值 0.7。因为 A 列中没有精确匹配的值，所以返回一个错误值。(#N/A)

=VLOOKUP(0.1,A2:C10,2,TRUE) 使用近似匹配在 A 列中搜索值 0.1。因为 0.1 小于 A 列中最小的值，所以返回一个错误值。(#N/A)

=VLOOKUP(2,A2:C10,2,TRUE) 使用近似匹配搜索 A 列中的值 2，在 A 列中找到小于等于 2 的最大值 1.29，然后返回同一行中 B 列的值。(1.71)

 

 

示例 2

本示例搜索婴幼儿用品表中的“货品 ID”列，并在“成本”和“涨幅”列中查找与之匹配的值，以计算价格和测试条件。

 

 

1

2

3

4

5

6

A B C D

货品 ID 货品 成本 涨幅

ST-340 童车 ￥145.67 30%

BI-567 围嘴 ￥3.56 40%

DI-328 尿布 ￥21.45 35%

WI-989 柔湿纸巾 ￥5.12 40%

AS-469 吸出器 ￥2.56 45%

公式 说明（结果）

= VLOOKUP("DI-328", A2:D6, 3, FALSE) * (1 + VLOOKUP("DI-328", A2:D6, 4, FALSE)) 涨幅加上成本，计算尿布的零售价。(￥28.96)

= (VLOOKUP("WI-989", A2:D6, 3, FALSE) * (1 + VLOOKUP("WI-989", A2:D6, 4, FALSE))) * (1 - 20%) 零售价减去指定折扣，计算柔湿纸巾的销售价格。(￥5.73)

= IF(VLOOKUP(A2, A2:D6, 3, FALSE) >= 20, "涨幅为 " & 100 * VLOOKUP(A2, A2:D6, 4, FALSE) &"%", "成本低于 ￥20.00") 如果某一货品的成本大于或等于￥20.00，则显示字符串“涨幅为 nn%”；否则，显示字符串“成本低于 ￥20.00”。（涨幅为 30%）

= IF(VLOOKUP(A3, A2:D6, 3, FALSE) >= 20, "涨幅为: " & 100 * VLOOKUP(A3, A2:D6, 4, FALSE) &"%", "成本为 ￥" & VLOOKUP(A3, A2:D6, 3, FALSE)) 如果某一货品的成本大于或等于 ￥20.00，则显示字符串“涨幅为 nn%”；否则，显示字符串“成本为￥n.nn”。（成本为 ￥3.56）

 

 

示例 3

本示例搜索员工表的 ID 列并查找其他列中的匹配值，以计算年龄并测试错误条件。

 

 

1

2

3

4

5

6

7

A B C D E

ID 姓氏 名字 职务 出生日期

1 李 小明 销售代表 12/8/1968

2 林 彩瑜 销售部副总 2/19/1952

3 王 志东 销售代表 8/30/1963

4 潘 金 销售代表 9/19/1958

5 林 丹 销售经理 3/4/1955

6 苏 术平 销售代表 7/2/1963

公式 说明（结果）

=INT(YEARFRAC(DATE(2004,6,30), VLOOKUP(5,A2:E7,5, FALSE), 1)) 针对 2004 财政年度，查找 ID 为 5 的员工的年龄。使用 YEARFRAC 函数，以此财政年度的结束日期减去出生日期，然后使用 INT 函数将结果以整数形式显示。(49)

=IF(ISNA(VLOOKUP(5,A2:E7,2,FALSE)) = TRUE, "未找到员工", VLOOKUP(5,A2:E7,2,FALSE)) 如果有 ID 为 5 的员工，则显示该员工的姓氏；否则，显示消息“未找到员工”。(林)

当 VLOOKUP 函数返回错误值 #NA 时，ISNA 函数返回值 TRUE。

 

=IF(ISNA(VLOOKUP(15,A3:E8,2,FALSE)) = TRUE, "未找到员工", VLOOKUP(15,A3:E8,2,FALSE)) 如果有 ID 为 15 的员工，则显示该员工的姓氏；否则，显示消息“未找到员工”。（未找到员工）

当 VLOOKUP 函数返回错误值 #NA 时，ISNA 函数返回值 TRUE。

 

=VLOOKUP(4,A2:E7,3,FALSE) & " " & VLOOKUP(4,A2:E7,2,FALSE) & "是" & VLOOKUP(4,A2:E7,4,FALSE) & "。" 对于 ID 为 4 的员工，将三个单元格的值连接为一个完整的句子。（潘金是销售代表。）

 

 

注释 上例中的第一个公式使用的是 YEARFRAC 函数。如果该函数不可用并返回错误 #NAME?，请安装和加载“分析工具库”加载宏。

 

操作方法

 

在“工具”菜单上，单击“加载宏”。

在“可用加载宏”列表中，选中“分析工具库”框，然后单击“确定”。

如有必要，请按照安装程序中的说明操作。

 

笔者觉得，若要精确查找数据，由于计算机运算速度很快，可省略排序操作，直接用第四个参数用FALSE即可。

 

转 VLookup 使用

2007-03-24 20:23

最近爱上了VLOOKUP，有人还对它进行了更新。因为它的漏洞就是只能返回重复值得第一个值。下面就详细来叙述一下吧！

VLOOKUP(lookup_value,table_array,col_index_num,range_lookup)  

Lookup_value 为需要在Table_array第一列中查找的数值。

      可以为数值、引用或文本字符串。需要注意的是类型必须与table_array第一列的类型一致。

      查找文本时，文本不区分大小写；可以使用通配符“*”、“?”。

 

Table_array 为需要在其中查找数据的数据表。

      可以使用对区域或区域名称的引用、常数数组、计算后的内存数组。

      对区域引用时，可以引用整列,excel会自动判断使用区域。

      该参数的第一列必须包含查找的内容，其它列包含需返回的内容；返回内容的列序号由下个参数指定。

 

Col_index_num 为table_array中待返回的匹配值的列序号。

      如为1时，返回table_array第一列中的数值；为2，返回table_array第二列中的数值，以此类推。

      如果col_index_num小于1，函数 VLOOKUP 返回错误值值 #VALUE!；

      如果col_index_num大于table_array的列数，函数 VLOOKUP 返回错误值 #REF!。

 

Range_lookup 为一逻辑值，指明函数VLOOKUP返回时是精确匹配还是近似匹配。     

      如果为TRUE或省略，则返回近似匹配值，也就是说，如果找不到精确匹配值，则返回小于lookup_value的最大数值；    

       近似匹配查询一般用于数值的查询，table_array的第一列必须按升序排列；否则不能返回正确的结果。   

      如果range_value为FALSE（或0），函数VLOOKUP将返回精确匹配值。    

       此时，table_array不必进行排序。如果找不到，则返回错误值#N/A；可isna检测错误后使用if判断去除错误信息。   

=====================================================================

VLOOKUP 经常会出现错误的#N/A,下面是几种可能性：

数据有空格或者数据类型不一致。

可以在lookup_value 前用TRIM（）将空格去除。

如果格式不一致，可以将数值强制转换成文本，lookup_value之后用&跟""表示的空字符串。

将文本转换成数值，lookup_value*1进行运算。

=====================================================================