oracle cursor 游标的介绍

理解含义：

游标用来处理从数据库中检索的多行记录（使用SELECT语句）。利用游标，程序可以逐个地处理和遍历一次检索返回的整个记录集。

为了处理SQL语句，Oracle将在内存中分配一个区域，这就是上下文区。这个区包含了已经处理完的行数、指向被分析语句的指针，整个区是查询语句返回的数据行集。游标就是指向上下文区句柄或指针。

游标是映射在结果集中一行数据上的位置实体，有了游标，用户就可以访问结果集中的任意一行数据了，将游标放置到某行后，即可对该行数据进行操作，例如提取当前行的数据等。

  游标的属性4种
       %notfound  fetch是否提到数据 没有true 提到false
       %found      fetch是否提到数据 有true 没提到false
       %rowcount  已经取出的记录的条数
       %isopen    布尔值 游标是否打开

两种游标：

一、显式游标

    显式游标被用于处理返回多行数据的SELECT 语句，游标名通过CURSOR….IS 语句显示地赋给SELECT 语句。

       显式游标所必需的四个步骤：

       1）声明游标；declare CURSOR cursor_name IS select_statement
       2）为查询打开游标；OPEN cursor_name
       3）取得结果放入PL/SQL变量中；FETCH cursor_name INTO list_of_variables;
       4）关闭游标：CLOSE cursor_name

       注意：在声明游标时，select_statement不能包含INTO子句。当使用显示游标时，INTO子句是FETCH语句的一部分。

    显式游标：
         for循环游标
         参数游标
         fetch游标
         引用游标

二、隐式游标

       在 PL/SQL 程序中执行DML SQL 语句时自动创建隐式游标，名字固定叫sql。所有的隐式游标都被假设为只返回一条记录。
       使用隐式游标时，用户无需进行声明、打开及关闭。PL/SQL隐含地打开、处理，然后关掉游标。
       例如：
       …….
       SELECT studentNo,studentName
       INTO curStudentNo,curStudentName
       FROM StudentRecord
       WHERE name=’gg’;

       上述游标自动打开，并把相关值赋给对应变量，然后关闭。执行完后，PL/SQL变量curStudentNo,curStudentName中已经有了值。

   隐式游标
         单条sql语句所产生的结果集合，用关键字SQL表示隐式游标
         多条sql语句，隐式游标SQL永远指的是最后一条sql语句的结果
        主要使用在update 和 delete语句上  

实际操作和例子：

(1)FOR循环游标 (常用的一种游标)

 --<1>定义游标
 --<2>定义游标变量
 --<3>使用for循环来使用这个游标

  --前向游标 只能往一个方向走
  --效率很高
      declare
        cursor cc is select empno,ename,job,sal from emp where job = 'MANAGER';     --类型定义
        ccrec cc%rowtype;              --定义一个游标变量ccrec cc%rowtype ，该类型为游标cc中的一行数据类型
      begin
         --for循环
         for ccrec in cc loop
            dbms_output.put_line(ccrec.empno||'-'||ccrec.ename||'-'||ccrec.job||'-'||ccrec.sal);
         end loop;      
      end;

   (2) fetch游标
     --使用的时候 必须要明确的打开和关闭
      declare     
        cursor cc is select empno,ename,job,sal from emp where job = 'MANAGER';   --类型定义     
        ccrec cc%rowtype;          --定义一个游标变量
      begin      
         open cc;              --打开游标
         loop                    --loop循环
            fetch cc into ccrec;              --提取一行数据到ccrec中       
            exit when cc%notfound;      --判断是否提取到值，没取到值就退出，取到值cc%notfound 是false，取不到值cc%notfound 是true
            dbms_output.put_line(ccrec.empno||'-'||ccrec.ename||'-'||ccrec.job||'-'||ccrec.sal);           
         end loop;
         close cc;                 --关闭游标
      end;

   (3)参数游标
     --按部门编号的顺序输出部门经理的名字
     declare
       cursor c1 is select deptno from dept;
       cursor c2(no number,pjob varchar2) is select emp.* from emp  --参数游标c2,定义参数的时候只能指定类型,不能指定长度,参数只能出现在select语句=号的右侧
         where deptno = no and job=pjob;
       c1rec c1%rowtype;
       c2rec c2%rowtype;
       v_job varchar2(20);       --定义变量的时候要指定长度
     begin
        for c1rec in c1 loop     --参数在游标中使用       
          for c2rec in c2(c1rec.deptno,'MANAGER') loop
            dbms_output.put_line(c1rec.deptno||'-'||c2rec.ename);
          end loop;
        end loop;
     end;
    
    
  (4)引用游标/动态游标
       -- select语句是动态的
     declare
       type cur is ref cursor;                             --定义一个类型(ref cursor)弱类型  
       type cur1 is ref cursor return emp%rowtype;         --强类型(返回的结果集有要求) 
       cura cur;                                           --定义一个ref cursor类型的变量
       c1rec emp%rowtype;
       c2rec dept%rowtype;
     begin
  DBMS_output.put_line('输出员工')   ;      
       open cura for select * from emp;
       loop
         fetch cura into c1rec;  
         exit when cura%notfound;
         DBMS_output.put_line(c1rec.ename)   ;
       end loop ;
  DBMS_output.put_line('输出部门')   ;
       open cura for select * from dept;
       loop
         fetch cura into c2rec;  
         exit when cura%notfound;
         DBMS_output.put_line(c2rec.dname)   ;
       end loop; 
       close cura;
    end;

来自 “ ITPUB博客 ” ，链接：http://blog.itpub.net/29289867/viewspace-1975848/，如需转载，请注明出处，否则将追究法律责任。

转载于:http://blog.itpub.net/29289867/viewspace-1975848/