网卡IP配置脚本

@echo off
:main
cls
echo =============IP配置脚本=============
echo.
echo 1.将IP设置为公司用的IP 请按 1
echo 2.将IP设置为自动获取 请按 2
echo 3.查看当前IP设置 请按 3
echo 4.退出 请按 4
echo.
set NIC="本地连接 2"
set /p choice=请选择您的操作：

echo.
if "%choice%"=="1" goto stcip
if "%choice%"=="2" goto dycip
if "%choice%"=="3" goto lookip
if "%choice%"=="4" goto end

goto main

:stcip
rem ****************************************************
rem IP配置脚本
rem NIC是网络连接名，一般为"本地连接"或"本地连接 2"等
rem IP是网卡ip地址，GW是默认网关
rem MASK是子网掩码
rem DNS1和DNS2分别是首选和备用DNS服务器
rem ****************************************************
set IP="192.168.1.199"
set GW="192.168.1.1"
set MASK="255.255.255.0"
set DNS1="218.2.135.1"
set DNS2="61.147.37.1"
echo --------------------------------
echo 下面将把网卡%NIC%设为如下地址：        
echo IP地址:          %IP%
echo 子网掩码:        %MASK%
echo 默认网关:        %GW%
echo 首选DNS服务器：  %DNS1%
echo 备用DNS服务器:    %DNS2%
echo --------------------------------
echo 用恒网IP开始设置网卡，请稍等数秒......
netsh interface ip set address %NIC% static %IP% %MASK% %GW% 1
echo 开始设置DNS......
netsh interface ip set dns %NIC% static %DNS1% primary
echo 开始设置备用DNS......
netsh interface ip add dns %NIC% %DNS2%
echo 设置完毕!

CHOICE /C YN /M "退出请按 Y，返回菜单请按 N。" 
if errorlevel 2 goto main
if errorlevel 1 goto end 

:dycip
echo 将网卡设为DHCP自动获取IP
echo 开始设置网卡，请稍等数秒......
netsh interface ip set address %NIC% source = dhcp
netsh interface ip set dns %NIC% source = dhcp 
echo 设置完毕!
CHOICE /C YN /M "退出请按 Y，返回菜单请按 N。" 
if errorlevel 2 goto main
if errorlevel 1 goto end 

:lookip
echo 查看网卡参数
ipconfig /all
CHOICE /C YN /M "退出请按 Y，返回菜单请按 N。" 
if errorlevel 2 goto main
if errorlevel 1 goto end 

:end

原文链接： http://blog.csdn.net/vince6799/article/details/3790156

转载于:https://my.oschina.net/chen106106/blog/45865