VBA 单元格基本操作 - 值的判断

YeXueQing2020

于 2020-08-05 23:21:43 发布

2871

分类专栏： EXCEL VBA

本文链接：https://blog.csdn.net/Di77HaoWenMing/article/details/107827849

版权

EXCEL VBA 专栏收录该内容

36 篇文章 29 订阅

订阅专栏

继续讲讲单元格的操作

一、提示用户输入值

Sub SetValue()
    Sheets("sheet3").Range("a1") = InputBox("输入一个数字")
End Sub

运行后就会弹出个警告框，提示用户输入内容，输入后就会在A1单元格显示了，但是也存在一个问题，就是取消后呢，原来在A1单元格的内容就会被清空。

所以改良一下，也把“输入数字这个功能再完善一下”。

Sub SetValue()
    Dim myInput As Variant
    myInput = InputBox("输入一个数字")
    If myInput <> "" Then
        If IsNumeric(myInput) Then
            Sheets("sheet3").Range("a1") = myInput
        Else
            MsgBox "输入的不是数字"
        End If
    Else
        MsgBox "输入的内容为空值"
    End If
End Sub

在判断是否是数字上，如果用WorksheetFunction.IsNumber判断可能会出错。用户在输入123后，WorksheetFunction.IsNumber仍然会识别成文本格式。经过资料查询，解释是这样的：

WorksheetFunction.IsNumber：函数中的数值参数是无法转换的。例如，大部分其他函式中其中一个数字是必要，文字值19会转换的数字19。不过，在公式中ISNUMBER（“19”）、19不会转换文字值，且IsNumber函数会传回False。

IsNumeric：如果在整个表达式被视为一个数字就为真，否则，它会传回False。如果_表达式_为日期表达式IsNumeric会传回False。

所以咱们就知道为什么IsNumeric用来判断用户输入是否数字可以，而WorksheetFunction.IsNumber不行啦。

二、在空值输入内容

在空值输入内容的第一步当然是确定空值的位置啦，运行后跳转到空值的地方进行输入。我这里主要用到昨天的Range.End(xldown)来确定下一行的空值。

Sub SetBlankValue()
    Dim rowNum As Integer
    rowNum = Range("a1").End(xlDown).Row + 1
    Range("a" & rowNum).Select
End Sub

是不是很简单啦。

三、计算选中单元格数量

MsgBox Selection.Count

框柱单元格后运行就出来了，一句话完事儿~

如果要有选择多个选区，想知道多个选取的数量，用以下方式

MsgBox Selection.Areas.Count

四、有效遍历选区

有效遍历选区一般是对选区内有值的进行遍历操作，不然大量空值存在就很浪费时间，下面是对用户框住的内容进行判断，小于0的就成黄色，大于等于0的就蓝色。

Sub BianLi()
    Dim cell As Range
    If TypeName(Selection) <> "Range" Then Exit Sub
    Application.ScreenUpdating = False
    For Each cell In Selection
        If cell.Value < 0 Then
            cell.Interior.Color = RGB(255, 255, 0)
        Else
            cell.Interior.Color = RGB(0, 255, 255)
        End If
    Next
End Sub

框选后确实变色了，但是呢如果选中整行整列的话，会比较慢，工作表有个叫UsedRange的方法，官方解释【返回一个**Range** 对象, 该对象代表指定工作表上的所用区域。】也就是咱们用了多少单元格意思。输出个已使用单元格数量试试

MsgBox (Sheets(1).UsedRange.Count)

然后我们就可以根据用户框住的区域和这个UsedRange区域进行交叉匹配，匹配到了的说明有值，需要进行运算

Sub BianLi2()
    Dim cell As Range, rng As Range
    If TypeName(Selection) <> "Range" Then Exit Sub
    Application.ScreenUpdating = False
    Set rng = Application.Intersect(Selection, ActiveSheet.UsedRange)
    For Each cell In rng
        If cell.Value < 0 Then
            cell.Interior.Color = RGB(255, 255, 0)
        Else
            cell.Interior.Color = RGB(0, 255, 255)
        End If
    Next
End Sub

结果和上图相似，但是速度会稍稍快了点，但是也带来一个问题，如果用户点了空白区域，既没有内容，也没有使用，所以可能会报错哟，所以还需要改进一下。

此刻需要用表达式。Range.specialcells(Type, Value)来区分一下，该函数返回一个Range对象, 该对象代表与指定类型和值匹配的所有单元格。第一个参数是要包含的单元格，必填；第二个参数是可选的，写上要返回哪些类型的单元格

所以咱们把有值的Range用这个函数拆成2部分，数字的，就做判断，不是数字的，就不管了

Sub BianLi3()
    Dim numCells As Range, cell As Range
    If TypeName(Selection) <> "Range" Then Exit Sub
    Application.ScreenUpdating = False
    
    'xlConstants 意思是单元格是值，xlNumbers意思就是数字
    Set numCells = Selection.SpecialCells(xlConstants, xlNumbers)
   
    For Each cell In numCells
        If cell.Value < 0 Then
            cell.Interior.Color = RGB(255, 255, 0)
        Else
            cell.Interior.Color = RGB(0, 255, 255)
        End If
    Next
End Sub