CREATE OR REPLACE PROCEDURE send_mail(
p_recipient VARCHAR2, -- 邮件接收人
p_subject VARCHAR2, -- 邮件标题
p_message VARCHAR2 -- 邮件正文
)
IS
--下面四个变量请根据实际邮件服务器进行赋值
v_mailhost VARCHAR2(30) := 'smtp.XXX.com'; --SMTP服务器地址
v_user VARCHAR2(30) := 'user'; --登录SMTP服务器的用户名
v_pass VARCHAR2(20) := 'pwd'; --登录SMTP服务器的密码
v_sender VARCHAR2(50) := 'user@XXX.com'; --发送者邮箱,一般与 ps_user 对应
v_conn UTL_SMTP. connection ; --到邮件服务器的连接
v_msg varchar2(4000); --邮件内容
BEGIN
v_conn := UTL_SMTP.open_connection(v_mailhost, 25);
UTL_SMTP.ehlo(v_conn, v_mailhost); --是用 ehlo() 而不是 helo() 函数
--否则会报:ORA-29279: SMTP 永久性错误: 503 5.5.2 Send hello first.
UTL_SMTP.command(v_conn, 'AUTH LOGIN' ); -- smtp服务器登录校验
UTL_SMTP.command(v_conn,UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_user))));
UTL_SMTP.command(v_conn,UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_pass))));
UTL_SMTP.mail(v_conn, v_sender); --设置发件人
UTL_SMTP.rcpt(v_conn, p_recipient); --设置收件人
-- 创建要发送的邮件内容 注意报头信息和邮件正文之间要空一行
v_msg := 'Date:' || TO_CHAR(SYSDATE, 'dd mon yy hh24:mi:ss' )
|| UTL_TCP.CRLF || 'From: ' || '<' || v_sender || '>'
|| UTL_TCP.CRLF || 'To: ' || '<' || p_recipient || '>'
|| UTL_TCP.CRLF || 'Subject: ' || p_subject
|| UTL_TCP.CRLF || UTL_TCP.CRLF -- 这前面是报头信息
|| p_message; -- 这个是邮件正文
UTL_SMTP.open_data(v_conn); --打开流
UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(v_msg)); --这样写标题和内容都能用中文
UTL_SMTP.close_data(v_conn); --关闭流
UTL_SMTP.quit(v_conn); --关闭连接
EXCEPTION
WHEN OTHERS THEN
DBMS_OUTPUT.put_line(DBMS_UTILITY.format_error_stack);
DBMS_OUTPUT.put_line(DBMS_UTILITY.format_call_stack);
END send_mail;
【补充】邮件内容支持HTML方式如下:
UTL_SMTP.open_data(v_conn); --打开流
UTL_SMTP.write_data(v_conn, 'From:' || v_sender || utl_tcp.CRLF);
UTL_SMTP.write_data(v_conn, 'To:' || p_recipient || utl_tcp.crlf);
UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(convert('Subject:' || p_subject || utl_tcp.CRLF, 'ZHS16GBK')));
UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(convert('Content-Type:text/html;charset=GBK' || utl_tcp.CRLF, 'ZHS16GBK')));
UTL_SMTP.write_data(v_conn, utl_tcp.CRLF);
UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(convert(p_message, 'ZHS16GBK'))); --这样写标题和内容都能用中文
UTL_SMTP.close_data(v_conn); --关闭流
UTL_SMTP.quit(v_conn); --关闭连接
利用Oracle数据库发送邮件的实例代码
PROCEDURE Send_mail_ (p_from VARCHAR2,--邮件发送人
p_fromuser VARCHAR2,--发件人昵称
p_touser VARCHAR2,--接受人昵称
p_to VARCHAR2,--邮件接收人
p_cc VARCHAR2,--邮件抄送人
p_subject VARCHAR2,--邮件标题
p_message VARCHAR2,--邮件内容
p_user VARCHAR2,--邮件验证用户
p_mailhost VARCHAR2,--邮件的服务地址
p_psd VARCHAR2 --邮件验证密码
)
IS
v_conn utl_smtp.connection; --到邮件服务器的连接
v_msg VARCHAR2(32700); --邮件内容
psrc VARCHAR2(4000);
psrc1 VARCHAR2(4000);
v_touser1 VARCHAR2(4000);
v_touser VARCHAR2(500);
v_to VARCHAR2(500);
i NUMBER := 1;
j NUMBER := 1;
m NUMBER := 1;
n NUMBER := 1;
str_error VARCHAR2(20000);
BEGIN
v_touser1 := '';
v_conn := utl_smtp.Open_connection(p_mailhost, 25);
utl_smtp.Ehlo(v_conn, p_mailhost);
-- 是用 ehlo() 而不是 helo() 函数否则会报:ORA-29279: SMTP 永久性错误: 503 5.5.2 Send hello first.
utl_smtp.Command(v_conn, 'AUTH LOGIN'); -- smtp服务器登录校验
utl_smtp.Command(v_conn,
utl_raw.Cast_to_varchar2(
utl_encode.Base64_encode(utl_raw.Cast_to_raw(p_user))));
utl_smtp.Command(v_conn, utl_raw.Cast_to_varchar2(
utl_encode.Base64_encode(utl_raw.Cast_to_raw(p_psd)
)));
utl_smtp.Mail (v_conn, '<'
|| p_from
|| '>'); --设置发件人
-- 设置收件人----------------
psrc := Rtrim(Ltrim(p_to, ';'), ';')
|| ';';
psrc1 := Rtrim(Ltrim(p_touser, ';'), ';')
|| ';';
IF Nvl(Instr(psrc, ';', j), 0) > 0 THEN
LOOP
i := Nvl(Instr(psrc, ';', j), 0);
m := Nvl(Instr(psrc1, ';', n), 0);
IF i > 0 THEN
v_to := Trim(Substr(psrc, j, i - j));
v_touser := Nvl(Trim(Substr(psrc1, n, m - n)), '1');
utl_smtp.Rcpt(v_conn, v_to); --设置收件人
IF v_touser = '1' THEN
v_touser := Trim(Substr(v_to, 1, Instr(v_to, '@') - 1));
END IF;
IF j = 1 THEN
v_touser1 := v_touser1
|| v_touser
|| '<'
|| v_to
|| '>';
ELSE
v_touser1 := v_touser1
|| ';'
|| v_touser
|| '<'
|| v_to
|| '>';
END IF;
j := i + 1;
n := m + 1;
END IF;
Exit WHEN i = 0;
END LOOP;
ELSE
utl_smtp.Rcpt(v_conn, p_to); --设置收件人
v_touser1 := v_touser1
|| p_touser
|| '<'
|| p_to
|| '>';
END IF;
-- 设置抄送人----------------
i := 1;
j := 1;
IF Nvl(p_cc, 'aa') <> 'aa' THEN
psrc := Rtrim(Ltrim(p_cc, ';'), ';')
|| ';';
IF Nvl(Instr(psrc, ';', j), 0) > 0 THEN
LOOP
i := Nvl(Instr(psrc, ';', j), 0);
IF i > 0 THEN
v_to := Trim(Substr(psrc, j, i - j));
j := i + 1;
utl_smtp.Rcpt(v_conn, v_to); --设置抄送人
END IF;
Exit WHEN i = 0;
END LOOP;
ELSE
IF Nvl(p_cc, '1') <> '1' THEN
utl_smtp.Rcpt(v_conn, p_cc); --设置抄送人
END IF;
END IF;
END IF;
-- 创建要发送的邮件内容注意报头信息和邮件正文之间要空一行
v_msg := 'Date: '
|| To_char(SYSDATE, 'dd mon yy hh24:mi:ss')
|| utl_tcp.crlf
|| 'From: '
|| p_fromuser
|| '<'
|| p_from
|| '>'
|| utl_tcp.crlf
|| 'To: '
|| v_touser1
|| utl_tcp.crlf
|| 'Cc: '
|| p_cc
|| utl_tcp.crlf
|| 'Subject: '
|| p_subject
|| utl_tcp.crlf
|| utl_tcp.crlf -- 这前面是报头信息
|| p_message; -- 这个是邮件正文
utl_smtp.Open_data(v_conn); --打开流
utl_smtp.Write_raw_data(v_conn,
utl_raw.Cast_to_raw(Convert('Content-Type:text/html;charset=utf-8'
|| v_msg, 'ZHS16GBK'
))); --这样写标题和内容都能用中文
utl_smtp.Close_data(v_conn); --关闭流
utl_smtp.Quit(v_conn); --关闭连接
EXCEPTION
WHEN OTHERS THEN
str_error := dbms_utility.format_error_stack
|| dbms_utility.format_call_stack;
dbms_output.Put_line(str_error);
END;