存储过程分页的使用

前不久专门在csdn上看了看分页的效率的问题，很多高手都提出在大数据量的情况下都不宜使用datagrid的自带的分页方法，而应该使用存储过程。使用存储过程分页，也有很多种方法，select....top.....，not .....in....等等。经过考虑最后我还是使用了select....top....这种存储过程来进行分页。我使用的存储过程源码为：(根据最下面的帖子中的一段，自己改了改，增加了根据条件获取总数这一段）

CREATE PROCEDURE GetPageRecords
    @tblName      varchar(255),     
    @fldName      varchar(255),      
    @PageSize     int = 12,          
    @PageIndex    int = 1,          
    @IsCount      bit = 0,           
    @OrderType    bit = 0,           
    @strWhere     varchar(1000) = '' 
 /*<summary>************************************************************************************************************
 名称： GetPageRecords
 功能： 获取分页数据每页的数据或者数据的总共条数
 参数：
    input: @tblName     表名
           @fldName     用于排序的字段
    @PageSize    每页显示数据条数
    @PageIndex   页码
    @IsCount     返回记录总数 ，非 0 值则返回记录总数
    @OrderType   设置排序类型，非 0 值则降序
    @strWhere    查询条件（注意：不要加 where）
   ——————————————————————————————————————————————————————————

    @strSql      主语句
    @strTmp      临时变量
    @strOrder    排序类型
 数据来源： Documents 新闻表
 制作人：杨文珺
 日期： 2004/9/21
 注：该存储过程较为通用，若想进一步提高效率，即可提供专门针对该应用的select语句取代 select *
 ************************************************************************************************************</summary>*/
AS

declare  @strSQL   varchar(2000)     -- 主语句
declare @strTmp   varchar(1000)     -- 临时变量
declare @strOrder varchar(1000)       -- 排序类型

if @OrderType != 0
begin
    set @strTmp = "<(select min"
    set @strOrder = " order by [" + @fldName +"] desc"
end
else
begin
    set @strTmp = ">(select max"
    set @strOrder = " order by [" + @fldName +"] asc"
end

set @strSQL = "select top " + str(@PageSize) + " * from ["
    + @tblName + "] where [" + @fldName + "]" + @strTmp + "(["
    + @fldName + "]) from (select top " + str((@PageIndex-1)*@PageSize) + " ["
    + @fldName + "] from [" + @tblName + "]" + @strOrder + ") as tblTmp)"
    + @strOrder

if @strWhere != ''
    set @strSQL = "select top " + str(@PageSize) + " * from ["
        + @tblName + "] where [" + @fldName + "]" + @strTmp + "(["
        + @fldName + "]) from (select top " + str((@PageIndex-1)*@PageSize) + " ["
        + @fldName + "] from [" + @tblName + "] where (" + @strWhere + ") "
        + @strOrder + ") as tblTmp) and (" + @strWhere + ") " + @strOrder

if @PageIndex = 1
begin
    set @strTmp = ""
    if @strWhere != ''
        set @strTmp = " where (" + @strWhere + ")"

    set @strSQL = "select top " + str(@PageSize) + " * from ["
        + @tblName + "]" + @strTmp + " " + @strOrder
end

if @IsCount != 0
    if @strWhere !=''
    set @strSQL = "select count(*) as Total from [" + @tblName + "]where("+@strWhere+")"
    else
    set @strSQL = "select count(*) as Total from [" + @tblName + "]"

exec (@strSQL)
GO

------------------------------------------------------------------------------------------------------------------------------相关讨论在这：http://community.csdn.net/Expert/TopicView.asp?id=3292678