查询SQL死锁

DECLARE @spid INT ,
            @bl INT ,
            @intTransactionCountOnEntry INT ,
            @intRowcount INT ,
            @intCountProperties INT ,
            @intCounter INT
        CREATE TABLE #tmp_lock_who
            (
              id INT IDENTITY(1, 1) ,
              spid SMALLINT ,
              bl SMALLINT
            )

        IF @@ERROR <> 0 
            print @@ERROR

        INSERT  INTO #tmp_lock_who
                ( spid ,
                  bl
                )
                SELECT  0 ,
                        blocked
                FROM    ( SELECT    *
                          FROM      master..sysprocesses
                          WHERE     blocked > 0
                        ) a
                WHERE   NOT EXISTS ( SELECT *
                                     FROM   ( SELECT    *
                                              FROM      master..sysprocesses
                                              WHERE     blocked > 0
                                            ) b
                                     WHERE  a.blocked = spid )
                UNION
                SELECT  spid ,
                        blocked
                FROM    master..sysprocesses
                WHERE   blocked > 0
        IF @@ERROR <> 0 
            print @@ERROR

-- 找到临时表的记录数
        SELECT  @intCountProperties = COUNT(*) ,
                @intCounter = 1
        FROM    #tmp_lock_who

        IF @@ERROR <> 0 
            print @@ERROR

        IF @intCountProperties = 0 
            SELECT  '现在没有阻塞和死锁信息' AS message
-- 循环开始
        WHILE @intCounter <= @intCountProperties 
            BEGIN
-- 取第一条记录
                SELECT  @spid = spid ,
                        @bl = bl
                FROM    #tmp_lock_who
                WHERE   id = @intCounter
                BEGIN
                    IF @spid = 0 
                        SELECT  '引起数据库慢的是: ' + CAST(@bl AS VARCHAR(10))
                                + '进程号,其执行的SQL语法如下'
                    ELSE 
                        SELECT  '进程号SPID：' + CAST(@spid AS VARCHAR(10)) + '被'
                                + '进程号SPID：' + CAST(@bl AS VARCHAR(10))
                                + '阻塞,其当前进程执行的SQL语法如下'
                    DBCC INPUTBUFFER (@bl )
                END
-- 循环指针下移
                SET @intCounter = @intCounter + 1
            END

        DROP TABLE #tmp_lock_who
        print 0

SELECT XEvent.query('(event/data/value/deadlock)[1]') AS DeadlockGraph 
FROM (
SELECT XEvent.query('.') AS XEvent 
       FROM ( SELECT CAST(target_data AS XML) AS TargetData 
              FROM sys.dm_xe_session_targets st 
                   JOIN sys.dm_xe_sessions s 
                   ON s.address = st.event_session_address 
              WHERE s.name = 'system_health' 
                    AND st.target_name = 'ring_buffer' 
              ) AS Data 
              CROSS APPLY 
                 TargetData.nodes 
                    ('RingBufferTarget/event[@name="xml_deadlock_report"]')
              AS XEventData ( XEvent ) 
) AS src