Delphi防止同时出现多个应用程序实例--CreateMutex

文章转载处： http://hi.baidu.com/lingyin55/blog/item/f07a897a99cbeae92e73b383.html 

 

 

多实例指同时有同一个应用程序的多个副本在运行。同一个应用程序的多个副本可以相互独立地同时运行，是Win32操作系统提供的一个功能。但有时，我们可能希望用户启动应用程序后就不再启动它的别的副本。比如某种设备资源的控制程序，像调制解调器和并行端口。这种情况下，用程序代码防止同时出现多个程序的副本在运行是非常必要的。[separator]
　　在16位的Windows中，要防止出现多个实例是很简单的，因为系统变量hPrevInst可以被用来判断是否有其他的实例存在。当hPrevInst变量不为0时，表示已经有别的应用程序实例在运行。
　　然而，在Win32系统中每个进程之间有R32绝缘层来彼此隔绝。因此，在Win32系统中变量hPrevInst的值总为0。另一种既适合Win32系统又适合于16位的Windows的技术，是调用FindWindow()API函数去搜索一个已激活的程序窗口。
　　Windows API 提供了函数FindWindow，可以是应用程序在启动时检查自己是否已经存在。 该函数在Delphi中的语法为：
　　function FindWindow(lpClassName: PChar, lpWindowName: PChar): HWND;
　　其中，参数lpCalssName 是要查找的窗口的类的名称，参数lpWindowName是要查找的窗口的标题(Caption)。 如果找到了相应的窗口实例，将返回一个非0 的该窗口句柄的整型值，否则返回0 。因此，只要判断应用程序的主窗口（或者伴随着应用程序存在而存在的窗口）是否存在就可以判断是否已经有实例存在了。
　　例如：
[codes=delphi]
　　H := FindWindow('TForm1', nil);
　　if H = 0 then begin
　　 ShowMessage('没有发现相同的应用程序实例。');
　　 //加入加载应用程序的语句
　　 //...
　　end else begin
　　 ShowMessage('应用程序已经加载。');
　　 SetActiveWindow(H);
　　end;
[/codes]
　　其中，参数lpWindowName的位置以Delphi保留字nil 代替，是因为窗口的标题可能在应用程序中是变化的。Windows API 函数SetActiveWindow 用于指定活动窗口。

　　但是，这种方法有两个缺陷：一是它只能基于窗口类名或标题来搜索窗口，但是在整个系统中窗口很可能会重复。所以，这样做是不可靠的。而利用窗口的标题的方法也有问题，因为窗口的标题有可能发生变化(以Delphi和Word为例，每次打开不同文件，它们的标题都会变化)，所以这种方法不可取。另一个缺陷是它每次搜索都要遍历所有窗口，这样执行进来非常慢。

　　因此，在Win32系统中最好的解决方案是利用那些不依赖于进程的API对象，并且它们的使用也很简单，互斥对象就可以解决这个问题。当一个应用程序首次运行时，我们就使一个互斥对象被API函数CreateMutex()创建。这个函数的参数lpName是一个唯一标识互斥对象的字符串。当应用程序的实例要运行前，它首先要用OpenMutex()来打开互斥对象，如果已经有一个CreateMutex()创建的互斥对象则返回非零值。另外，当试图运行另一个程序实例时，使第一个实例被激活。
　　对于这个问题，最好的解决方法是在首次运行时，利用RegisterWindowMessage()函数注册一个消息，并在应用程序中创建唯一的消息标识符。然后，利用第一个实例对这个消息的响应使它被第二个实例激活。
下面介绍两种实现方法，均在Delphi7，Win2000/XP下测试通过。

1 、这种方法阻止新实例的产生，但不能提前，不过较简便。我就是采用这种方法：）
在Project的Program文件中
[codes=delphi]
program KS_Kd_Srv;

uses
Windows,
Forms,
ShellApi,
SysUtils,
.....;

{$R *.TLB}

{$R *.res}
var
HMutex:Hwnd;
Ret:Integer;
begin

Application.Initialize;
aTitle := '考场应用服务器';
//Application.Title := aTitle; //Application.Title不能接受变量的值，怪了
Application.Title := '考场应用服务器';

HMutex:=CreateMutex(nil,False,Pchar(aTitle)); //建立互斥对象，名字为aTitle--'考场应用服务器'
Ret:=GetLastError;
If Ret<>ERROR_ALREADY_EXISTS Then
begin
    ... //做我们正常该做的事情
end else
    ReleaseMutex(hMutex); //防止创建多个程序实例 有人在此用 Halt(0);结束应用程序，明显不好！

Application.Run;
end.
[/codes][newpage]
2 、在《Delphi 5 开发人员指南》中第13章中有一篇“防止同时出现多个应用程序实例”，代码中给出了一个MultInst.pas单元，工程引用此单元就能防止同时出现多个实例，
但实际应用中发现, 如果应用程序并没有最小化，第二个实例不能把第一个实例提到最前。
下面是我改写的MultInst.pas单元，能解决这个小问题。这里参考了ysai的代码。
[codes=delphi]
//==============================================================================
// Unit Name: MultInst
// Author   : xieyunc
// Date     : 2003-05-20
// Purpose : 解决应用程序多实例问题
// History :
//==============================================================================

//==============================================================================
// 工作流程
// 程序运行先取代原有向所有消息处理过程,然后广播一个消息.
// 如果有其它实例运行,收到广播消息会回发消息给发送程序,并传回它自己的句柄
// 发送程序接收到此消息,激活收到消息的程序,然后关闭自己
//==============================================================================
unit MultInst;

interface

uses
Windows ,Messages, SysUtils, Classes, Forms;

implementation

const
STR_UNIQUE    = '{2BE6D96E-827F-4BF9-B33E-8740412CDE96}';
MI_ACTIVEAPP = 1; //激活应用程序
MI_GETHANDLE = 2; //取得句柄

var
iMessageID    : Integer;
OldWProc      : TFNWndProc;
MutHandle     : THandle;
BSMRecipients : DWORD;

function NewWndProc(Handle: HWND; Msg: Integer; wParam, lParam: Longint):
Longint; stdcall;
begin
Result := 0;
if Msg = iMessageID then
begin
    case wParam of
      MI_ACTIVEAPP: //激活应用程序
        if lParam<>0 then
        begin
          //收到消息的激活前一个实例
          //为什么要在另一个程序中激活?
          //因为在同一个进程中SetForegroundWindow并不能把窗体提到最前
          if IsIconic(lParam) then
            OpenIcon(lParam)
          else
            SetForegroundWindow(lParam);
          //终止本实例
          Application.Terminate;
        end;
      MI_GETHANDLE: //取得程序句柄
        begin
          PostMessage(HWND(lParam), iMessageID, MI_ACTIVEAPP,
            Application.Handle);
        end;
    end;
end
else
    Result := CallWindowProc(OldWProc, Handle, Msg, wParam, lParam);
end;

procedure InitInstance;
begin
//取代应用程序的消息处理
OldWProc    := TFNWndProc(SetWindowLong(Application.Handle, GWL_WNDPROC,
    Longint(@NewWndProc)));

//打开互斥对象
MutHandle := OpenMutex(MUTEX_ALL_ACCESS, False, STR_UNIQUE);
if MutHandle = 0 then
begin
    //建立互斥对象
    MutHandle := CreateMutex(nil, False, STR_UNIQUE);
end
else begin
    Application.ShowMainForm := False;
    //已经有程序实例,广播消息取得实例句柄
    BSMRecipients := BSM_APPLICATIONS;
    BroadCastSystemMessage(BSF_IGNORECURRENTTASK or BSF_POSTMESSAGE,
        @BSMRecipients, iMessageID, MI_GETHANDLE,Application.Handle);
end;
end;

initialization
//注册消息
iMessageID := RegisterWindowMessage(STR_UNIQUE);
InitInstance;

finalization
//还原消息处理过程
if OldWProc <> Nil then
    SetWindowLong(Application.Handle, GWL_WNDPROC, LongInt(OldWProc));

//关闭互斥对象
if MutHandle <> 0 then CloseHandle(MutHandle);

end.
//使用方法很简单，只要把此单元加入工程就可以了。
[/codes][file]attachment/multinst.rar[/file]
　　但是这种方法由于是在新的实例MainForm.create后中止新实例，同时把旧实例提前，故还存在两点不足：
1、假设我们的Application.ShowMainForm设为FALSE，但是如果在MainForm.Create之前调用了其他如Flash界面，仍然会短暂的显示出来。
2、如果在同一工程组的中的多个应用程序都包含了此文件的话，那么不同的应用程序也会互斥！