链接脚本分析

最新推荐文章于 2024-03-21 06:00:00 发布
最新推荐文章于 2024-03-21 06:00:00 发布
阅读量372 收藏 3
点赞数
分类专栏： 嵌入式学习记录

1. 概述

链接器的作用主要是对符号的解析以及将符号与地址进行绑定。要实现这个功能需要依赖链接脚本，链接脚本大多数情况下用来链接输入文件，并生成目标文件。编译器的“-T”参数就是用来指定链接脚本的。

2. 链接脚本

需要解析的链接脚本代码如程序清单 2.1所示。
程序清单 2.1 链接脚本源码

OUTPUT_FORMAT("elf32-tradlittlemips")
OUTPUT_ARCH(mips)
ENTRY(_start)
SECTIONS
{
  /* Read-only sections, merged into text segment: */
  . = 0x80100000;
  .text      : 
  {
    _ftext = . ;
    *(.text)
    *(.rodata)
    *(.rodata1)
    *(.reginfo)
    *(.init)
    *(.stub)
    /* .gnu.warning sections are handled specially by elf32.em.  */
    *(.gnu.warning)
  } =0
  _etext = .;
  PROVIDE (etext = .);
  .fini      : { *(.fini)    } =0
  .data    :
  {
    _fdata = . ;
    *(.data)
    CONSTRUCTORS
  }
  .data1   : { *(.data1) }
  .ctors         :
  {
                __CTOR_LIST__ = .;
                LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
               *(.ctors)
                LONG(0)
                __CTOR_END__ = .;
  }
  .dtors         :
  {
                __DTOR_LIST__ = .;
                LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
               *(.dtors)
                LONG(0)
                __DTOR_END__ = .;
  }
  _gp = ALIGN(16) + 0x7ff0;
  .got           :
  {
    *(.got.plt) *(.got)
   }
  /* We want the small data sections together, so single-instruction offsets
     can access them all, and initialized data all before uninitialized, so
     we can shorten the on-disk segment size.  */
  .sdata     : { *(.sdata) }
  .lit8 : { *(.lit8) }
  .lit4 : { *(.lit4) }
  _edata  =  .;
  PROVIDE (edata = .);
  __bss_start = .;
  _fbss = .;
  .sbss      : { *(.sbss) *(.scommon) }
  .bss       :
  {
   *(.dynbss)
   *(.bss)
   *(COMMON)
  }
  . = ALIGN(16);
  __bss_end = .;
  _end = .;__end = .; end = .; 
  PROVIDE (end = .);
  /* These are needed for ELF backends which have not yet been
     converted to the new style linker.  */
  .stab 0 : { *(.stab) }
  .stabstr 0 : { *(.stabstr) }
  /* DWARF debug sections.
     Symbols in the .debug DWARF section are relative to the beginning of the
     section so we begin .debug at 0.  It's not clear yet what needs to happen
     for the others.   */
  .debug          0 : { *(.debug) }
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }
  .debug_sfnames  0 : { *(.debug_sfnames) }
.line           0 : { *(.line) }
  /* These must appear regardless of  .  */
  .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
  .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
}

3. 链接脚本逐句解析

OUTPUT_FORMAT("elf32-tradlittlemips")
OUTPUT_ARCH(mips)

OUTPUT_FORMAT 和 OUTPUT_ARCH 都是 ld 脚本的保留字命令。OUTPUT_FORMAT 说明输出二进制文件的格式，OUTPUT_ARCH 说明输出文件所在平台。

ENTRY(_start)

ENTRY 命令的作用是，将后面括号中的符号值设置成入口地址。入口地址（entry point）的定义：进程执行的第一条用户空间的指令在进程地址空间中的地址。
ld 有多种方法设置进程入口地址，通常它按以下顺序设置：（编号越前, 优先级越高）
1. ld 命令行的“-e”选项；
2. 链接脚本的 ENTRY(SYMBOL) 命令；
3. 如果定义了 start 符号, 使用 start 符号值；
4. 如果存在 .text section, 使用 .text section 的第一字节的位置值；
5. 使用值 0。

SECTIONS
{

SECTIONS 命令告诉 ld 如何把输入文件的 sections 映射到输出文件的各个 section：即如何将输入 section 合为输出 section；如何把输出 section 放入程序地址空间 (VMA) 和进程地址空间 (LMA) 。其格式如下：

SECTIONS
{
….
}
/* Read-only sections, merged into text segment: */
  . = 0x80100000;

这句把定位器符号置为 0x80100000 （若不指定，则该符号的初始值为 0）。
. 是一个特殊的符号，它是定位器，即一个位置指针，指向程序地址空间内的某个位置（或某section内的偏移，前提是它在SECTIONS命令内的某section描述内），该符号只能在SECTIONS命令内使用。

.text      : 
  {
    _ftext = . ;
    *(.text)
    *(.rodata)
    *(.rodata1)
    *(.reginfo)
    *(.init)
    *(.stub)
    /* .gnu.warning sections are handled specially by elf32.em.  */
    *(.gnu.warning)
  } =0
  • 1
  • 2
  • 3

.text : 表示text段开始。
(.text) 将所有(符号代表任意输入文件)输入文件的.text section合并成一个.text section, 该section的地址由定位器符号的值指定。
} =0 表示合并时留下的空隙用 0 填充。

_etext = .;
  PROVIDE (etext = .);

_etext = .;很多变量都定义成等于这个 . 符，实际上这个符号所代表的值是在变化的，随着脚本越往后走，值越增加，根据前面填充的多少自动往后加。
PROVIDE关键字用于定义这类符号：在目标文件内被引用，但没有在任何目标文件内被定义的符号。
此时定义了一个 etext 符号，当目标文件内引用了 etext 符号，却没有定义它时，etext 符号对应的地址被定义为 .text section 之后的第一个字节的地址。

.fini : { *(.fini) } =0
含义同前文。

.data    :
  {
    _fdata = . ;
    *(.data)
    CONSTRUCTORS
  }
  .data1   : { *(.data1) }

此处代码就是用于描述数据段了。
CONSTRUCTORS 是一个保留字命令。与 c++ 内的（全局对象的）构造函数和（全局对像的）析构函数相关。

.ctors         :
  {
                __CTOR_LIST__ = .;
                LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
               *(.ctors)
                LONG(0)
                __CTOR_END__ = .;
  }
  .dtors         :
  {
                __DTOR_LIST__ = .;
                LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
               *(.dtors)
                LONG(0)
                __DTOR_END__ = .;
  }

对于支持任意section名的目标文件格式，比如COFF、ELF格式，GNU C++将全局构造和全局析构信息分别放入 .ctors section 和 .dtors section 内。
当链接器生成的目标文件格式不支持任意section名字时，比如ECOFF、XCOFF格式，链接器将通过名字来识别全局构造和全局析构，对于这些文件格式，链接器把与全局构造和全局析构的相关信息放入出现 CONSTRUCTORS 关键字的输出section内。

符号CTORS_LIST表示全局构造信息的的开始处，CTORS_END表示全局构造信息的结束处。
这两块信息的开始处是一字长的信息，表示该块信息有多少项数据，然后以值为零的一字长数据结束。
一般来说，GNU C++在函数__main内安排全局构造代码的运行，而__main函数被初始化代码（在main函数调用之前执行）调用。

_gp = ALIGN(16) + 0x7ff0;

_gp是一个重要的全局变量，用作全局引用的一个指针。

.got           :
  {
    *(.got.plt) *(.got)
   }
  /* We want the small data sections together, so single-instruction offsets
     can access them all, and initialized data all before uninitialized, so
     we can shorten the on-disk segment size.  */
  .sdata     : { *(.sdata) }
  .lit8 : { *(.lit8) }
  .lit4 : { *(.lit4) }

含义同前文。

_edata  =  .;
  PROVIDE (edata = .);

意义与前面的 etext 类似。edata 符号也较为重要。

__bss_start = .;
  _fbss = .;
  .sbss      : { *(.sbss) *(.scommon) }
  .bss       :
  {
   *(.dynbss)
   *(.bss)
   *(COMMON)
  }
  . = ALIGN(16);
  __bss_end = .;
  _end = .;__end = .; end = .; 
  PROVIDE (end = .);

此处是描述BSS段。COMMON 这个保留字的意义：
通用符号(common symbol)的输入section：在许多目标文件格式中，通用符号并没有占用一个section。链接器认为，输入文件的所有通用符号在名为COMMON的section内。上例中将所有输入文件的所有通用符号放入输出.bss section内。
上述脚本，定义了几个重要的符号：

__bss_start = .;
__bss_end = .;
_end = .;
__end = .;
end = .;

这些内容在代码中可能会用到的。

/* These are needed for ELF backends which have not yet been
     converted to the new style linker.  */
  .stab 0 : { *(.stab) }
  .stabstr 0 : { *(.stabstr) }
  /* DWARF debug sections.
     Symbols in the .debug DWARF section are relative to the beginning of the
     section so we begin .debug at 0.  It's not clear yet what needs to happen
     for the others.   */
  .debug          0 : { *(.debug) }
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }
  .debug_sfnames  0 : { *(.debug_sfnames) }
  .line           0 : { *(.line) }
  /* These must appear regardless of  .  */
  .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
  .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
}

最后这部分内容意义与上述类似，看英文注释可以明白，是新版本链接器所需要的一些内容。

4. 免责声明

内部交流文档，仅针对SylixOS平台，若发现相关错误或者建议，请及时联系文档创建者进行修订和更新。

转自： https://blog.csdn.net/PCSean/article/details/78596324
DoDoBird_cz
关注
  • 0
    点赞
  • 踩
  • 3
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
GNU+链接脚本分析
05-13
GNU 链接脚本分析，比较全面的连接脚本分析，，，，，，，，，，，，，，，，，，，，，
GNU 链接脚本分析_中文.pdf
07-23
GNU 链接脚本分析.pdf，中文说明，学习必备，欢迎下载
RISC-V GCC默认链接脚本
task_struct的博客
10-16 525
RISC-V 链接脚本
Linux链接脚本lds和C程序混合调试
u013416923的博客
04-05 691
转载自https://www.cnblogs.com/li-hao/p/4107964.html 一、 概论 每一个链接过程都由链接脚本(linker script, 一般以lds作为文件的后缀名)控制.链接脚本主要用于规定如何把输入文件内的section放入输出文件内, 并控制输出文件内各部分在程序地址空间内的布局. 但你也可以用连接命令做一些其他事情. 连接器有个默认的内置连接脚本, 可用ld –-verbose查看. 连接选项-r和-N可以影响默认的连接脚本(如何影响?). -T选项用以指定自己的链.
程序的本质之六根据实例简要说明链接脚本的语义
tanglinux
11-05 1721
操作系统：CentOS Linux release 7.7.1908 内核版本：3.10.0-1062.1.1.el7.x86_64 运行平台：x86_64 参考文献： https://sourceware.org/binutils/docs-2.27/ld/index.html 通过执行$ gcc -m32 -Wl,--verbose tanglinux.c -o tanglinu...
【嵌入式智能产品开发实战】（十一）—— 政安晨：通过ARM-Linux掌握基本技能【C语言程序的链接过程】
政安晨——致力于AI人工智能数字互动领域
03-21 895
在一个C项目的编译中，编译器以C源文件为单位，将一个个C文件翻译成对应的目标文件。生成的每一个目标文件都是由代码段、数据段、BSS段、符号表等section组成的。这些section从目标文件的零偏移地址开始按照顺序依次排放，每个段中的符号相对于零地址的偏移，其实就是每个符号的地址，这样程序中定义的变量、函数名等，都有了一个暂时的地址。 这些目标文件是不可执行的，它们需要经过链接器链接、重定位后才能运行。 链接主要分为3个过程：分段组装、符号决议和重定位。
gcc x64 环境中默认链接脚本分析之 ENTRY 标号与 _start 函数
龙瑜的博客
10-17 3251
ENTRY 标号 ENTRY(_start) ENTRY 标号指定可执行程序的入口。 对应这里便是 _start 函数，这个函数为 main 函数执行做了一些准备工作。需要说明的是对用户程序代码而言 main 函数是执行入口，但对整个 elf 可执行文件而言，_start 文件才是执行入口。 我在 嵌入式中指定程序执行入口 中有对 ENTRY 标号与程序执行入口更具体的描述，这里就不赘述了。 _start 函数从哪里来？ 我们在编码时并没有实现任何名为 _start 函数，那这个函数是从哪里来的呢？ 实
链接脚本.lds（详细）总结附实例快速掌握
Luckiers的博客
10-16 8821
链接器：把一个或多个输入文件合并成一个输出文件，输入文件是目标文件或者链接脚本文件，输出文件是目标文件（库文件）或者可执行文件，链接器从链接脚本读完一个 section 后，将定位器符号的值增加该 section 的大小。链接脚本：链接脚本的一个主要目的是描述输入文件中的各个段(数据段,代码段,堆,栈,bss)如何被映射到输出文件中,并控制输出文件的各部分在程序地址空间内的布局，地址空间包括 ROM 和 RAM。
RT-Thread-连接脚本(ENTRY)
tyustli
05-07 375
/* Entry Point * 在运行一个程序时第一个被执行到的指令称为"入口点". 你可以使用'ENTRY'连接脚本命令来设置入口点.参数是一个符号名: ENTRY(SYMBOL) * 有多种不同的方法来设置入口点.连接器会通过按顺序尝试以下的方法来设置入口点, 如果成功了,就会停止. * `-e'入口命令行选项; * 连接脚本中的`ENTRY(SYMBOL)'命令; *...
ld链接器脚本（二）
安仔的博客
09-18 1403
简单的链接器脚本命令 本部分将阐述简单的链接器脚本命令 设置入口点 第一个指令为，入口点。可以使用ENTRY链接器命令来设置入口点。他的参数为符号名。如下： ENTRY(symbol) 有几种方式设置入口点,链接器将按照如下顺序设置入口点，一旦某个步骤成功，则停止： -e 命令行选项 链接器脚本中的ENTRY命令 如果定义了start符号，则使用这个符号的值 如果存在.text section，则使用其第一个字节地址。 地址0 处理文件的命令 有几个链接器脚本命令可以用来处理文件 INCLUDE fi
Linux下链接脚本基础
05-13
linux链接脚本基础，玩嵌入式linux，不会写，不会分析链接脚本的同志看过来了！
gnu链接脚本
11-02
gnu链接脚本分析，关于ld文件的写法，代码段数据段.data .text等如何安排等，装载地址和运行地址的区别。
linux内核链接脚本
09-20
本文简单的介绍了理解内核链接脚本需要的链接器知识和链接脚本语法，从vmlinux_32.lds.S文件分析了内核image的构成，并着重讲解了使用自定义section配合链接脚本动态创建表的方法。这里或许有一些你经常看到但不了解...
自动驾驶运动规划(Motion Planning).pdf
04-26
自动驾驶运动规划(Motion Planning)问题分析
财务数据分析模型6.xlsx
04-26
Excel数据看板，Excel办公模板，Excel模板下载，Excel数据统计，数据展示
人力资源数据分析看版.xlsx
04-26
Excel数据看板，Excel办公模板，Excel模板下载，Excel数据统计，数据展示
重庆大学2011-2012(2)数字电子技术II.pdf
最新发布
04-26
重庆大学期末考试试卷，重大期末考试试题，试题及答案
随波逐流CTF编码工具 V5.6 20240424.rar
04-26
由随波逐编写开发，CTF编码工具为用户提供丰富的离线加密解密功能，还可以对字符编码进行转换，文件隐写查看，用户可以根据自己的需求来使用功能，非常实用，能够提高大家的工作效率！
利用makefile获取elf文件链接关系并生成新的链接脚本
04-24
可以通过以下步骤来利用makefile获取elf文件链接关系并生成新的链接脚本： 1. 在makefile中使用gcc命令生成目标文件，同时加入-g选项以生成调试信息。 2. 使用readelf命令来分析生成的目标文件，提取出目标文件中...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值