在Oracle中执行动态SQL

一、使用动态游标实现

1、声明动态游标 
TYPE i_cursor_type IS REF CURSOR; 
2、声明游标变量 
my_cursor i_cursor_type; 
3、使用游标 
n_deptno:=20; 
dyn_select := ’select empno,ename from emp where deptno=’||n_deptno; 
OPEN my_cursor FOR dyn_select; 
LOOP  
  FETCH my_cursor INTO n_empno,v_ename; 
  EXIT WHEN my_cursor%NOTFOUND; 
  --用n_empno,v_ename做其它处理 
  --.... 
END LOOP; 
CLOSE my_cursor; 

 

declare 
  type i_cursor_type is ref cursor;
  my_cursor i_cursor_type;
  n_deptno number(4);
  n_empno  number(4);
  n_ename  varchar2(100);
  dyn_select varchar2(100);
 
begin
  n_deptno:=20;
  dyn_select :='select empno,ename from scott.emp where deptno='||n_deptno;
  open my_cursor for dyn_select;
  loop 
       fetch my_cursor into n_empno,n_ename;
       exit when my_cursor%NOTFOUND;
    
  end loop;
  close my_cursor;
end;

 

二、使用 EXECUTE IMMEDIATE

EXECUTE IMMEDIATE代替了以前Oracle8i中DBMS_SQL package包.它解析并马上执行动态的SQL语句或非运行时创建的PL/SQL块.动态创建和执行SQL语句性能超前，EXECUTE IMMEDIATE的目标在于减小企业费用并获得较高的性能，较之以前它相当容易编码.尽管DBMS_SQL仍然可用，但是推荐使用EXECUTE IMMEDIATE,因为它获的收益在包之上。

使用技巧

1. EXECUTE IMMEDIATE将不会提交一个DML事务执行，应该显式提交
 如果通过EXECUTE IMMEDIATE处理DML命令，那么在完成以前需要显式提交或者作为EXECUTE IMMEDIATE自己的一部分. 如果通过EXECUTE IMMEDIATE处理DDL命令,它提交所有以前改变的数据
2. 不支持返回多行的查询,这种交互将用临时表来存储记录(参照例子如下)或者用REF cursors.
3. 当执行SQL语句时，不要用分号，当执行PL/SQL块时，在其尾部用分号.
4. 在Oracle手册中，未详细覆盖这些功能。下面的例子展示了所有用到Execute immediate的可能方面.希望能给你带来方便.
5. 对于Forms开发者,当在PL/SQL 8.0.6.3.版本中，Forms 6i不能使用此功能.

EXECUTE IMMEDIATE用法例子

1. 在PL/SQL运行DDL语句 

 begin 
  execute immediate ’set role all’; 
 end; 

 
2. 给动态语句传值(USING 子句) 

 declare 
  l_depnam varchar2(20) := ’testing’; 
  l_loc    varchar2(10) := ’Dubai’; 
  begin 
  execute immediate ’insert into dept values  (:1, :2, :3)’ [Page]
    using 50, l_depnam, l_loc; 
  commit; 
 end; 

 
3. 从动态语句检索值(INTO子句) 

declare 
  l_cnt    varchar2(20); 
 begin 
  execute immediate ’select count(1) from emp’ 
    into l_cnt; 
  dbms_output.put_line(l_cnt); 
 end; 

 
4. 动态调用例程.例程中用到的绑定变量参数必须指定参数类型.黓认为IN类型,其它类型必须显式指定 
 

declare 
  l_routin   varchar2(100) := ’gen2161.get_rowcnt’; 
  l_tblnam   varchar2(20) := ’emp’; 
  l_cnt      number; 
  l_status   varchar2(200); 
 begin 
  execute immediate ’begin ’ || l_routin || ’(:2, :3, :4); end;’ 
    using in l_tblnam, out l_cnt, in out l_status; 

  if l_status != ’OK’ then 
     dbms_output.put_line(’error’); 
  end if; 
 end; 

 
5. 将返回值传递到PL/SQL记录类型;同样也可用%rowtype变量 

 declare 
  type empdtlrec is record (empno  number(4), 
                           ename  varchar2(20), 
                           deptno  number(2)); 
  empdtl empdtlrec; 
 begin 
  execute immediate ’select empno, ename, deptno ’ || 
                   ’from emp where empno = 7934’ 
    into empdtl; 
 end; 

 
6. 传递并检索值.INTO子句用在USING子句前

 declare 
  l_dept    pls_integer := 20; 
  l_nam     varchar2(20); 
  l_loc     varchar2(20); 
 begin 
  execute immediate ’select dname, loc from dept where deptno = :1’ 
    into l_nam, l_loc  using l_dept ; 
 end; 

 7. 多行查询选项.对此选项用insert语句填充临时表，用临时表进行进一步的处理,也可以用REF cursors纠正此缺憾.

declare 
  l_sal   pls_integer := 2000; 
 begin 
  execute immediate ’insert into temp(empno, ename) ’ || 
                   ’          select empno, ename from emp ’ || 
                   ’          where  sal > :1’ 
    using l_sal; 
  commit; 
 end; 

 
三、使用DBMS_SQL包

　使用DBMS_SQL包实现动态SQL的步骤如下：A、先将要执行的SQL语句或一个语句块放到一个字符串变量中。B、使用DBMS_SQL包的parse过程来分析该字符串。C、使用DBMS_SQL包的bind_variable过程来绑定变量。D、使用DBMS_SQL包的execute函数来执行语句

1、使用DBMS_SQL包执行DDL语句

create or replace procedure proc_dbms_sql
(
table_name in varchar2, --表名
field_name1 in varchar2, --字段名
datatype1 in varchar2, --字段类型
field_name2 in varchar2, --字段名
datatype2 in varchar2 --字段类型
)as
v_cursor number; --定义光标
v_string varchar2(200); --定义字符串变量
v_row number; --行数
begin
v_cursor:=dbms_sql.open_cursor; --为处理打开光标
v_string:=’create table ’||table_name||’(’||field_name1||’ ’||datatype1||’,’||field_name2||’ ’||datatype2||’)’;
dbms_sql.parse(v_cursor,v_string,dbms_sql.native); --分析语句
v_row:=dbms_sql.execute(v_cursor); --执行语句
dbms_sql.close_cursor(v_cursor); --关闭光标
exception
when others then
dbms_sql.close_cursor(v_cursor); --关闭光标
raise;
end;

 2、使用DBMS_SQL包执行DML语句

create or replace procedure proc_dbms_sql_update
(
id number,
name varchar2
)as
v_cursor number; --定义光标
v_string varchar2(200); --字符串变量
v_row number; --行数
begin
v_cursor:=dbms_sql.open_cursor; --为处理打开光标
v_string:=’update dinya_test2 a set a.name=:p_name where a.id=:p_id’;
dbms_sql.parse(v_cursor,v_string,dbms_sql.native); --分析语句
dbms_sql.bind_variable(v_cursor,’:p_name’,name); --绑定变量
dbms_sql.bind_variable(v_cursor,’:p_id’,id); --绑定变量
v_row:=dbms_sql.execute(v_cursor);　　　　　　　　　　　--执行动态ＳＱＬ
dbms_sql.close_cursor(v_cursor); --关闭光标
exception
when others then
dbms_sql.close_cursor(v_cursor); --关闭光标
raise;
end;

 使用DBMS_SQL中，如果要执行的动态语句不是查询语句，使用DBMS_SQL.Execute或DBMS_SQL.Variable_Value来执行，如果要执行动态语句是查询语句，则要使用DBMS_SQL.define_column定义输出变量，然后使用DBMS_SQL.Execute, DBMS_SQL.Fetch_Rows, DBMS_SQL.Column_Value及DBMS_SQL.Variable_Value来执行查询并得到结果。