PX4飞控学习（二）

最新推荐文章于 2024-08-06 23:15:00 发布
Orbz
最新推荐文章于 2024-08-06 23:15:00 发布
阅读量1.7k
点赞数 1
分类专栏： px4飞控
px4飞控专栏收录该内容
4 篇文章 2 订阅
订阅专栏
CMakeList.txt
############################################################################

# 首先判断cmake版本

if (${CMAKE_VERSION} VERSION_LESS 3.1.0)
    message("Not a valid CMake version")
    message("On Ubuntu >= 16.04, install or upgrade via:")
    message("   sudo apt-get install cmake")
    message("")
    message("Official website: https://cmake.org/download/")
    message(FATAL_ERROR "Update CMake and try again" )
endif()

# Warning: Changing this modifies CMake's internal workings
# and leads to wrong toolchain detection
cmake_minimum_required(VERSION 3.1 FATAL_ERROR)

set(PX4_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
set(PX4_BINARY_DIR "${CMAKE_CURRENT_BINARY_DIR}")

execute_process(
    COMMAND Tools/check_submodules.sh
    WORKING_DIRECTORY ${PX4_SOURCE_DIR}
    )

#=============================================================================
# 设置
#
# 项目开始所需设置的参数

set(CONFIG "nuttx_px4fmu-v2_default" CACHE STRING "desired configuration")

# CONFIG 赋值 "nuttx_px4fmu-v2_default"

string(REPLACE "_" ";" config_args ${CONFIG})
list(GET config_args 0 OS)
list(GET config_args 1 BOARD)
list(GET config_args 2 LABEL)
set(target_name "${OS}-${BOARD}-${LABEL}")

#OS赋值nuttx  BOARD赋值px4fmu-v2 LABEL赋值default

file(GLOB_RECURSE configs RELATIVE cmake/configs "cmake/configs/*.cmake")

#cmake/configs 目录下的 *.cmake文件

set_property(CACHE CONFIG PROPERTY STRINGS ${configs})

set(THREADS "4" CACHE STRING "number of threads to use for external build processes")
set(DEBUG_PORT "/dev/ttyACM0" CACHE STRING "debugging port")
set(EXTERNAL_MODULES_LOCATION "" CACHE STRING "External modules source location")

if (NOT EXTERNAL_MODULES_LOCATION STREQUAL "")
    get_filename_component(EXTERNAL_MODULES_LOCATION "${EXTERNAL_MODULES_LOCATION}" ABSOLUTE)
endif()

list(APPEND CMAKE_MODULE_PATH "${PX4_SOURCE_DIR}/cmake")
message(STATUS "CMAKE_MODULE_PATH: ${CMAKE_MODULE_PATH}")
set(config_module "configs/${CONFIG}")
include(${config_module})

include(common/coverage)
include(common/sanitizers)

# CMake build type
# Debug Release RelWithDebInfo MinSizeRel Coverage
if (NOT CMAKE_BUILD_TYPE)
    if (${OS} STREQUAL "nuttx")
        set(PX4_BUILD_TYPE "MinSizeRel")
    elseif (${OS} STREQUAL "bebop")
        set(PX4_BUILD_TYPE "MinSizeRel")
    else()
        set(PX4_BUILD_TYPE "RelWithDebInfo")
    endif()

    set(CMAKE_BUILD_TYPE ${PX4_BUILD_TYPE} CACHE STRING "Build type" FORCE)
endif()

set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug;Release;RelWithDebInfo;MinSizeRel;Coverage")

message(STATUS "Build Type: ${CMAKE_BUILD_TYPE}")


#=============================================================================
# git
#
include(common/px4_git)

execute_process(
    COMMAND git describe --always --tags
    OUTPUT_VARIABLE git_tag
    OUTPUT_STRIP_TRAILING_WHITESPACE
    WORKING_DIRECTORY ${PX4_SOURCE_DIR}
    )

execute_process(
    COMMAND Tools/tag_to_version.py --root ${PX4_SOURCE_DIR}
    OUTPUT_VARIABLE git_version
    WORKING_DIRECTORY ${PX4_SOURCE_DIR}
    )

px4_add_git_submodule(TARGET git_cmake_hexagon PATH "cmake/cmake_hexagon")
px4_add_git_submodule(TARGET git_driverframework PATH "src/lib/DriverFramework")
px4_add_git_submodule(TARGET git_ecl PATH "src/lib/ecl")
px4_add_git_submodule(TARGET git_gazebo PATH "Tools/sitl_gazebo")
px4_add_git_submodule(TARGET git_gazebo_flow PATH "Tools/sitl_gazebo/external/OpticalFlow")
px4_add_git_submodule(TARGET git_gazebo_klt PATH "Tools/sitl_gazebo/external/OpticalFlow/external/klt_feature_tracker")
px4_add_git_submodule(TARGET git_gencpp PATH "Tools/gencpp")
# 消息生成
px4_add_git_submodule(TARGET git_genmsg PATH "Tools/genmsg")
# GPS驱动
px4_add_git_submodule(TARGET git_gps_devices PATH "src/drivers/gps/devices")
# jMAVSim模拟器
px4_add_git_submodule(TARGET git_jmavsim PATH "Tools/jMAVSim")
# 矩阵
px4_add_git_submodule(TARGET git_matrix PATH "src/lib/matrix")

#mavlink 1.0 2.0
px4_add_git_submodule(TARGET git_mavlink PATH "mavlink/include/mavlink/v1.0")
px4_add_git_submodule(TARGET git_mavlink2 PATH "mavlink/include/mavlink/v2.0")

#nuttx操作系统
px4_add_git_submodule(TARGET git_nuttx PATH "NuttX")
#uavcan驱动
px4_add_git_submodule(TARGET git_uavcan PATH "src/modules/uavcan/libuavcan")
px4_add_git_submodule(TARGET git_micro_cdr PATH "src/lib/micro-CDR")

px4_create_git_hash_header()

#=============================================================================

message(STATUS "PX4 VERSION: ${git_tag}")
message(STATUS "CONFIG: ${target_name}")

# The URL for the elf file for crash logging
if (DEFINED ENV{BUILD_URI})
    set(BUILD_URI $ENV{BUILD_URI})
else()
    set(BUILD_URI "localhost")
endif()

add_definitions(-DBUILD_URI=${BUILD_URI})

# Define GNU standard installation directories
include(GNUInstallDirs)

# Add support for external project building
include(ExternalProject)

# Setup install paths
if (NOT CMAKE_INSTALL_PREFIX)
    if (${OS} STREQUAL "posix")
        set(CMAKE_INSTALL_PREFIX "/usr" CACHE PATH "Install path prefix" FORCE)
    endif()
endif()
if (CMAKE_INSTALL_PREFIX)
    message(STATUS "CMAKE_INSTALL_PREFIX: ${CMAKE_INSTALL_PREFIX}")
endif()

#=============================================================================
# require px4 module interface px4模块接口
set(px4_required_interface
    px4_os_prebuild_targets
    px4_os_add_flags
    )
foreach(cmd ${px4_required_interface})
    if (NOT COMMAND ${cmd})
        message(FATAL_ERROR "${config_module} must implement ${cmd}")
    endif()
endforeach()

set(px4_required_config config_module_list)
foreach(conf ${px4_required_config})
    if (NOT DEFINED ${conf})
        message(FATAL_ERROR "cmake/${config_module} must define ${conf}")
    endif()
endforeach()

# force static lib build
set(BUILD_SHARED_LIBS OFF)

#=============================================================================
# ccache
#
option(CCACHE "Use ccache if available" OFF)
find_program(CCACHE_PROGRAM ccache)
if (CCACHE AND CCACHE_PROGRAM)
    message(STATUS "Enabled ccache: ${CCACHE_PROGRAM}")
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

#=============================================================================
# project definition
#
project(px4 CXX C ASM)

set(package-contact "px4users@googlegroups.com")

#=============================================================================
# find programs and packages
#

# see if catkin was invoked to build this
if (CATKIN_DEVEL_PREFIX)
    message(STATUS "catkin ENABLED")
    find_package(catkin REQUIRED)
    if (catkin_FOUND)
        catkin_package()
    else()
        message(FATAL_ERROR "catkin not found")
    endif()
endif()

find_package(PythonInterp REQUIRED)
px4_find_python_module(jinja2 REQUIRED)

#=============================================================================
# cmake testing
#
enable_testing()
include(CTest)

#=============================================================================
# generate compile command database
#
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

#=============================================================================
# check required toolchain variables
#

# PX4 requires c++11
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

# PX4 requires c99
set(CMAKE_C_STANDARD 99)
set(CMAKE_C_STANDARD_REQUIRED ON)

set(required_variables CMAKE_C_COMPILER_ID CMAKE_CXX_COMPILER_ID)
foreach(var ${required_variables})
    if (NOT ${var})
        message(FATAL_ERROR "Toolchain/config must define ${var}")
    endif()
endforeach()

# print full c compiler version
execute_process(COMMAND ${CMAKE_C_COMPILER} --version
        OUTPUT_VARIABLE c_compiler_version
        OUTPUT_STRIP_TRAILING_WHITESPACE
        )
STRING(REGEX MATCH "[^\n]*" c_compiler_version_short ${c_compiler_version})
message(STATUS "C compiler: ${c_compiler_version_short}")

# print full c++ compiler version
execute_process(COMMAND ${CMAKE_CXX_COMPILER} --version
        OUTPUT_VARIABLE cxx_compiler_version
        OUTPUT_STRIP_TRAILING_WHITESPACE
        )
STRING(REGEX MATCH "[^\n]*" cxx_compiler_version_short ${cxx_compiler_version})
message(STATUS "C++ compiler: ${cxx_compiler_version_short}")

#=============================================================================
# external libraries
# 这里生成nuttx系统 
px4_os_prebuild_targets(OUT prebuild_targets
    BOARD ${BOARD}
    THREADS ${THREADS})

#=============================================================================
# build flags
# 针对不同芯片产生的编译参数 
px4_os_add_flags(
    BOARD ${BOARD}
    C_FLAGS c_flags
    CXX_FLAGS cxx_flags
    OPTIMIZATION_FLAGS optimization_flags
    EXE_LINKER_FLAGS exe_linker_flags
    INCLUDE_DIRS include_dirs
    LINK_DIRS link_dirs
    DEFINITIONS definitions)

px4_join(OUT CMAKE_EXE_LINKER_FLAGS LIST "${exe_linker_flags}" GLUE " ")
px4_join(OUT CMAKE_C_FLAGS LIST "${c_flags};${optimization_flags}" GLUE " ")
px4_join(OUT CMAKE_CXX_FLAGS LIST "${cxx_flags};${optimization_flags}" GLUE " ")

include_directories(${include_dirs})
#message("INCLUDE_DIRS=${include_dirs}")
link_directories(${link_dirs})
add_definitions(${definitions})

#=============================================================================
# message, and airframe generation
# 消息产生 uorb 消息总线上的消息

include(common/px4_metadata)

add_subdirectory(msg)
px4_generate_messages(TARGET msg_gen
    MSG_FILES ${msg_files}
    OS ${OS}
    INCLUDES ${msg_include_paths}
    DEPENDS git_genmsg git_gencpp git_micro_cdr prebuild_targets
    )
include_directories("${PX4_SOURCE_DIR}/src/lib/micro-CDR/include"
                    "${PX4_BINARY_DIR}/src/lib/micro-CDR/include/microcdr")

px4_generate_airframes_xml(BOARD ${BOARD})

#=============================================================================
# DriverFramework
# 驱动框架

# List the DriverFramework drivers
if (DEFINED config_df_driver_list)
    message("DF Drivers: ${config_df_driver_list}")
endif()

set(df_driver_libs)
foreach(driver ${config_df_driver_list})
    add_subdirectory(src/lib/DriverFramework/drivers/${driver})
    list(APPEND df_driver_libs df_${driver})
    message("Adding DF driver: ${driver}")
endforeach()

#=============================================================================
# external projects
# 外部项目 

set(ep_base ${PX4_BINARY_DIR}/external)
set_property(DIRECTORY PROPERTY EP_BASE ${ep_base})

# add external project install folders to build
link_directories(${ep_base}/Install/lib)
include_directories(${ep_base}/Install/include)
# add the directories so cmake won't warn
execute_process(COMMAND cmake -E make_directory ${ep_base}/Install/lib)
execute_process(COMMAND cmake -E make_directory ${ep_base}/Install/include)

#=============================================================================
# external modules
# 外部模块 在*.cmake文件中定义 config_module_list_external config_module_list变量
if (NOT EXTERNAL_MODULES_LOCATION STREQUAL "")
    message(STATUS "External modules: ${EXTERNAL_MODULES_LOCATION}")
    add_subdirectory("${EXTERNAL_MODULES_LOCATION}/src" external_modules_src)

    set(config_module_list_external_expanded)
    foreach(external_module ${config_module_list_external})
        list(APPEND config_module_list_external_expanded
            ${EXTERNAL_MODULES_LOCATION}/src/${external_module})
    endforeach()
    set(config_module_list
        ${config_module_list}
        ${config_module_list_external_expanded}
        )
endif()

#=============================================================================
# subdirectories
# 子目录 IO板固件
set(module_libraries)
foreach(module ${config_module_list})
    string(REGEX MATCH "^[./]" external_module ${module})
    if (external_module)
        STRING(REGEX REPLACE "//" "/" EXT_MODULE ${module})
        STRING(REGEX REPLACE "/" "__" EXT_MODULE_PREFIX ${EXT_MODULE})
        add_subdirectory(${module} ${PX4_BINARY_DIR}/${EXT_MODULE_PREFIX})
    else()
        add_subdirectory(src/${module})
    endif()
    px4_mangle_name(${module} mangled_name)
    list(APPEND module_libraries ${mangled_name})
endforeach()

# Keep track of external shared libs required for modules
set(module_external_libraries "${module_external_libraries}" CACHE INTERNAL "module_external_libraries")

add_subdirectory(src/firmware/${OS})

# config_io_board参数存在，进入px4iofirmware目录生成io板固件

if (config_io_board)
    add_subdirectory(src/modules/px4iofirmware)
endif()

#=============================================================================
# generate custom target to print for all executable and module cmake targets
#
if (all_posix_cmake_targets)
    list(SORT all_posix_cmake_targets)
    px4_join(OUT posix_cmake_target_list LIST ${all_posix_cmake_targets} GLUE "\\n")
    add_custom_target(list_cmake_targets
        COMMAND sh -c "printf \"${posix_cmake_target_list}\\n\""
        COMMENT "List of cmake targets that can be matched by PX4_NO_OPTIMIZATION:"
        VERBATIM
        )
endif()

#=============================================================================
# packaging
# 固件打包
# Important to having packaging at end of cmake file.
#
set(CPACK_PACKAGE_NAME ${PROJECT_NAME}-${CONFIG})
set(CPACK_PACKAGE_VERSION ${git_version})
set(CPACK_PACKAGE_CONTACT ${package-contact})
set(CPACK_DEBIAN_PACKAGE_SHLIBDEPS ON)
set(CPACK_DEBIAN_PACKAGE_SECTION "devel")
set(CPACK_DEBIAN_PACKAGE_PRIORITY "optional")
set(short-description "The px4 autopilot.")
set(CPACK_DEBIAN_PACKAGE_DESCRIPTION ${short-description})
set(CPACK_GENERATOR "ZIP")
set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${CONFIG}-${git_tag}")
set(CPACK_SOURCE_PACKAGE_FILE_NAME "${PROJECT_NAME}-${git_version}")
set(CPACK_SOURCE_GENERATOR "ZIP;TBZ2")
set(CPACK_PACKAGING_INSTALL_PREFIX "")
set(CPACK_SET_DESTDIR "OFF")
if ("${CMAKE_SYSTEM}" MATCHES "Linux")
    find_program(DPKG_PROGRAM dpkg)
    if (EXISTS ${DPKG_PROGRAM})
        list (APPEND CPACK_GENERATOR "DEB")
    endif()
endif()
include(CPack)

# vim: set noet fenc=utf-8 ff=unix ft=cmake :