VB6.0设计真正实用的TreeView控件[2003-04-07· ·东方欲晓··yesky]

摘要:]在实际开发中,许多人不喜欢使用TreeView,主要是由于默认的TreeView是“只读”的,不支持添加、删除、编辑、调整节点位置等操作。本文通过一个TVEdit工程说明如何解决这些问题。

  TreeView是最灵活的Windows控件之一,它以分层的形式显示数据,允许用户随意扩展或折叠节点。鉴于实际生活中许多事物有着层次关系,如计算机里的文件夹、人事组织关系、地区从属关系等,TreeView的应用也极其广泛。但在实际开发中,许多人不喜欢使用TreeView,主要是由于默认的TreeView是“只读”的,不支持添加、删除、编辑、调整节点位置等操作。本文将通过一个TVEdit工程说明如何解决这些问题。

  TVEdit工程(图一)允许在运行时生成节点数据、编辑节点标签、通过拖放操作改变节点的位置,以及将TreeView的数据保存到XML文件或从XML文件读取。



             图一

  一、规划键击事件

  修改用户界面控件的默认行为不仅要考虑到用户如何通过鼠标访问新的控件功能,而且还要允许用户使用键盘操作。TreeView默认支持下列键击事件:

   ▲ 上下两个箭头键移动光标(变换当前被选中的节点)。

   ▲ 左右箭头键除了变换当前被选中的节点之外,兼具扩展/折叠节点功能。

   ▲ Enter键扩展或折叠节点。

  TVEdit工程不改变这些默认的键击行为。但由于TreeView默认的键击事件不允许用户编辑其内容,所以我们要另外添加几个事件:

   ▲ 按Insert键在当前选中的节点之下插入一个新的节点。如果要添加一个新的根节点,按Ctrl+Insert键。用户按下Insert键之后,控件自动进入编辑状态,再按Enter键可退出编辑状态,控件自动选中父节点,以便用户只需按一下Insert键就可以在同一父节点之下插入新节点。

   ▲ 按Space键(或鼠标停留较长时间)使当前选中的节点进入编辑状态(也许有的人更乐意用Enter键进入编辑状态,但TreeView控件已经定义了Enter键的默认行为,所以这里不再用它)。

   ▲ 按Delete键删除当前选中的节点。如果被删除的节点包含子节点,所有子节点也被同时删除。

   ▲ 用鼠标拖放节点可改变节点在TreeView分层结构中的位置。如果被拖动的节点包含子节点,所有子节点也将被移动。

 二、设计事件的句柄

  在TVEdit工程中,TreeView控件的KeyDown事件句柄处理所有涉及键击的编辑操作,它用一个Select Case块判断用户按下的键,每一个Case语句对应一个键击事件。

  当用户按下Space键,我们调用StartLabelEdit方法将节点转入编辑模式。如果被按下的是Delete键,则调用TreeView.Nodes集合的Remove方法删除当前选中的节点。对于Insert键,则用下面的代码在当前选中的节点下添加一个新节点,使新节点处于编辑模式:

Set currNode = SmartTreeView.Nodes.Add (SmartTreeView.SelectedItem, tvwChild)
currNode.Text = ""
SmartTreeView.StartLabelEdit


  如果用户按下了Ctrl+Insert键,通过下面的代码添加一个新的根节点并让它处于编辑状态:

If Shift And vbCtrlMask Then
 Set currNode = SmartTreeView.Nodes.Add()
 currNode.Selected = True
 SmartTreeView.StartLabelEdit
End If


  每一个节点必须有一个键——字符串形式的标识符。对于新添加的或编辑过的节点,我们在编辑操作结束时生成一个1到10000000之间的随机数字,加上前缀“K”,以此作为节点的键。由于Rnd()函数不保证随机数字的唯一性,所以我们使用了一个循环,如果第一次生成的键已经被使用,VB会触发一个错误,这时我们继续循环,寻找另外的键。

Dim Repeat As Boolean
Repeat = True
While Repeat
 On Error Resume Next
 SmartTreeView.SelectedItem.Key = "K" & 1 + Int(Rnd() * 10000000)
 If Err.Number = 0 Then Repeat = False
Wend


  三、拖放操作

  TreeView控件本身不支持内部节点的拖放操作,所以我们要实现OLE拖放事件的句柄。首先必须把控件的OLEDragMode属性设置成ccOLEDragAutomatic,把OLEDropMode属性设置成ccOLEDropManual。当用户开始拖动一个节点,控件触发OLEStartDrag事件:

Private Sub SmartTreeView_OLEStartDrag( _
Data As MSComctlLib.DataObject, _
AllowedEffects As Long)
 Data.Clear
 If Not Me.SmartTreeView.SelectedItem Is Nothing Then
  Data.SetData Me.SmartTreeView.SelectedItem.Key,vbCFText
 End If
End Sub


  OLEStartDrag事件句柄把Data参数设置成被拖放节点的Key属性,稍后我们可以看到这个值的用处。当用户用鼠标拖着节点移动,VB触发OLEDragOver事件,下面给出了事件句柄的代码。当用户拖着节点经过其他节点时,其他节点不会自动以高亮度颜色显示,所以我们必须将TreeView控件的DropHighlight属性设置到适当的节点,以表明鼠标当前正处在该节点的位置上。鼠标所在位置的节点可通过控件的HitTest方法获知,HitTest方法的参数是指针的坐标。

Private Sub SmartTreeView_OLEDragOver _
(Data As MSComctlLib.DataObject, Effect As Long, _
Button As Integer, Shift As Integer, x As Single, _
y As Single, State As Integer)

 With SmartTreeView
  If State = vbLeave Then
   Set .DropHighlight = Nothing
  Else
   .DropHighlight = .HitTest(x, y)
  End If
 End With
 mfX = x
 mfY = y
 If y > 0 And y < 100 Then
  m_iScrollDir = -1
  Timer1.Enabled = True
 ElseIf y > (SmartTreeView.Height - 200) And _
  y < SmartTreeView.Height Then
  m_iScrollDir = 1
  Timer1.Enabled = True
 Else
  Timer1.Enabled = False
 End If
End Sub


  拖着节点经过其他可见的节点不存在什么问题,但要把节点拖到某个当前不在控件可见区域的节点就要复杂一些。为了实现这个功能,当鼠标拖着节点到达TreeView控件的顶部或底部时,我们必须强制TreeView滚动其可见区域。TVEdit工程利用了一个每200ms触发的Timer,以便分析当前鼠标指针所处的位置。如果鼠标拖着节点到达距离TreeView控件顶部或底部100 pixel的位置,控件显示的内容就必须滚动。有关这一技术的详细说明,有兴趣的读者可参见MSDN文章Q177743。

  SmartTreeView_OLEDragOver事件句柄有几行代码用来判断是否要滚动控件以及开启Timer,但实际的滚动操作由Timer的事件句柄完成。

  当用户拖着节点到达目的地后放开鼠标键,控件触发OLEDragDrop事件,这个事件句柄要提取出被拖动的节点,并把它放在当前高亮度显示的节点之下。前面我们把被拖动节点的Key放入了事件句柄的参数Data对象,现在可以利用这个Key方便地从Notes集合得到被拖动的节点,只要把这个节点的ParentNode属性设置成当前高亮度显示的节点,就完成了移动节点(及其所有子节点)的操作。注意被拖动的节点不能放入它自己的子节点之下,因为这会形成父子节点相互引用的循环引用关系。

Private Sub SmartTreeView_OLEDragDrop( _
Data As MSComctlLib.DataObject, Effect As Long, _
Button As Integer, Shift As Integer, x As Single, _
y As Single)

 Dim strKey As String
 Dim thisNode, DragNode As Node

 Set oNode = Me.SmartTreeView.HitTest(x, y)

 If Data.GetFormat(vbCFText) Then
  strKey = Data.GetData(vbCFText)
  Set oDragNode = SmartTreeView.Nodes(strKey)
  On Error Resume Next
  Set oDragNode.Parent = oNode
  If Err.Number = 35614 Then
   MsgBox "节点不能移动到此位置:不能创建循环引用关系。"
   On Error GoTo 0
  End If
  Set SmartTreeView.DropHighlight = Nothing
 End If
End Sub

四、保存节点数据

  TreeView本身没有提供保存节点数据的Save方法,也没有从文件读取节点数据的Load方法,这些方法都要我们自己实现。保存TreeView数据最简单的形式是XML文件,因为层次型结构是XML固有的特征。我们将用MSXML组件来创建和保存XML文档,VB6默认不带这个组件,但你可以从MSDN下载。

  在VB中使用MSXML组件首先要把它加入工程:打开“工程”菜单,选择“引用”,在对话框中选中“Microsoft XML v3.0”组件。


          图二

  点击“保存”按钮,控件的当前数据将被保存为一个“扁平”XML文件(图二):每一个节点保存为一个XML元素,节点的属性作为XML元素的属性保存,节点之间的从属关系通过元素的ParentKey属性得以体现。下面是“保存”按钮点击事件句柄的代码。

Private Sub bttnSave_Click()
 Dim xmlDoc As DOMDocument30
 Set xmlDoc = New DOMDocument30

 Dim ElementNode As IXMLDOMElement
 Dim RootElementNode As IXMLDOMElement
 Set ElementNode = xmlDoc.createElement("NODES")
 Set RootElementNode = xmlDoc.appendChild(ElementNode)

 Dim TNode As Node
 Dim i As Integer
 For i = 1 To SmartTreeView.Nodes.Count
  Set TNode = SmartTreeView.Nodes(i)
  Set ElementNode = xmlDoc.createElement("NODE")
  ElementNode.setAttribute "Caption", TNode.Text
  ElementNode.setAttribute "Key", TNode.Key
  ElementNode.setAttribute "Tag", TNode.Tag
  If TNode.Parent Is Nothing Then
   ElementNode.setAttribute "ParentKey", ""
  Else
   ElementNode.setAttribute "ParentKey", TNode.Parent.Key
  End If
  RootElementNode.appendChild ElementNode
 Next
 xmlDoc.save ("C:/XMLNodes.xml")
End Sub

  bttnSave_Click事件句柄首先创建根元素,然后用一个For...Next循环遍历TreeView控件的节点集合,每次循环创建一个新的元素,提取节点的属性作为XML元素的属性。

  用“保存”按钮生成的XML文档虽然包含了重构TreeView所需的所有信息,但XML文档本身未能直观地显示出节点之间的从属关系。点击“保存(嵌套)”按钮可将TreeView的节点数据保存为另一种XML格式,如图三。


         图三

  新的嵌套XML格式更加直观地反映出节点之间的从属关系,虽然它在编程方面不一定比前面的“扁平”格式方便,但它显然更适合人阅读和理解。

  将节点数据保存为嵌套格式也同样要用到MSXML组件,但生成XML文档的过程略有变化。仔细观察嵌套XML文档的结构,可以发现它蕴含一种递归结构——节点“浙江省”同“绍兴”的关系,正如“绍兴”同“嵊州”的关系,因此,TVEdit工程用一个递归过程方便地生成了嵌套XML文档,具体的代码这里就不再说明。

  五、读取节点数据

  不论是扁平XML文档还是嵌套XML文档,读取和恢复节点数据的代码完全一样,这得感谢DOMDocument类的强大功能。“读取XML文档”按钮的Click事件句柄首先创建一个DOMDocument对象,然后读入XML文档。接着,利用getElementsByTagName依次获取各个节点,分别设置节点的各个属性,最终装配出原先保存的TreeView,如下所示:

Private Sub bttnLoad_Click()
 Dim xmlDoc As DOMDocument30
 Set xmlDoc = New DOMDocument30
 If Not xmlDoc.Load("C:/XMLNodes.xml") Then
  MsgBox "不能读取C:/XMLNodes.xml文件。"
  Exit Sub
 End If
 SmartTreeView.Nodes.Clear
 Dim iNode As Integer
 Dim newElement As IXMLDOMElement
 For iNode = 0 To xmlDoc.getElementsByTagName("NODE").length - 1
  Set newElement = xmlDoc.getElementsByTagName ("NODE").Item(iNode)
  If newElement.getAttribute("ParentKey") = "" Then
   SmartTreeView.Nodes.Add , , _
   newElement.getAttribute("Key"), _
   newElement.getAttribute("Caption")
  Else
   SmartTreeView.Nodes.Add _
   newElement.getAttribute("ParentKey"), _
   tvwChild, newElement.getAttribute("Key"),newElement.getAttribute("Caption")
  End If
 Next
End Sub

  综上所述,一个功能强大的TreeView已经制作完毕。经过改造的TreeView具有编辑、添加、删除、拖放节点的功能,更好地满足实际应用中的需求。


阅读更多

没有更多推荐了,返回首页