Flex 读取 bmp 格式的图片

Flex 读取 bmp 格式的图片

• 博客分类： 
• Flex

 

    现在要求把后台bmp格式的图片，在flash中显示。如大家所知的，Flash已经内置了对jgp,png,gif图片的支持。不知道Adobe怎么想的，为啥不支持bmp呢。唉，bmp真是个苦命的孩子啊。

     不过还好有解决方案：以二进制的形式，把图片从后台加载到前台，然后通过bmp本身的格式进行解析，解析成为Flash认识的格式（BitMapData）,然后就可以使用了哈，废话不多说了，看实例（加载24位bmp）：

AS3.0代码

Java代码  

1. package service  
2. {  
3.     import flash.display.BitmapData;  
4.     import flash.utils.ByteArray;  
5.     import flash.utils.Endian;  
6.       
7.     /** 
8.      * 读取24位的BitMap用类。<BR> 
9.      */  
10.     public class BmpReader {  
11.           
12.         /** 
13.          * 构造函数。<BR> 
14.          */  
15.         public function BmpReader(){  
16.             super();  
17.         }  
18.           
19.         /** 
20.          * 读取24位的BitMap。<BR> 
21.          */  
22.         public static function read(byteArray:ByteArray):BitmapData {  
23.             try {  
24.                 // 设置字节序  
25.                 byteArray.endian = Endian.LITTLE_ENDIAN;  
26.                   
27.                 // 读取2字节，'BM'`对用十六进制为4D42,转化为十进制为19778  
28.                 if(byteArray.readUnsignedShort() == 19778) {  
29.                       
30.                     // 跳到表示图片从头到图像数据的偏移量的字节  
31.                     byteArray.position = 10;  
32.                     var offset:int = byteArray.readInt();  
33.                     // 跳到表示图片宽和高的字节  
34.                     byteArray.position = 18;  
35.                     var imageWidth:Number = byteArray.readInt();  
36.                     var imageHeight:Number = byteArray.readInt();  
37.                     // 跳到表示图片位数的字节  
38.                     byteArray.position = 28;  
39.                     var biBitCount:int = byteArray.readUnsignedShort();  
40.                     // 本类仅处理24位bmp  
41.                     if(biBitCount != 24) {  
42.                         trace("Image Format Error");  
43.                         return null;  
44.                     }  
45.                     var bitmapData:BitmapData = new BitmapData(imageWidth, imageHeight, false, 0x00FFFFFF);  
46.                     var px:int = 0;  
47.                     var py:int = imageHeight;  
48.                     var rColor:int = 0;  
49.                     var gColor:int = 0;  
50.                     var bColor:int = 0;  
51.                     // 补齐用字节数  
52.                     var junkbyte:int= 4 - ((imageWidth * 3) % 4);  
53.                       
54.                     while(py >= 0) {  
55.                         px = 1;  
56.                         while(px <= imageWidth) {  
57.                             if(byteArray.bytesAvailable > 3) {  
58.                                 bColor = byteArray.readUnsignedByte();  
59.                                 gColor = byteArray.readUnsignedByte();  
60.                                 rColor = byteArray.readUnsignedByte();  
61.                                 bitmapData.setPixel(px-1, py-1, 256*256*rColor+256*gColor+bColor);  
62.                             }  
63.                             px++;  
64.                         }  
65.                         // 跳过格式补齐用字节  
66.                         junkByteCheck(byteArray,junkbyte);  
67.                         py--;  
68.                     }  
69.                       
70.                       
71.                 } else {  
72.                     trace("Image Format Error");  
73.                     return null;  
74.                 }  
75.             } catch (err:Error){  
76.                 trace(err.getStackTrace());  
77.             }  
78.               
79.             return bitmapData;  
80.         }  
81.           
82.         /** 
83.          * 跳过格式补齐用字节。<BR> 
84.          */  
85.         private static function junkByteCheck(byteArray:ByteArray, junkbyte:int):void {  
86.             var bavailable:int=byteArray.bytesAvailable;  
87.             if ((junkbyte>0 && junkbyte < 4) && (bavailable >= junkbyte)){  
88.                 for (var i:int; i<junkbyte; i++){  
89.                     byteArray.readUnsignedByte();  
90.                 }  
91.             }else{  
92.                 return  
93.             }  
94.         }  
95.   
96.     }  
97. }  

 Flex mxml代码

Xml代码  

1. <?xml version="1.0" encoding="utf-8"?>  
2. <mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"  
3.     layout="absolute" creationComplete="init()">  
4.     <mx:Script>  
5.         <![CDATA[ 
6.             import flash.net.URLLoader; 
7.             import flash.net.URLLoaderDataFormat; 
8.             import flash.net.URLRequest; 
9.             import flash.events.*; 
10.              
11.             import service.BmpReader; 
12.              
13.             // 加载用 
14.             private var loader:URLLoader; 
15.             // 请求用 
16.             private var request:URLRequest; 
17.              
18.             /** 
19.              * 初期化。<BR> 
20.              */  
21.             private function init():void { 
22.                 loader = new URLLoader(); 
23.                 request = new URLRequest("**.bmp"); 
24.                 loader.dataFormat = URLLoaderDataFormat.BINARY; 
25.                 loader.addEventListener(Event.COMPLETE, onCompleteHandler); 
26.                 loader.addEventListener(IOErrorEvent.IO_ERROR,onIOError); 
27.                 loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR,onSecurityError); 
28.             } 
29.              
30.             /** 
31.              * 加载图片。<BR> 
32.              */  
33.             private function load():void { 
34.                 try{ 
35.                     loader.load(request); 
36.                 } catch(error:Error) { 
37.                     trace("Request" + error); 
38.                 } 
39.             } 
40.              
41.             /** 
42.              * 加载完成后处理。<BR> 
43.              */ 
44.             private function onCompleteHandler(e:Event):void { 
45.                 trace("load Complete"); 
46.                 var byteArray:ByteArray = ByteArray(e.currentTarget.data); 
47.                 var bitMap:Bitmap = new Bitmap(BmpReader.read(byteArray)); 
48.                 bitMap.width = 400; 
49.                 bitMap.height = 300; 
50.                 image.source = bitMap; 
51.             } 
52.              
53.             /** 
54.              * 安全错误处理。<BR> 
55.              */ 
56.             private function onSecurityError(securityError: SecurityErrorEvent):void { 
57.                 trace("securityError"); 
58.             } 
59.              
60.             /** 
61.              * IO错误处理。<BR> 
62.              */ 
63.             private function onIOError(ioError: IOErrorEvent):void { 
64.                 trace("ioError"); 
65.             } 
66.              
67.         ]]>  
68.     </mx:Script>  
69.       
70.     <!-- GUI -->  
71.     <mx:Image id="image" x="10" y="10" width="400" height="300"/>  
72.     <mx:Button x="10" y="332" label="Show BMP" click="load()"/>  
73.       
74. </mx:Application>  

 对bmp格式感兴趣的朋友，可参考: http://www.umekkii.jp/data/computer/file_format/bitmap.cgi

引自：http://hanyi366.iteye.com/blog/1580748#comments