罗云彬win32汇编教程笔记 Win32汇编的全局变量与局部变量

Win32汇编的全局变量与局部变量

变量的值在程序运行中是需要改变的,所以它必须定义在可写的段内,如 .data和 .data?,或者在堆栈内。
按照定义的位置不同,MASM中的变量也分为全局变量和局部变量两种。


1.  全局变量的定义
全局变量的作用域是整个程序,Win32汇编的全局变量定义在 .data或 .data?段内,可以同时定义变量的类型和长度,格式是:

变量名      类型    初始值1, 初始值2,……
变量名      类型    重复数量 dup (初始值1,初始值2,……)
MASM中可以定义的变量类型相当多,具体如下:

名    称                                    表示方式      缩    写          长度(字节)
字节                                        byte              db                   1
字                                            word             dw                  2
双字(doubleword)           dword           dd                   4
三字(farword)                   fword            df                    6
四字(quadword)               qword           dq                   8
十字节BCD码(tenbyte)   tbyte              dt                   10
有符号字节(signbyte)      sbyte                                   1
有符号字(signword)         sword                                  2
有符号双字(signdword)   sdword                                4
单精度浮点数                         real4                                    4
双精度浮点数                         real8                                    8
10字节浮点数                        real10                                  10
所有使用到变量类型的情况中,只有定义全局变量的时候类型才可以用缩写

.data
wHour               dw       ?                         ;定义了一个未初始化的word类型变量,名称为wHour。
wMinute            dw      10                       ;定义了一个名为wMinute的word类型变量
_hWnd              dd       ?                         ;定义了一个双字类型的变量_hWnd
word_Buffer      dw      100 dup (1,2)    ;定义了一组字,以0001,0002,0001,0002,…的顺序在内存中重复100遍,一共是200个字
szBuffer             byte    1024 dup (?)     ;定义了一个1 024字节的缓冲区
szText                db       'Hello,world!'     ;定义了一个字符串,总共占用了12字节。两头的单引号是定界的符号,并不属于字符串中真正的内容

在byte类型变量的定义中,可以用引号定义字符串和数值定义的方法混用,假设要定义两个字符串“Hello,World! ”和“Hello again”,每个字符串后面跟回车和换行符,最后以一个0字符结尾,可以定义如下:
szText          db      'Hello,world!',0dh,0ah,'Hello again',0dh,0ah,0

 

2. 全局变量的初始化值

全局变量在定义中既可以指定初值,也可以只用问号预留空间,在 .data?段中,只能用问号预留空间,因为 .data?不能指定初始值,这里就有一个问题:
既然可以用问号预留空间,那么在实际运行的时候,这个未初始化的值是随机的还是确定的呢?
在全局变量中,这个值就是0,所以用问号指定的全局变量如果要以0为初始值的话,在程序中可以不必为它赋值。


3. 局部变量

局部变量的作用域是单个子程序,在进入子程序的时候,通过修改堆栈指针esp来预留出需要的空间,在用ret指令返回主程序之前,同样通过恢复esp丢弃这些空间,这些变量就随之无效了。
 临时变量的空间是临时分配的,所以无法定义含有初始化值的变量,对局部变量的初始化一般在子程序中由指令完成。

局部变量的初始化值就是需要手动初始化.

 

局部变量的定义
MASM用local伪指令提供了对局部变量的支持。定义的格式是:

local       变量名1[[重复数量]][:类型],变量名2[[重复数量]][:类型]……

1. local伪指令必须紧接在子程序定义的伪指令proc后、其他指令开始前,这是因为局部变量的数目必须在子程序开始的时候就确定下来,
2. 在一个local语句定义不下的时候,可以有多个local语句,语法中的数据类型不能用类型的缩写,
3. 如果要定义数据结构,可以用数据结构的名称当做类型。
4. Win32汇编默认的类型是dword,如果定义dword类型的局部变量,则类型可以省略。
5. 当定义数组的时候,可以 [] 括号括起来。
6. 不能使用定义全局变量的dup伪指令(因为局部变量没有默认的初始值, 需要手工初始化)。
7. 局部变量不能和已定义的全局变量同名。
8. 局部变量的作用域是当前的子程序,所以在不同的子程序中可以有同名的局部变量。

这里有几个定义局部变量的例子:
local      loc1[1024]:byte        ;定义了一个1 024字节长的局部变量loc1。
local      loc2                           ;定义了一个名为loc2的局部变量,类型是默认值dword
local      loc3:WNDCLASS   ;定义了一个WNDCLASS数据结构,名为loc3
下面是局部变量使用的一个典型的例子:
TestProc         proc
                 local  @loc1:dword,@loc2:word  ;定义局部变量 @loc1
                 local  @loc3:byte

                 mov    eax, @loc1
                 mov    ax, @loc2
                 mov    al, @loc3
                 ret    
TestProc         endp

这是一个名为TestProc的子程序,用local语句定义了3个变量,@loc1是dword类型,@loc2是word类型,@loc3是byte类型,在程序中分别有3句存取3个局部变量的指令,然后就返回了,
编译成可执行文件后,再把它反汇编就得到了以下指令:
:00401000 55                        push ebp
:00401001 8BEC                  mov ebp, esp
:00401003 83C4F8              add esp, FFFFFFF8
:00401006 8B45FC             mov eax, dword ptr [ebp-04]
:00401009 668B45FA         mov ax, word ptr [ebp-06]
:0040100D 8A45F9             mov al, byte ptr [ebp-07]
:00401010 C9                    leave
:00401011 C3                    ret

可以看到,反汇编后的指令比源程序多了前后两段指令,它们是:
:00401000 55                        push ebp
:00401001 8BEC                  mov ebp, esp
:00401003 83C4F8              add esp, FFFFFFF8
            …
:00401010 C9                       leave

这些就是使用局部变量所必需的指令,分别用于局部变量的准备工作和扫尾工作。执行了call指令后,CPU把返回的地址压入堆栈,再转移到子程序执行,
esp在程序的执行过程中可能随时用到,不可能用esp来随时存取局部变量,大家一定有印象,在介绍寄存器的时候提到过ebp寄存器也是以堆栈段为默认数据段的,
所以,可以用ebp做指针,于是,在初始化前,先用一句push ebp指令把原来的ebp保存起来,然后把esp的值放到ebp中,供存取局部变量做指针用,
再后面就是在堆栈中预留空间了,由于堆栈是向下增长的,所以要在esp中加一个负值,FFFFFFF8就是–8。慢着!一个dword加一个word加一个字节不是7吗,
为什么是8呢?这是因为在80386处理器中,以dword为界对齐时存取内存速度最快,所以MASM宁可浪费一个字节,执行了这3句指令后,初始化完成,
就可以进行正常的操作了,从指令中可以看出局部变量在堆栈中的位置排列,如表3.3所示。

表3.3  上例中局部变量排列的顺序
ebp偏移                内    容
ebp+4                   由call推入的返回地址
Ebp                       push ebp指令推入的原ebp值,然后新的ebp=现在的esp
ebp-4                    第一个局部变量
ebp-6                    第二个局部变量
ebp-7                    第三个局部变量
在程序退出的时候,必须把正确的esp设置回去,否则,ret指令会从堆栈中取出错误的地址返回,看程序可以发现,ebp就是正确的esp值,
因为子程序开始的时候已经有一句mov ebp,esp,所以要返回的时候只要先mov esp,ebp,然后再pop ebp,堆栈就是正确的了。

在80386指令集中有一条指令可以在一句中实现这个功能,就是leave指令,所以,编译器在ret指令之前只使用了一句leave指令。

明白了局部变量使用的原理,就很容易理解使用时的注意点:ebp寄存器是关键,它起到保存原始esp的作用,并随时用做存取局部变量的指针基址,所以在任何时刻,
不要尝试把ebp用于别的用途,否则会带来意想不到的后果。

Win32汇编中局部变量的使用方法可以解释一个很有趣的现象:在DOS汇编的时候,如果在子程序中的push指令和pop指令不配对,那么返回的时候ret指令从堆栈里得到的肯定是错误的返回地址,
程序也就死掉了。但在Win32汇编中,push指令和pop指令不配对可能在逻辑上产生错误,却不会影响子程序正常返回,原因就是在返回的时候esp不是靠相同数量的push和pop指令来保持一致的,
而是靠leave指令从保存在ebp中的原始值中取回来的,也就是说,即使把esp改得一塌糊涂也不会影响到子程序的返回,当然,“窍门”就在ebp,把ebp改掉,程序就玩完了!

 

------------罗云彬win32汇编教程 笔记

没有更多推荐了,返回首页