安装绿色版MySQL的做法

作者：朱金灿

来源：http://blog.csdn.net/clever101

 

1.      下载MySQL绿色版，下载地址为：MySQL绿色版。

2.      解压下载下来的文件夹，把该文件夹解压到指定目录下，比如D:\Program Files (x86)。

 

3.      用记事本打开SetMySQLEnv.bat，将下面的批处理代码复制到这个文件（覆盖原有的文本）

rem 作者：朱金灿
rem 联系方式：clever101#163.com
rem 请注意用管理员权限运行该批处理文件，否则会出现find命令无法识别的错误

@echo off

rem 创建MySQL服务
sc create MySQL binpath= "%~dp0bin\mysqld.exe" displayname= "MySQL" start= auto

ver | find "4.0." > NUL &&  goto win_xp    
ver | find "4.10." > NUL &&  goto win_xp   
ver | find "4.90." > NUL &&  goto win_xp   
ver | find "3.51." > NUL &&  goto win_xp   
ver | find "5.0." > NUL &&  goto win_xp    
ver | find "5.1." > NUL &&  goto win_xp    
ver | find "5.2." > NUL &&  goto win_xp    
ver | find "6.0." > NUL &&  goto win7   
ver | find "6.1." > NUL &&  goto win7    
ver | find "6.2." > NUL &&  goto win7   
ver | find "6.3." > NUL &&  goto win7  
ver | find "10.0." > NUL &&  goto win7

:win_xp 

rem 设置环境变量MYSQL_HOME
wmic ENVIRONMENT where "name='MYSQL_HOME'" delete 
wmic ENVIRONMENT create name="MYSQL_HOME",username="<system>",VariableValue=%~dp0
echo %MYSQL_HOME%

rem 将%MYSQL_HOME%\bin添加到path变量
rem 检查path中有没有e:tools(有就跳到end，没有就接着执行)
echo %path%|findstr /i "%~dp0bin"&&(goto end)

rem 先添加，防止没有时修改出错
wmic ENVIRONMENT create name="Path",VariableValue="%~dp0bin;%Path%"

rem 再修改，防止已有时添加出错
wmic ENVIRONMENT where "name='Path' and username='<system>'" set VariableValue="%~dp0bin;%Path%"

goto end 

:win7

rem 设置环境变量MYSQL_HOME
@setx MYSQL_HOME %~dp0 -m

rem 将%MYSQL_HOME%\bin添加到path变量
echo %path%|findstr /i "%~dp0bin"&&(goto end)

@setx Path "%~dp0bin;%Path%" -m

goto end

:end
pause

然后双击运行SetMySQLEnv.bat，结果如下图：

4.      检查是否安装成功，在控制台中输入一个查看MySQL版本的命令：mysql –V，如下图：